Executable à partir d'un hwnd ?

Question

Salut ;)

Voila par exemple j'ai winamp de lancé donc je recup son hwnd, titre de fenetre et nom de tache mais j'arrive pas a récuperer le nom de l'executable cad :

c:\program files\winamp\winamp.exe

qqu'un sait comemnt faire ?

cs_ludo24 · Answer

Est-ce que "PROCESSENTRY32" te dit qqch?

je pense que la variable "szExeFile" t'interessera.

Va voir là: http://msdn.microsoft.com/library/default.asp?url=/library/en-us/wcekernl/html/_wcesdk_win95_PROCESSENTRY32_str.asp

La fonction Windows "CreateToolhelpSnapshot" te sera aussi nécessaire.

Recontacte-moi en cas de probleme.

J'ai aussi filé un bout de code intéressant à qqn ds le forum qui cherchait comment savoir si un process etait actif. 9a pourrait aussi t'etre utile.

cs_Esquisse · Answer

Merci pour une réponse aussi rapide mais ca m'aide pas trop :/

En fait, grace à toi,  je trouve les noms des exe lancés... Mais je ne voit pas comment trouver un lien entre les api de process vers ceux de fenetres (ceux que j'ai : handle, Nom fenetre, ID app)...

Car dans les process comme c ecrit dans la MSDN ce sont des pseudohandle et (forcement) ils correspondent pas aux handle des fenetres.

Qqu'un connait une fonction qui pourrait faire le rapprochement entre un process et un handle (ou une autre voie de recherche) ?

cs_magma · Answer

Essaie la fonction GetModuleFileName(...)

cs_Esquisse · Answer

grr ca marche toujours pas. je doit pas être loin mais ca renvoie toujours c:\program files\...\vb6.exe :'(

Je mets un bout de code commenté et simplifié pour savoir ou est-ce que je fait une erreur (note faut que winamp 3.x soit lancer pour recup le hwnd) :

'Mes déclarations dans un module :
'Public Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long) As Long
'Public Declare Function GetModuleFileName Lib "kernel32" Alias "GetModuleFileNameA" (ByVal hModule As Long, ByVal lpFileName As String, ByVal nSize As Long) As Long
'Public Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
'Public Const GWL_HINSTANCE = (-6)

'Le code
Dim ModuleName As String
Dim FileName As String
Dim hInst As Long
Dim WinAMPHwnd As Long

'Je récupe le hwnd de Winamp
WinAMPHwnd = FindWindow("STUDIO", vbNullString)

'Formatte variables
ModuleName = String$(128, Chr$(0))

'Recup l'instance de winamp
hInst = GetWindowLong(WinAMPHwnd, GWL_HINSTANCE)

'Récup le nom de l'exe (du moins essaie :))
ModuleName = Left$(ModuleName, GetModuleFileName(hInst, ModuleName, Len(ModuleName)))
    
'Affiche
MsgBox "Module Filename : " + ModuleName

cs_magma · Answer

Essaie la fonction FindFirstFile( ... )

cs_Esquisse · Answer

euh aucun rapport avec ce dont j'ai besoin... Winamp est un exemple de programme (je ne sias pas quel prog ca peut-être... j'ai mit Winamp pour mon exemple)

cs_Esquisse · Answer

J'ai trouvé la solution :)

Je la mets au cas ou ca peux aider qqu'un :)

Dans un module :

Public Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Public Declare Function GetWindowThreadProcessId Lib "user32" (ByVal hwnd As Long, lpdwProcessId As Long) As Long
Public Declare Function CreateToolhelp32Snapshot Lib "Kernel32" (ByVal lFlags As Long, ByVal lProcessID As Long) As Long
Public Declare Function Process32First Lib "Kernel32" (ByVal hSnapShot As Long, uProcess As PROCESSENTRY32) As Long
Public Declare Function Process32Next Lib "Kernel32" (ByVal hSnapShot As Long, uProcess As PROCESSENTRY32) As Long
Public Declare Sub CloseHandle Lib "Kernel32" (ByVal hPass As Long)

Public Const TH32CS_SNAPHEAPLIST = &H1
Public Const TH32CS_SNAPPROCESS = &H2
Public Const TH32CS_SNAPTHREAD = &H4
Public Const TH32CS_SNAPMODULE = &H8
Public Const TH32CS_SNAPALL = (TH32CS_SNAPHEAPLIST Or TH32CS_SNAPPROCESS Or TH32CS_SNAPTHREAD Or TH32CS_SNAPMODULE)
Public Const TH32CS_INHERIT = &H80000000
Public Const MAX_PATH As Integer = 260

Public Type PROCESSENTRY32
    dwSize As Long
    cntUsage As Long
    th32ProcessID As Long
    th32DefaultHeapID As Long
    th32ModuleID As Long
    cntThreads As Long
    th32ParentProcessID As Long
    pcPriClassBase As Long
    dwFlags As Long
    szExeFile As String * MAX_PATH
End Type

Code : 

Dim ModuleName As String
Dim FileName As String
Dim hInst As Long
Dim WinAMPHwnd As Long
Dim ProcessID As Long
Dim hSnapShot As Long
Dim uProcess As PROCESSENTRY32
Dim r As Boolean

'Je récupe le hwnd de Winamp
WinAMPHwnd = FindWindow("STUDIO", vbNullString)

GetWindowThreadProcessId WinAMPHwnd, ProcessID

hSnapShot = CreateToolhelp32Snapshot(TH32CS_SNAPALL, 0&)
uProcess.dwSize = Len(uProcess)
r = Process32First(hSnapShot, uProcess)
Do While r

    If ProcessID = uProcess.th32ProcessID Then
        FileName = Left$(uProcess.szExeFile, IIf(InStr(1, uProcess.szExeFile, Chr$(0)) > 0, InStr(1, uProcess.szExeFile, Chr$(0)) - 1, 0))
        Exit Do
    End If
    r = Process32Next(hSnapShot, uProcess)
Loop

CloseHandle hSnapShot

MsgBox "Module Filename : " + FileName

Executable à partir d'un hwnd ?

7 réponses

Discussions similaires