problème boucle while + doevent avec prog dans le systray

Question

bonsoir tt le monde!
 
alors voila mon probl&#232;me :

mon prog s'ex&#233;cute dans le systray et j'effectue une boucle while qui a pour sortie une interaction avec le menu deroulant du systray, le probl&#232;me c'est que je n'arrive pas &#224; entrer dans le menu, je n'ai pas la main malgr&#233; les doevents + sleep que j'ai pu mettre 
J'aimerais aussi ne pas avoir &#224; utiliser de threads, j'ai pas confiance niveau stabilit&#233; et compatibilit&#233; avec d'autres OS.
si quelqu'un a une petite id&#233;e &#231;a serait sympa de me donner un coup de pouce!!

cboulas · Answer

Salut, pourquoi ne pas utiliser un timer qui v&#233;rifierais une valeur boolean que la boucle d&#233;terminerais, exemple :


Dim Value as Boolean

Sub toto....
   do while
      if x=y then
         Value=True
         exit do
      end if
   loop
End Sub

Sub Timer......
   if Value then msgbox("Valeur &#224; True")
End sub


Parce que l&#224; vu que ta boucle tourne en rond, elle ne te laisse pas la main, car tu sature le proc.


Chris...
Web : Firstruner - eMail : [mailto:support@firstruner.com Support]&nbs

cs_casy · Answer

Regarde la source de Dark sur le systray tu trouvera peut-etre des r&#233;ponses

http://www.vbfrance.com/code.aspx?ID=27709



Il existe pr&#232;s d'une centaine de sources sur ce site traitant du
systray regarde-les, tu trouvera probablement un bug dans ton code.




 Si le cerveau &#233;tait assez simple pour que nous puissions le comprendre,

nous serions assez b&#234;te pour ne pas le comprendre malgr&#233; tout.

cs_CanisLupus · Answer

Salut,

Le menu affich&#233; dans le systray est celui d'une de tes forms (voire d'une mdiForm) il suffit, &#224; mon avis que tu joues avec la propi&#233;t&#233; visible des items de ce menu. Du genre : frm_Main.mnuOuvrir.Visible = false.

Loup Gris

crenaud76 · Answer

Des Doevents, je veux bine, cela va aider l'appli &#224; d&#233;tecter un evt, mais des Sleep !!! Cela va faire dormir ton appli et bloquer toute d&#233;tection d'EVT justment !! A banir dans une boucle interruptible par l'utilisateur !!!

Christophe R

mcleod06 · Answer

erf merci beaucoup pour vos r&#233;ponses mais ca marche toujours pas...si je mets un bouton &#224; l'ext&#233;rieur de mon icone systray j'arrive &#224; sortir de la boucle mais c'est l'interaction avec le systray qu'il n'arrive pas &#224; prendre en charge pourtant avant de lancer le prog, tout se passe bien, menu deroulant etc, mais des que je le lance plus possible de faire quoi que ce soit sur l'icone du systray :/
j'ai cherch&#233; dans les propri&#233;t&#233;s de ma form sans succ&#233;s et frm_Main.mnuOuvrir.Visible = false 
ne fait que rendre invisible mon menu ouvrir (je cherche mais je ne vois pas l'interet ^^)
desol&#233; de vous poser tant de probl&#233;mes mais je s&#232;che completement l&#224;, je vois pas de solutions &#224; part peut etre une propriete ou une fonction du systray que je ne connais pas.

cs_CanisLupus · Answer

Bon, alors un tit exemple que j'utilise :

Dans un module, tu colles &#231;a :

Private Const NIM_ADD = &H0
Private Const NIM_MODIFY = &H1
Private Const NIM_DELETE = &H2
Private Const NIF_MESSAGE = &H1
Private Const NIF_ICON = &H2
Private Const NIF_TIP = &H4
Private Const WM_MOUSEMOVE As Long = &H200
Private Const WM_LBUTTONDOWN = &H201
Private Const WM_LBUTTONDBLCLK = &H203
Private Const WM_RBUTTONUP = &H205


Private Type NOTIFYICONDATA
    cbSize As Long
    hwnd As Long
    uId As Long
    uFlags As Long
    ucallbackMessage As Long
    hIcon As Long
    szTip As String * 64
End Type


Private Declare Function SetForegroundWindow _
  Lib "user32.dll" _
    ( _
      ByVal hwnd As Long _
    ) As Long
    
Private Declare Function Shell_NotifyIcon _
  Lib "shell32" Alias "Shell_NotifyIconA" _
    ( _
      ByVal dwMessage As Long, _
      pnid As NOTIFYICONDATA _
    ) As Boolean
    
Private nid As NOTIFYICONDATA


Public Sub Creation_TrayIcon()


  ' D&#233;finition des options de l'icone Tray
  With nid
    .cbSize = Len(nid)
    .hwnd = frm_Main.hwnd
    .uId = vbNull
    .uFlags = NIF_ICON Or NIF_TIP Or NIF_MESSAGE
    .ucallbackMessage = WM_MOUSEMOVE
    .hIcon = frm_Main.Icon
    .szTip = "Programme en cours d'ex&#233;cution" & vbNullChar
  End With
  
  ' Cr&#233;er l'icone Tray
  Shell_NotifyIcon NIM_ADD, nid


End Sub


Public Sub Ouvrir_Fermer(Etat As Boolean)


  frm_Main.mnuOuvrir.Visible = Not Etat
  frm_Main.mnuFermer.Visible = Etat
  frm_Main.Visible = Etat
  
End Sub


Public Sub Continuer_Suspendre(Etat As Boolean)


  frm_Main.mnuContinuer.Visible = Not Etat
  frm_Main.mnuSuspendre.Visible = Etat
  
  nid.szTip = IIf(Etat, "Le programme est en cours d'ex&#233;cution" & vbNullChar, "Le programme est suspendu" & vbNullChar)
  
  Shell_NotifyIcon NIM_MODIFY, nid


End Sub


' R&#233;ception des appels en provenance de l'icone Tray
Public Sub Appels_Tray(X As Single)
  
  ' La valeur de X peux varier suivant le choix du scalemode
  Select Case IIf(frm_Main.ScaleMode = vbPixels, X, X / Screen.TwipsPerPixelX)
    Case WM_RBUTTONUP 'Afficher le menu contextuel
      SetForegroundWindow frm_Main.hwnd
      frm_Main.PopupMenu frm_Main.mnuSysTray
    Case WM_LBUTTONDBLCLK 'Afficher la fenetre
      Ouvrir_Fermer True
  End Select


End Sub


Public Sub Kill_Icone_Tray()
  Shell_NotifyIcon NIM_DELETE, nid
End Sub

Public Sub Quitter()


  If (MsgBox("Voulez-vous vraiment quitter l'application ?", vbQuestion + vbYesNo + vbDefaultButton2, "") = vbYes) Then
    Unload frm_Main
  End If
  
End Sub
Et dans un form (frm_Main pour l'exemple) tu cr&#233;es un menu "SysTray" (mnuSysTray) avec visible false avec les items "Ouvrir" (mnuOuvrir, visible true), "Fermer" (mnuFermer, visible = false), "Suspendre" (mnuSuspendre, visible = true), "Continuer" (mnuContinuer, visible = false), "Quitter" (mnuQuitter, visible = true). Bien entendu, tous sont enable = true.

Code des diff&#233;rents items :

Private Sub mnuOuvrir_Click()
  Ouvrir_Fermer True
End Sub


Private Sub mnuFermer_Click()
  Ouvrir_Fermer False
End Sub


Private Sub mnuContinuer_Click()
  Continuer_Suspendre True
End Sub


Private Sub mnuSuspendre_Click()
  Continuer_Suspendre False
End Sub


Private Sub mnuQuitter_Click()
  Quitter
End Sub

Et, pour terminer :

Private Sub Form_Unload(Cancel As Integer)
  Kill_Icone_Tray
End Sub

J'esp&#232;re que &#231;a t'aidera.

Loup Gris

Problème boucle while + doevent avec prog dans le systray

6 réponses

Discussions similaires