Boite de dialogue

Question

Bonjour, 

Je voudrais que l'utilisateur de mon programme sélectionne un répertoire dans son arborescence.
Pour cela, j'ai trouvé la solution de l'objet CommonDialog. Donc, l'utilisateur parcourt le disque, et lorsqu'il trouve le bon endroit, il sélectionne un fichier. A ce moment là, je récupère le chemin d'accès, et je l'affiche dans une zone de texte à côté. Seulement voilà, je ne veux pas qu'il choisisse un fichier mais plutôt un répertoire. Je suis sure que c'est possible, mais je ne trouve pas la solution. Quelqu'un pourrait-il m'aider, svp.
Ca m'empêche d'avancer dans mon boulot, et je déprime.
Merci d'avance.
gaby33

cs_Crazyht · Answer

Ben alors il faut pas déprimé.

Crée une fenêtre dans la quelle tu place 1 ctl DriveListBox et 1 Ctl DirListBox, tu y ajoute 2 boutons ( OK,Annuler ) et voila le tour est joué.

cs_gaby33 · Answer

Si c'est aussi simple que ça, je vais encore plus déprimer!!!
Ca veut dire sue je suis vraiment nulle, alors!!!!
Merci quand même, et à bientôt pour d'autres questions encore plus subtiles que celle d'aujourd'hui!

Makabey · Answer

Met dans un module ceci, au début du code il y as un exemple d'utilisation:

'
' Origine:  http://www.vbthunder.com/source/explorer/folderbrowse.htm
'=====
'
'  Exemple d'utilisation:
'
'Private Sub cmdFolder_Click()
'     Dim sFolder As String
'     sFolder = GetFolder(hwnd)
'     If Len(sFolder) > 0 Then
'          MsgBox "Folder selected was: " & sFolder
'     Else
'          MsgBox "No folder selected!"
'     End If
'End Sub
'

Public Type BROWSEINFO
  hOwner As Long
  pidlRoot As Long
  pszDisplayName As String
  lpszTitle As String
  ulFlags As Long
  lpfn As Long
  lParam As Long
  iImage As Long
End Type

'BROWSEINFO.ulFlags values:
Private Const BIF_RETURNONLYFSDIRS = &H1

Private Declare Function SHGetPathFromIDList Lib "shell32.dll" _
     Alias "SHGetPathFromIDListA" (ByVal pidl As Long, _
     ByVal pszPath As String) As Long

Private Declare Function SHBrowseForFolder Lib "shell32.dll" _
     Alias "SHBrowseForFolderA" (lpBrowseInfo As BROWSEINFO) As Long

Private Declare Sub CoTaskMemFree Lib "ole32.dll" (ByVal pv As Long)

Public Function GetFolder(ByVal hWndModal As Long) As String
  Dim bInf As BROWSEINFO
  Dim RetVal As Long
  Dim PathID As Long
  Dim RetPath As String
  Dim Offset As Integer
  
  'Set the properties of the folder dialog
  bInf.hOwner = hWndModal
  bInf.lpszTitle = "Please select a folder:"
  bInf.ulFlags = BIF_RETURNONLYFSDIRS
  'Show the Browse For Folder dialog
  PathID = SHBrowseForFolder(bInf)
  RetPath = Space$(512)
  RetVal = SHGetPathFromIDList(ByVal PathID, ByVal RetPath)
  If RetVal Then
      'Trim off the null chars ending the path
      'and display the returned folder
      Offset = InStr(RetPath, Chr$(0))
      GetFolder = Left$(RetPath, Offset - 1)
      'Free memory allocated for PIDL
      CoTaskMemFree PathID
    Else
      GetFolder = vbNullString
  End If
End Function

allenboi · Answer

Bonjour!
J'aimerais trouver le moyen d'enregistrer le contenu d'une TextBox dans un document .txt
Est-ce possible?
J'ai aussi une autre question:
Est-ce possible de changer la couleur d'un texte surligné (juste un texte surligné) par un Menu?
Si vous connaissez la réponse à une des deux questions, envoyez moi une réponse le plus vite possible! [mailto:guest_number_one@hotmail.com guest_number_one@hotmail.com]

Boite de dialogue

4 réponses

Discussions similaires