Erreur à la deuxième exécution du scriptRésolu

Question

Bonjour, Je fais face à un problème d'exécution d'un script. A la première exécution le script se déroule correctement. Mai a la deuxième j'ai l'erreur suivante: "Run-time error '91': Object variable or with blockvariable not set". Le script est arrété sur l'instruction " Selection.copy". Je suis alors obligé d'arréter le script de fermer le fichier EXCEL ouvert par le script. Si j'exécute le scipt à nouveau je n'ai pas d'erreur. J'ai remarquer qu'en pointant sur les methods "Worksheet" ou "Rows" de mon script, au premier passage j'ai le tooltype text suivant "Worksheets =

mrdep1978 · Accepted Answer

Salut,

Le mieux, c'est de virer tout ce qui concerne les objets de type "Selection", "ActiveSheet", "ActiveCell" (bref, les "ActiveXXXX").
Evite également les méthodes Activate et Select.
Elles sont utiles si tu veux positionner le curseur sur la cellule Excel ou afficher une feuille précise, sinon ça apporte des ennuis mais pas d'intérêt.

Pour moi, ton code devrait donner qqe chose comme ça :

Private Sub Button3_Released()

'Best to define variable first but not nessecary
Dim ObjExcelApp As Object
Dim l_WorkBook As Object
Dim Fname As String
Dim name As String

Fname = "C:\Classeur1.xls" 'name of already created excel project

Set ObjExcelApp = CreateObject("Excel.Application")
ObjExcelApp.Visible = True

'l_WorkBook représente le classeur que tu as ouvert
Set l_WorkBook = ObjExcelApp.Workbooks.Open (Fname)
'ObjExcelApp.Worksheets("Feuil1").Activate
With l_WorkBook.Worksheets("Feuil1")
    .Cells(1, "A").Value = "OK man" 'Write date to cell A1
    .Range("A1").Copy .Range("B2")  'Copy data from A1 to B2
End With
l_WorkBook.Close True   'Save and close the workbook
ObjExcelApp.Quit        'Close Excel
Set l_WorkBook = Nothing
Set ObjExcelApp = Nothing

End Sub

mortalino · Answer

salut,

n'utilise pas le type Object mais Excel

1/ dans le menu Projet, références, coche Microsoft Excel Object Library.

remplace Dim ObjExcelApp As Object
par Dim ObjExcelApp As New Excel.Application

et supprime
Set ObjExcelApp = CreateObject("Excel.Application")

@++ 

<hr width="100%" size="2" />( Nouveau forum : Exclusivement Office & VBA/STRONG>

JG73 · Answer

Bonjour et merci pour votre réponse rapide. J'ai modifié mon script sur vos conseils mais malheureusement sans succès. La réponse faite par mrdep1978 a résolu le problème.


Encore merci


JG73

vbnet64 · Answer

Bonjour, quand j'ai eu ce problème je l'ai corriger en ajoutant l'objet avant la sélection ex:  objexcelapp.Selection.Copy

vbnet

Erreur à la deuxième exécution du script

4 réponses

Votre réponse

Discussions similaires