enregistrer le contenu d'un textbox

Question

bon
j'aimerais savoir comment enregistrer le contenue d'un textbox en .txt en cliquant sur un command1, et que l'utilisateur a le choix d'enregistrer le fichier dans n'importe quel dossier de ton pc.
merci

shtroumf

NitRic · Answer

Pour commencer va dans le menu Project/Components... et sélectionne Microsoft Common Dialog ... ensuite ajoute le sur ta Form et voila le code:

Private Sub Command1_Click()

Dim lFile As Integer

On Error Resume Next ' Si erreur, on continue...

With CommonDialog1

' Pouvoir intercepter les erreurs
.CancelError = True
' Titre de la boîte de dialogue
.DialogTitle = "Enregistrer sous..."
' Type de fichier
.Filter = "Fichier Texte (*.txt)|*.txt|Tous les fichiers (*.*)|*.*|"
' Type de fichier sélectionner par defaut
.FilterIndex = 1
' Répertoire de départ
.InitDir = CurDir

' Clear les erreurs
Err.Clear
' Ouvre la boîte de dialogue
.ShowSave

End With

' Si aucune erreur et qu'un nom de fichier à été inscrit
If (Err.Number = 0 And .Filename <> "") Then

' Vérifie si le fichier existe déjà
If Dir$(.Filename) <> "" Then

' Le fichier existe, demande à l'utilisateur s'il veut le remplacer
If MsgBox("Le fichier " & .Filename & " existe déjà, voulez-vous le remplacer?", vbYesNo + vbQuestion, "Fichier Existe") <> vbYes Then
' Il ne veut pas le remplacer, alors on quitte
Exit Sub
End If

End If

' Demande un numéro de fichier non utiliser
lFile = FreeFile
' Ouvre le fichier en écriture seulement
Open .Filename For Output As #lFile

' Sauvegarde le texte du TextBox Text1
Print #lFile, Text1.Text;

' Ferme le fichier(important)
Close #lFile

End If

End Sub

[mailto:VB__MAN@Hotmail.com VB_MAN]

NitRic · Answer

Une erreur, met le  "End With" juste avant le  "End Sub", désoler :|

Enregistrer le contenu d'un textbox

2 réponses

Discussions similaires