problème de systrayRésolu

Question

Bonjour,

J'ai un programme systray qui fonctionne bien sur 2 programmes. J'ai commencé une autre application, et j'ai un problème avec ce même systray.
Au démarrage, l'icône ce met bien dans la barre des tâches. Lorsque je pointe la souris sur l'icône sans cliquer, l'info bulle apparaît. Par contre lorsque je clique dessus, rien ne se passe, que ce soit un clic droit ou gauche ou double clic, rien.
J'ai consulté le programme de long en large, et je ne trouve rien. Alors, je me suis dit que c'était peut-être arrivé à l'un de vous, et qu'il aurait trouvé la solution à ce problème.

Merci d'avance pour toutes réponses.
@+++
marcod59

Renfield · Accepted Answer

ne mets pas le hWnd de rappel a celui de la Form !
ca va si celle ci est masquée... a la limite.

ajoute un pictureBox (Picture1) et fait par exemple :

IconeT.hwnd = Picture1.hwnd

et 

Private Sub Picture1_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
    On Error Resume Next
'Si la souris est sur la feuille et n'est pas sur un bouton, alors, retirer le cadre du bouton précédent,
Static rec As Boolean, msg As Long
'Se produit lorsque l'utilisateur agit avec la souris sur
'l'icône placée dans le système tray
msg = X / Screen.TwipsPerPixelX
If rec = False Then
    rec = True
    Select Case msg
        
        Case DOUBLE_CLICK_GAUCHE:
        
        Case BOUTON_GAUCHE_POUSSE:
        
        Case BOUTON_GAUCHE_LEVE:
            Me.PopupMenu mnsystray
            
        Case DOUBLE_CLICK_DROIT:
        
        Case BOUTON_DROIT_POUSSE:
        
        Case BOUTON_DROIT_LEVE:
            Me.PopupMenu mnsystray
    End Select
    rec = False
End If
End Sub

Renfield
Admin CodeS-SourceS- MVP Visual Basic

marcod59 · Answer

J'ai trouvé ce qui dérange. Sur ma form, j'ai mis un contrôle toolbar, et lorsque je l'enlève le clic sur l'icône fonctionne. Y a-t-il une façon de programmer le toolbar afin que le systray fonctionne correctement ?

@+++
marcod59

Renfield · Answer

faut voir comment est codé ton systray... et comment sont traités les messages de celui ci.

Renfield
Admin CodeS-SourceS- MVP Visual Basic

marcod59 · Answer

Voilà le code

Option Explicit


Private Type IconeTray
    cbSize As Long      'Taille de l'icône (en octets)
    hwnd As Long        'Handle de la fenêtre chargée de recevoir les messages envoyés lors des évènements sur l'icône (clics, doubles-clics...)
    uID As Long         'Identificateur de l'icône
    uFlags As Long
    uCallbackMessage As Long    'Messages à renvoyer
    hIcon As Long               'Handle de l'icône
    szTip As String * 64        'Texte à mettre dans la bulle d'aide
End Type
Dim IconeT As IconeTray




'Constantes nécessaires
Private Const AJOUT = &H0
Private Const MODIF = &H1
Private Const SUPPRIME = &H2
Private Const MOUSEMOVE = &H200
Private Const MESSAGE = &H1
Private Const Icone = &H2
Private Const TIP = &H4


Private Const DOUBLE_CLICK_GAUCHE = &H203
Private Const BOUTON_GAUCHE_POUSSE = &H201
Private Const BOUTON_GAUCHE_LEVE = &H202
Private Const DOUBLE_CLICK_DROIT = &H206
Private Const BOUTON_DROIT_POUSSE = &H204
Private Const BOUTON_DROIT_LEVE = &H205


'API nécessaire
Private Declare Function Shell_NotifyIcon Lib "shell32" Alias "Shell_NotifyIconA" (ByVal dwMessage As Long, pnid As IconeTray) As Boolean


Private Declare Function GetMenuItemCount Lib "user32" (ByVal hMenu As Long) As Long
Private Declare Function GetSystemMenu Lib "user32" (ByVal hwnd As Long, ByVal bRevert As Long) As Long
Private Declare Function DeleteMenu Lib "user32" (ByVal hMenu As Long, ByVal nPosition As Long, ByVal wFlags As Long) As Long
Private Declare Function DrawMenuBar Lib "user32" (ByVal hwnd As Long) As Long
Private Const SC_CLOSE As Long = &HF060&
Private Const MF_BYCOMMAND As Long = &H0&
Private Const MF_BYPOSITION = &H400&

Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
    On Error Resume Next
'Si la souris est sur la feuille et n'est pas sur un bouton, alors, retirer le cadre du bouton précédent,
Static rec As Boolean, msg As Long
'Se produit lorsque l'utilisateur agit avec la souris sur
'l'icône placée dans le système tray
msg = X / Screen.TwipsPerPixelX
If rec = False Then
    rec = True
    Select Case msg
        
        Case DOUBLE_CLICK_GAUCHE:
        
        Case BOUTON_GAUCHE_POUSSE:
        
        Case BOUTON_GAUCHE_LEVE:
            Me.PopupMenu mnsystray
            
        Case DOUBLE_CLICK_DROIT:
        
        Case BOUTON_DROIT_POUSSE:
        
        Case BOUTON_DROIT_LEVE:
            Me.PopupMenu mnsystray
    End Select
    rec = False
End If
End Sub

Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
IconeT.cbSize = Len(IconeT)
IconeT.hwnd = Me.hwnd
IconeT.uID = 1&
Shell_NotifyIcon SUPPRIME, IconeT
End Sub

Private Sub Form_Load()
Form1.Visible = False
'Grisage de la croix Quittre
Dim hSysMenu As Long
hSysMenu = GetSystemMenu(hwnd, False)
Call DeleteMenu(hSysMenu, SC_CLOSE, MF_BYCOMMAND)
Call DeleteMenu(hSysMenu, GetMenuItemCount(hSysMenu) - 1, MF_BYPOSITION)
Call DrawMenuBar(Me.hwnd)
'Fin Grisage
son = 1
'Préparation de la variable IconeT
IconeT.cbSize = Len(IconeT)                             'Taille de l'icône en octet
IconeT.hwnd = Me.hwnd                                   'Handle de l'application (pour qu'elle reçoive les messages envoyés lors d'un clic, double-clic...
IconeT.uID = 1&                                         'Identificateur de l'icône
IconeT.uFlags = Icone Or TIP Or MESSAGE
IconeT.uCallbackMessage = MOUSEMOVE                     'Renvoyer les messages concernant l'action de la souris
IconeT.hIcon = Me.Icon                                  'Utilise l'icone de la feuille
IconeT.szTip = "Alerte métro" & Chr$(0)          'Texte de la bulle d'aide


'Appel de la fonction pour mettre l'icône dans le système tray
Shell_NotifyIcon AJOUT, IconeT


'Cache la fenêtre
Me.Hide


'Retire le bouton de l'application de la barre des tâches
App.TaskVisible = False
Exit Sub
End Sub

Private Sub mnouvrir_Click()
Form1.Visible = True
End Sub
Private Sub mnquitter_Click()
    serveur.Close
IconeT.cbSize = Len(IconeT)
IconeT.hwnd = Me.hwnd
IconeT.uID = 1&
Shell_NotifyIcon SUPPRIME, IconeT
    End
End Sub

Voilà, rien de plus. Merci

@+++
marcod59

marcod59 · Answer

Salut Renfield,

Merci pour ta solution qui fonctionne à merveille.

Joyeuses Pâques à toi et à tous les membres.
@+++
marcod59

Problème de systray

5 réponses

Votre réponse

Discussions similaires