resolution

Question

y a-t-il une facon, lors de l'ouverture de l'application, de definir la resolution de l'ecran de l'utilisateur?

Merci d'avance. Vous me conseillez trop bien, j'ai l'impression d'abuser  :blush)

Radiohead4ever · Answer

PS: je parle de visual basic

Tilois · Answer

tiens voila une source qui devrait d'aider!
http://www.vbfrance.com/code.aspx?ID=7468

Radiohead4ever · Answer

%-6  Ca pas de sens comme c'est compliqué !!!
Je dois avoir passé 1h 15 a scruter les codes mais j'arrive pas a trouver quel code dit tout simplement de mettre la resolution en 1024 x 720... au fond c'est tout ce que je veux savoir. Ensuite, je mettrais ce code dans le form load de mon jeu et tout serais ok. J'ai pas besoin de toutes ces conditions...

Tilois · Answer

Dans un module:

Public Declare Function ChangeDisplaySettings Lib "user32" Alias "ChangeDisplaySettingsA" (lpDevMode As Any, ByVal dwFlags As Long) As Long
Public Declare Function EnumDisplaySettings Lib "user32" Alias "EnumDisplaySettingsA" (ByVal lpszDeviceName As Long, ByVal iModeNum As Long, lpDevMode As Any) As Boolean
Public Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long

Public Const DM_WIDTH = &H80000
Public Const DM_HEIGHT = &H100000
Public Const WM_DEVMODECHANGE = &H1B
Public Const HWND_BROADCAST = &HFFFF&
Public Const CCHDEVICENAME = 32
Public Const CCHFORMNAME = 32
Public Const DM_BITSPERPEL = &H40000
Public Const DM_DISPLAYFREQUENCY = &H400000

Public Type DEVMODE
    dmDeviceName As String * CCHDEVICENAME
    dmSpecVersion As Integer
    dmDriverVersion As Integer
    dmSize As Integer
    dmDriverExtra As Integer
    dmFields As Long
    dmOrientation As Integer
    dmPaperSize As Integer
    dmPaperLength As Integer
    dmPaperWidth As Integer
    dmScale As Integer
    dmCopies As Integer
    dmDefaultSource As Integer
    dmPrintQuality As Integer
    dmColor As Integer
    dmDuplex As Integer
    dmYResolution As Integer
    dmTTOption As Integer
    dmCollate As Integer
    dmFormName As String * CCHFORMNAME
    dmUnusedPadding As Integer
    dmBitsPerPel As Integer
    dmPelsWidth As Long
    dmPelsHeight As Long
    dmDisplayFlags As Long
    dmDisplayFrequency As Long
End Type

Public dmEcran                  As DEVMODE

Public Sub ResolutionEcran(Largeur As Single, Hauteur As Single, Profondeur As Integer, Frequence As Integer)
Dim blTMP As Boolean
Dim lgTmp As Long
lgTmp = 0
Do
    blTMP = EnumDisplaySettings(0, lgTmp, dmEcran)
    lgTmp = lgTmp + 1
Loop Until Not blTMP
dmEcran.dmFields = DM_WIDTH Or DM_HEIGHT Or DM_BITSPERPEL Or DM_DISPLAYFREQUENCY
dmEcran.dmPelsWidth = Largeur
dmEcran.dmPelsHeight = Hauteur
dmEcran.dmBitsPerPel = Profondeur
dmEcran.dmDisplayFrequency = Frequence
lgTmp = ChangeDisplaySettings(dmEcran, 0)
Call SendMessage(HWND_BROADCAST, WM_DEVMODECHANGE, 0, 0)
End Sub

Et l'appel
ResolutionEcran 1024,768,16,72

->donne du 1024*768 16bits de couleur et 72Hz

Radiohead4ever · Answer

wow ! jte remerci. Sa marche  :big)  sauf que des fois je me dis que la programmation c peut-être un peu trop compliquer pour moi. c pas que je suis con, c'est juste que je passe pas assez de temps la dessus. enfin.. merci  encore|

Resolution

5 réponses

Discussions similaires