Marquise de sélection

Question

Comment faire pour dessiner une marquise de sélection?
(pas de bidouille avec un objet shape en pointillé SVP, une vraie marquise)

merci d avance

MrDogbert

Delbeke · Answer

Désolé je ne sais pas ce qu'est une marquise de sélection

Jean-Luc

MrDogbert · Answer

l espece de rectangle en pointillés qui te permet de sélectionner tes icones sur le bureau par exemple.

MrDogbert

Delbeke · Answer

On utilise l'api DrawFocusRect

Pace un picturebox sur une feuille 
puis colle le source suivant

Option Explicit
Private Type RECT
    Left As Long
    Top As Long
    Right As Long
    Bottom As Long
End Type
Private Declare Function DrawFocusRect Lib "user32" (ByVal hdc As Long, lpRect As RECT) As Long

Dim DrawRct As RECT
Dim Drawing As Boolean

Private Sub Form_Load()
  Picture1.AutoRedraw = False
  Picture1.ScaleMode = vbPixels
End Sub

Private Sub Picture1_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
  Dim lRet As Long
  If (Button And 1) = 1 Then
    DrawRct.Left = X
    DrawRct.Top = Y
    DrawRct.Right = X
    DrawRct.Bottom = Y
    lRet = DrawFocusRect(Picture1.hdc, DrawRct)
    Drawing = True
  End If
End Sub

Private Sub Picture1_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
  Dim lRet As Long
  If Drawing Then
    lRet = DrawFocusRect(Picture1.hdc, DrawRct)
    DrawRct.Right = X
    DrawRct.Bottom = Y
    lRet = DrawFocusRect(Picture1.hdc, DrawRct)
  End If
End Sub

Private Sub Picture1_MouseUp(Button As Integer, Shift As Integer, X As Single, Y As Single)
  Dim lRet As Long
  If Drawing Then
    lRet = DrawFocusRect(Picture1.hdc, DrawRct)
    Drawing = False
  End If
End Sub

Jean-Luc

MrDogbert · Answer

Merci bien

MrDogbert

Silmon · Answer

Je cherche le moyen de dessiner un focus (avec ou sans DrawFocusRect) dans un control, par exemple un bouton, une FlexGrid.

QQ a une idée SVP?

Marquise de sélection

5 réponses

Discussions similaires