Sleep VB qui plante

Question

Bonjour a tous,


J'utilise la fonction Sleep suivante sous VB :

Private Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)

Seulement lorsque je fais un Sleep de quelques secondes, mon appli plante plus ou moins, et reviens à la fin du sleep.

N'y a t-il pas une autre manière d'attendre sans plantage ou ralentissement ?

Merci

ucfoutu · Answer

Bonjour,

Que veux-tu "attendre" et pourquoi, exactement (car sleep met en sommeil et rien ne s'exécute pendant sa durée). ?


____________________
Très intéressante fable, L'OISELEUR, L'AUTOUR ET L'ALOUETTE !
Cliquer sur "Réponse acceptée" (en bas d'une solution avérée adéquate) rendra service à d'autres. PENSEZ-Y.

Lokomass · Answer

Lors de l'envoi de commande par exemple à un Switch, si je vais trop vite ça plante la machine, ou au contraire lors de la reception de ce dernier.
Oui, j'ai besoin d'attendre sans rien rien, et j'aimerai avoir une fonction qui ne fasse pas "planter" le programme.

Claiyah · Answer

salut
"Seulement lorsque je fais un Sleep de quelques secondes" = normal sleep bloc toute l'application
montre ton code pour qu'on puisse t'aider
tu peut utiliser "doevents" pour remettre la main au systeme au cas ou tu utilise des boucles

Lokomass · Answer

Par exemple ceci :


Open FileName For Output As #1
    MSComm1.Output = Chr$(26) & vbCr & "show running-config" & vbCr
    For i = 1 To 50
        MSComm1.Output = Chr(32)
    Next
    Sleep (7000)
    Write #1, MSComm1.Input
    Close #1

Je dois attendre que la configuration soit afficher en entière pour la stocker sinon il manque des morceaux

Renfield · Answer

il doit bien y avoir un moyen de savoir si MsComm est pret a te donner des données

sinon, je comprend pas l'imbrication fichier / MsComm (ni cette boucle d'espaces) :

MSComm1.Output = Chr$(26) & vbCr & "show running-config" & vbCr & Space$(50)
Sleep (7000)
Open FileName For Output As #1
    Write #1, MSComm1.Input
Close #1


Renfield - Admin CodeS-SourceS - MVP Visual Basic

Lokomass · Answer

Cette boucle d'espace permet de tout afficher.
JE m'explique.
Le switch affiche les 10 premières lignes de conf, tant que t'appuie pas sur espace, il attend.
Comme les conf peuvent faire 3 lignes ou 200, j'appuie beaucoup de fois et âpres j'envoie le tout dans le fichier texte.

Renfield · Answer

que penses tu de l'utilisation de Space$ ?

Renfield - Admin CodeS-SourceS - MVP Visual Basic

Lokomass · Answer

Je ne sais pas ce que c'est lol.

Dans tous les cas ce petit sleep me casse les pieds, si je fais un Doevents, et bien il ne copie rien dans le fichier texte.
Avec le sleep ça fonctionne, mais ça fait planter l'appli pendant tout le temps du sleep.

Existe t-il une autre manière que cela s'attendre sans rien faire d'autre et bien sur sans planter graphiquement l'appli ?

Renfield · Answer

dim nStart as long
nStart = Timer
Do 
    DoEvents
Loop while Timer < nStart+7


Renfield - Admin CodeS-SourceS - MVP Visual Basic

Lokomass · Answer

Merci de ton aide,

Mais non, cela ne fonctionne pas, le fichier texte reste vide.
Du moment qu'il y a DOevents, il fait ça trop vite j'ai l'impression et ça ne fonctionne pas.

Actuellement voila la fonction un peu bidouille que j'ai mais qui fonctionne "en plantant le logiciel pendant un certain temps"


    For i = 0 To 100
        If i 10 Or i 20 Or i = 30 Or i = 40 Or i = 50 Or i = 60 Or i = 70 Or i = 80 Or i = 90 Then
            Write #1, MSComm1.Input
        End If
        MSComm1.Output = Chr(32)
    Next

Renfield · Answer

Le problème est fort simple, en fait...

tu lit sur le port et tu stocke ce que tu lis dans le fichier

si le périphérique en face n'est pas pret, tu ne lira rien, et pas de deuxieme chance...

lis en boucle, et concatène ce qui est lu jusqu'a ce que tu estime/sache/calcule que ton message est complet et valide.
alors tu pourras quitter ta boucle et ecrire le buffer dans ton fichier


Renfield - Admin CodeS-SourceS - MVP Visual Basic

Lokomass · Answer

Je te remercie mais c'est dèjà plus ou moins ce que je fais avec ce "sleep".
Comment faire autrement, as tu un exemple de code ?

Lokomass · Answer

J'ai testé ça mais cela ne fonctionne pas :

    Do
    DoEvents
    Buffer = Buffer & MSComm1.Input
    MSComm1.Output = Chr(32)
    Loop Until InStr(MSComm1.Input, "end")
    Write #1, Buffer

Lokomass · Answer

Mon fichier texte est vide, car je ne sors jamais de cette boucle.
Pourtant le mot "end" apparait bien dans ce que m'affiche le Switch mais apparemment VB ne le vois pas passer et ne sors jamais de cette boucle, il n'écrit donc pas dans le fichier texte, je ne comprend pas.

Renfield · Answer

non.

l'ennui est que chaque instrcution MSComm1.Input lit le port, et cette donnée est perdu si tu ne la stocke pas.

ton code est donc pas mal, sauf en ce qui concerne le test de sortie 

Loop Until InStr(buffer, "end")


après, j'ai jamais joué avec MsComm, c'est dison du raisonnement de base que je fais là


Renfield - Admin CodeS-SourceS - MVP Visual Basic

Lokomass · Answer

Dans tous les cas, en fait cela va trop vite, dans la boucle, et donc mon Buffer est complètement pommé.
La seule solution est de faire une pause réelle durant laquelle le système ne fait rien d'autre qu'attendre sans "Doevents".
Mais voilà pendant 10 secondes la fenêtre devient blanche et plante complètement avec ce sleep.

Cela dit, à la fin du plantage, j'ai mon bon fichier texte....

Mais j'aimerai vraiment faire autrement.

Renfield · Answer

DoEvents, c'est assez simple en fait, comme instruction.

ca va forcer VB à consommer tous les messages lui étant déstinés.
du coup, Windows ne considérera pas ton application comme non-réactive, et ton interface réagira égallement.

du coup, ca chopera les messages concernant MsComm et remplira ton Buffer Input.

Maintenant, je vois pas en quoi cela deviens problématique, dés lors que tu lis bien (une seule fois) le contenu récéptionné dans Input et que stockes bien le tout de coté...


au pire, tentes de petites pause répétées :

Dim sBuffer as String
Do
    Sleep 200
    DoEvents
    sBuffer = sBuffer & MSComm1.Input
    MSComm1.Output = Chr(32)  '# J'ignore pourquoi cette ligne est là. Ne faut il pas envoyer également un Chr$(13) ?
Loop Until InStr(sBuffer, "end")
Open "...." For Ouput As #1
    Print #1, sBuffer;
Close #1


Renfield - Admin CodeS-SourceS - MVP Visual Basic

Lokomass · Answer

Alors, cette ligne :

MSComm1.Output = Chr(32)

Envoi des espaces. Parce que lorsque je demande au Switch de me montre sa configuration, il me montre une partie et attend que j'appuie sur l'espace. Donc comme je connais pas la longueur de la config (variable) j'arrive pas à savoir combien de fois je dois appuyer.

Bref, lol, il ne sort jamais de la boucle en fait là. Pourtant dans la config, le dernier mot à chaque fois c'est bien "end".

Je ne comprend pas

Renfield · Answer

testé en pas a pas ?

et c'est bien "end" pas "END" ou "End" ?

quid de l'envoi de chr(32) et chr(13) c'est tout faux ?

Renfield - Admin CodeS-SourceS - MVP Visual Basic

Lokomass · Answer

Il s'agit bien de "end" comme ceci.
Testé en pas en pas, c'est à dire ?
Et quid ca veut dire quoi lol ?

Renfield · Answer

pas a pas, c'est en executant le code ligne apres ligne, en placant un point d'arret (F9)
et en pressant F8 pour executer la ligne selectionnée

quid...

ben, me semblais que tout envoi MsComm devait etre validé par un chr(13)


Renfield - Admin CodeS-SourceS - MVP Visual Basic

Lokomass · Answer

On y est presque, avec cette fonction :

    Do
        DoEvents
        Sleep (300)
        buffer = buffer & MSComm1.Input
        MSComm1.Output = Chr(32)
    Loop Until InStr(buffer, "!" & vbCrLf & "end")

Voilà je sors bien de ma boucle, pas de figeage d'écran, mais encore un soucis...
Il manque des morceaux de mots... Ils s'affichent sur mon écran, et ne sont donc pas dans mon txt. Par exemple, dans ma fenetre je vois :

assword-e

Et dans mon fichier texte j'ai sur cette ligne :

service pncryption

Comme tu t'en doute la ligne correcte qu'il me faut c'est :

service password-encryption

Seulement sur mon fichier texte de 150 lignes, il me manque seulement deux ou trois petits morceaux de mot. C'est pas grand chose mais ça flingue le txt. J'ai essayé de faire varier le sleep, mais sans succès, on est vraiment pas loin mais y'a toujours un petit truc qui fait ****


:)

hellangel777 · Answer

Bonjour,

Je m'excuse si je suis hors des clous, j'ai fait de la lecture en Z de ce topic, pourtant ton problème, j'ai eu le même sous vb6.
Le truc c'est que j'ai utilisé une fonction automate combinée avec un timer. C'est à dire que je lancais ma communication et je stocquais les données reçues dans un buffer et je ne lançais aucunes autres instructions tant que me timer n'était pas échu.
As-tu tenté l'option timer plutot que le sleep? 


HellAngel777
Les machines ne font pas d'erreurs
Heureusement nous sommes humains

Lokomass · Answer

Non je n'ai pas testé, je en sais pas comment faire.
Merci de ta réponse, aurais tu un exemple de timer à inserer dans mon code et comment le mettre ??


MErci

hellangel777 · Answer

Je te file ca brut... Ca remonte à longtemps...
Je précise que c'est du vb6 !!!

Private Sub Automate(Situation As String)
Dim i As Integer
    
    i = 0
    Select Case Situation
        Case "TimeOut"                '-- Gestion du TimeOut
            '-- On vérifie que l'on a pas reçu d'information
            If rsResultat.RecordCount > 0 Then
                '-- On a des informations on lance la commande de traitement
                Automate ("TraitementFinal")
            Else
                '-- On a pas d'information et on défini une variable en mode erreur
                TypeErreur = "TimeOut"
                frm_Principale.timerCommande.Interval = 500
                frm_Principale.timerCommande.Enabled = True
                EnvoiCmd = False
            End If
        Case "ErreurReception"        '-- Erreur dans la réception
            TypeErreur = "ErrRcpt"
            TimerTimeOut.Enabled = True
            EnvoiCmd = False
        Case "TraitementInter"
            DoEvents
            Do While InStr(strBuffer, Chr$(13))
                strbuffer2 = Left(strBuffer, InStr(strBuffer, Chr$(13)))
                If frm_Principale.ValidEntree = True And InStr(strbuffer2, "[GES]") > 0 Then
                    strbuffer2 = Left(strbuffer2, Len(strbuffer2) - 1)
                    strbuffer2 = Right(strbuffer2, Len(strbuffer2) - 1)
                    rsResultat.AddNew
                    rsResultat!Ligne.Value = strbuffer2
                    rsResultat.Update
                    strBuffer = Right(strBuffer, Len(strBuffer) - InStr(strBuffer, Chr$(13)))
                Else
                    rsResultat.AddNew
                    rsResultat!Ligne.Value = strbuffer2
                    rsResultat.Update
                    strBuffer = Right(strBuffer, Len(strBuffer) - InStr(strBuffer, Chr$(13)))
                End If
            Loop
            TimerTimeOut.Enabled = True
            TypeErreur = "TrtmtInter"
        Case "TraitementFinal"
            If frm_Principale.ValidEntree = True And InStr(strBuffer, "[GES]") > 0 Then
               strbuffer2 = Left(strbuffer2, Len(strbuffer2) - 1)
               strbuffer2 = Right(strbuffer2, Len(strbuffer2) - 1)
               rsResultat.AddNew
               rsResultat!Ligne.Value = strbuffer2
               rsResultat.Update
               strBuffer = Right(strBuffer, Len(strBuffer) - InStr(strBuffer, Chr$(13)))
            Else
                rsResultat.AddNew
                rsResultat!Ligne.Value = strBuffer
                rsResultat.Update
                rsResultat.MoveFirst
            End If
            TypeErreur = "BufferFinal"
            frm_Principale.timerCommande.Interval = 500
            frm_Principale.timerCommande.Enabled = True
            TimerTimeOut.Enabled = False
            EnvoiCmd = False
        Case "PBConnexion"            '-- Erreur dans la connexion au module
            TypeErreur = "ErrCnx"
            TimerTimeOut.Enabled = True
            EnvoiCmd = False
    End Select
End Sub

Private Sub Communique_OnComm()
Dim strRecep As String

    Select Case Communique.CommEvent

        'liste des erreurs possibles

        Case comEventBreak      ' On a reçu un signal d'interruption (Break)
            Call Automate("ErreurReception")
        Case comEventCDTO       ' Timeout de la porteuse
            Call Automate("ErreurReception")
        Case comEventCTSTO      ' Timeout du signal CTS (Clear To Send)
            Call Automate("ErreurReception")
        Case comEventDSRTO      ' Timeout du signal de réception
            Call Automate("ErreurReception")
        Case comEventFrame      ' Erreur de trame
            Call Automate("ErreurReception")
        Case comEventOverrun   ' Des données ont été perdues
            Call Automate("ErreurReception")
        Case comEventRxOver     ' Tampon de réception saturé
            Call Automate("ErreurReception")
        Case comEventRxParity   ' Erreur de parité
            Call Automate("ErreurReception")
        Case comEventTxFull     ' Tampon d'envoi saturé
            Call Automate("ErreurReception")
        Case comEventDCB        ' Erreur de réception DCB (jamais vu)
            Call Automate("ErreurReception")
        
        ' liste des événements possibles qui sont, eux, normaux
        Case comEvCD            ' Changement dans la broche CD (porteuse)
        Case comEvCTS           ' Changement dans broche CTS
        Case comEvDSR           ' Changement dans broche DSR (réception)
        Case comEvRing          ' Changement dans broche RING (sonnerie)
        Case comEvReceive       ' Si on reçoit des données
            If EnvoiCmd True Or frm_Principale.ValidEntree True Then
                If frm_Principale.ValidBETGVA = True Then
                    TimerEOF.Interval = 5000
                Else
                    TimerEOF.Interval = 500
                End If
                TimerEOF.Enabled = True
                strBuffer = strBuffer & Communique.Input
                If InStr(strBuffer, Chr$(13)) > 0 Then
                    TimerEOF.Enabled = False
                    Call Automate("TraitementInter")
                End If
            End If
        Case comEvSend          ' Il y a des caractères à envoyer
        Case comEvEOF           ' On a reçu le caractère EOF
    End Select
End Sub

C'est une partie du code que j'ai fait qui est en fait un mscomm associé à un timer Le tout mis dans un controle utilisateur.

HellAngel777
Les machines ne font pas d'erreurs
Heureusement nous sommes humains

Sleep VB qui plante

25 réponses

Votre réponse

Discussions similaires