Doublon et listbox

Question

Bonjour tout le monde

Serait-il possible que quelqu'un m'aide, j'ai un petit probleme, lors d'ajout d'item dans une listbox j'aurais besoin d'un controle pour éviter de saisir deux fois le même item. une source est déjà presente sur le forum et hélas elle ne fonctionne pas.

Amicalement FrostByte

stevebelgium · Answer

et comme ca ? trop simple ?

tu a besoin 1 listbox :

Private Sub Command1_Click()
    
    add_item Me.List1, "test"
    add_item Me.List1, "a"
    add_item Me.List1, "test"
    
End Sub
Sub add_item(list_box As ListBox, the_item As String)
    
    Dim is_in_list As Boolean
    Dim x As Integer
    
    is_in_list = False
    
    For x = 0 To list_box.ListCount - 1
        If list_box.List(x) = the_item Then
            is_in_list = True
            Exit For
        End If
    Next x
    
    If is_in_list = False Then
        list_box.AddItem the_item
    Else
        MsgBox the_item & " : already in " & list_box.Name
    End If

End Sub

Renfield · Answer

ou encore les API........


Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As String) As Long
Private Const LB_FINDSTRINGEXACT = &H1A2

Private Sub Form_Load()
    AjouteItem List1, "test"
    AjouteItem List1, "a"
    AjouteItem List1, "test"
End Sub

Public Sub AjouteItem(ListBox As ListBox, Item As String, Optional EmpecheDoublons As Boolean = True)
    Dim Id
    Id = GetIndex(ListBox, Item)
    If Not EmpecheDoublons Or Not (EmpecheDoublons And Id <> -1) Then
        ListBox.AddItem (Item)
    End If
End Sub

Function GetIndex(ListBox As ListBox, Item As String) As Long
    'renvoie l'inddice de l'item dans le listbox. -1 si non trouvé.
    ' le parametre -1 donne l'indice de depart , utilisé dans la recherche.
    GetIndex = SendMessage(ListBox.hwnd, LB_FINDSTRINGEXACT, -1, Item)
End Function


-----------------------------------------------------------------------
By Renfield

thomas_reynald@msn.com

Aucune touche n'a été bléssée lors de la saisie de ce texte..........

cs_Chewba · Answer

Bon petit bout de code, très utile
Merci

Doublon et listbox

3 réponses

Discussions similaires