Comment tester si une table existante dans une base Access ? Résolu

Question

Je voudrais &#233;crire un code pour savoir si la table "toto" existe dans la base "MaBase".

Et si la r&#233;ponse est non, je voudrais cr&#233;er la table "toto" en sp&#233;cifiant les champs et le type de donn&#233;es.

Pouvez-vous m'aider ?
Merci de tout coeur.

Benedict

cs_CanisLupus · Accepted Answer

OK, donc essaie &#231;a :

' Coche Microsoft ADO Ext .... dans les r&#233;f&#233;rences du projet
Function ExistTable(strNomTable As String) As Boolean


   Dim cat As New ADOX.Catalog
   Dim tbl As ADOX.Table
   
   ' Ouverture du catalogue
   cat.Activeconnection = "Provider=Microsoft.Jet.OLEDB.4.0;" & "Data Source=TaBase.mdb;"
   
   'parcours de la collection de tables
   For Each tbl In cat.Tables
      If tbl.Name = strNomTable Then
        ExistTable = True
        Exit Function
      End If
   Next
   
   ExistTable = False
   
End Function

-------------------------------------------------
Dresseur de puces, .... normal pour un loup  !?

jhary69 · Answer

salut,

Function IsTableExiste(ByVal strNomTable As String) As Boolean
   Dim tblTemp As TableDef
   
   On Error GoTo err_IsTableExiste


    Set tblTemp = CurrentDb.TableDefs(strNomTable)
    IsTableExiste = True
    
   Exit Function
err_IsTableExiste:
   If Err.Number = 3265 Then ' element non trouv&#233; dans la collection
     IsTableExiste = False
   Else
        ' gerer l'erreur inconnue
   End If
End Function

A+

Christophe.

cs_CanisLupus · Answer

Salut,
Qu'utilise-tu pour interroger ta base ? DAO, ADO ?

-------------------------------------------------
Dresseur de puces, .... normal pour un loup  !?

cs_CanisLupus · Answer

Je me permettrais tout de m&#234;me de reprendre le code de jhary69 car je n'aime pas trop les on error quand ce n'est pas n&#233;cessaire :

Function IsTableExiste(ByVal strNomTable As String) As Boolean
Dim tblTemp As TableDef
  
  For Each tblTemp In CurrentDb.TableDefs
    If tblTemp.Name = strNomTable Then
      IsTableExiste = True
      Exit Function
    End If
  Next
   
  IsTableExiste = False


End Function

-------------------------------------------------
Dresseur de puces, .... normal pour un loup  !?

cs_benedict · Answer

Dresseur de puce,

J'utilise ADO

Benedict

cs_benedict · Answer

Merci CanisLupus.


Une autre puce &#224; dompter.

 Comment faire pour tester si un champ "titi" existe dans la table "toto" ?

Merci.

Benedict

jhary69 · Answer

re,

pour le test de l'existance d'une table effectivement si tu as peu de tables, le for each est tout aussi rapide par contre dans une bdd avec beaucoup de tables (des centaines) ca commence a etre long le parcours 

pour le test de l'existance d'un champ on adapte le code de CanisLupus (ou tu adaptes le mien ...)

je crois me souvenir qu'en adox c'est la collection columns qui represente les champs d'une table ... du coup ca donne :

Function ExistChamp(ByVal strNomTable As String, ByVal strNomChamp As String) As Boolean
   Dim cat As New ADOX.Catalog
   Dim tbl As ADOX.Table
   Dim col As ADOX.Column
   
   ExistChamp = False
   
   ' Ouverture du catalogue
   cat.Activeconnection = "Provider=Microsoft.Jet.OLEDB.4.0;" & "Data Source=TaBase.mdb;"
   
   Set tbl = cat.Tables(strNomTable)
   
   'parcours de la collection de colonnes
   For Each col In tbl.Columns
      If col.Name = strNomChamp Then
        ExistChamp = True
        Exit For
      End If
   Next
   
   Set tbl = Nothing
   
End Function

cs_CanisLupus · Answer

Jhary69 > d'abord, rien &#224; dire sur ton exemple pour les champs sauf que c'est correct.
 Par contre, une base access contenant "des centaines de tables", c'est peu vraisemblable. Sinon, c'est une base mal construite et/ou c'est une "usine &#224; gaz". 
J'ai eu &#224; bosser sur des bases "portail" avec des tables ou requetes attach&#233;es dans tous les sens (c'est la gal&#232;re) mais je n'ai jamais eu affaire &#224; "des centaines de tables" sauf dans un cas ou j'ai &#233;t&#233; oblig&#233; de reconstruire tout. 
Mais admettons. Dans ce cas,  le for each n'est pas beaucoup plus lent que le on error qui, mal utilis&#233; peut provoquer d'autres bugs, et c'est beaucoup plus propre.

-------------------------------------------------
Dresseur de puces, .... normal pour un loup  !?

jhary69 · Answer

re,

oki, faut dire que je suis habitu&#233; aux usines &#224; gaz sur Access voir meme sur Excel  !

A+

Christophe.

cs_benedict · Answer

D&#233;sol&#233; de vous emb&#233;ter, les amis, mais j'ai un probl&#232;me.

J'ai bien d&#233;clar&#233; la fonction ExistChamp et j'ai cr&#233;&#233; un bouton avec le code suivant :

Sub Command1_Click()
    ExistChamp=(strNomTable: = "toto", strNomChamp:= "titi")
End Sub

Ca ne marche pas.
J'ai "erreur de syntaxe : attendu )"

Quel est le code correct pour tester si dans la table "toto" il y a bien un champ "titi"

Benedict

jhary69 · Answer

re,

il y a une erreur sur ta ligne de code :

ExistChamp=(strNomTable: = "toto", strNomChamp:= "titi") ==>syntaxe incorrecte
bRet ExistChamp(strNomTable: "toto", strNomChamp:= "titi") ==> ca devrait mieux marcher comme ca ...

A+

Christophe.

Comment tester si une table existante dans une base Access ?

11 réponses

Discussions similaires