Valeurs d'un Userform contenu dans une variable Résolu

Question

Bonsoir,

J'ai créé une fonction publique pour tester si tous les champs de mes userforms ont été remplis. Et je suis totalememt bloqué car lors de l'exécution de la fonction, d'après celle-ci tous les contrôles sont vides...

Je suis perdu...


Voici le code!

Public Function Fields_Check(ActiveUserForm As String)

'Définit les variables
Dim MyControls As Control

'Teste si tout les champs sont remplis
For Each MyControls In VBA.UserForms.Add(ActiveUserForm).Controls
    If TypeOf MyControls Is msforms.TextBox Then
        If MyControls.Value = "" Then
            MsgBox "Veuillez remplir tous les champs", vbExclamation + vbOKOnly + vbApplicationModal, "Informations"
            Arret = True
            Exit Function
        End If
    End If
    If TypeOf MyControls Is msforms.ComboBox Then
        If MyControls.Value = "" Then
            MsgBox "Veuillez remplir tous les champs", vbExclamation + vbOKOnly + vbApplicationModal, "Informations"
            Arret = True
            Exit Function
        End If
    End If
    If TypeOf MyControls Is DTPicker Then
        If MyControls.Value = "" Then
            MsgBox "Veuillez remplir tous les champs", vbExclamation + vbOKOnly + vbApplicationModal, "Informations"
            Arret = True
            Exit Function
        End If
    End If
Next

End Function


Le Mycontrols.value ne retourne rien même s'ils sont remplis! (la fonction se trouve dans un module séparé des userforms)

Merci pour votre aide!

cs_Ayr · Accepted Answer

Bonsoir,

Essaye ça :

Public Function Fields_Check(ByVal MyUserForm As UserForm) As Boolean
  Dim FieldsOk As Boolean
  FieldsOk = True
  On Error Resume Next
  For Each MyControl In MyUserForm.Controls
    If MyControl.Value = "" Then
        MsgBox "Veuillez remplir tous les champs", vbOKOnly, "Informations"
        FieldsOk = False
        Exit For
    End If
  Next ctl
  On Error GoTo 0
  Fields_Check = FieldsOk
End Function

Il faut passer directement le UserForm Concerné à la fonction et elle retourne True si les champs sont remplis et Faux sinon.

PS: Elle traite tout les controles et si un n'a pas de propriété Value, l'erreur qui aurait été générée est ignorée grace à la ligne On Error Resume Next.

A+

cs_Ayr · Answer

Arrgggg !!!! J'ai oublié une ligne !!!!

La définition de MyControl...

Dim MyControl As Control
A ajouter avant ou après Dim FieldsOk As Boolean


Mais tu l'avais fait dans ta fonction.

J'en profite pour (me ) rappeler qu'il vaut mieux mettre Option Explicit en tête de module pour s'obliger à déclarer les variables...

Amartin6 · Answer

Merci Ayr! Ca marche à merveille, j'avais pas pensé à déclarer la variable en tant que UserForm,... ;-) Mais là ça m'a éviter de passer une deuxième nuit blanche...

Merci encore!

cs_Ayr · Answer

Ha ben ça fait plaisir, si je comprend bien, je suis aussi efficace qu'un somnifère 

Bonne Nuit alors

mammien · Answer

Salut,

Suite aux infos de ayr, me voilà! Je prends le code, je le copie ailleurs sur mon programme et j'essai d'appeler la fonction... C'est ça la procédure?

cs_Ayr · Answer

Bonjour,

oui, tu peux commencer par ça mais je te propose de continuer la discussion sur ton propre sujet.

A+

cs_Ayr · Answer

Je reviens pour dire que la fonction que j'ai proposé est à peu près, complètement foireuse 

Et si elle marche c'est dans des cas particuliers. La gestion d'erreur est mal faites et de plus des objets autres que combo, textbox et autres objets de saisie on une propriété value et pourrai être pris en compte alors qu'il ne le devraient pas...
Il y avait aussi une petite erreur à la fin du next...

Promis je me fouetterai plus tard mais pour l'instant je voudrait proposer une correction. Donc, plus de gestion d'erreur mais un controle du type des objets testés, comme tu le proposai Amartin6.


Public Function Fields_Check(ByVal MyUserForm As UserForm) As Boolean
  Dim FieldsOk As Boolean
  Dim MyControl As Control
  FieldsOk = True
  For Each MyControl In MyUserForm.Controls
    If TypeOf MyControl Is msforms.TextBox Or TypeOf MyControl Is msforms.ComboBox Then
        If MyControl.Value = "" Then
            MsgBox "Veuillez remplir tous les champs", vbOKOnly, "Informations"
            FieldsOk = False
            Exit For
        End If
    End If
  Next MyControl
  Fields_Check = FieldsOk
End Function


Je te laisse le soin de d'ajouter au test du type d'objets, ceux que tu veux prendre en compte aussi. Notamment le DatePicker.

Voilà, encore désolé de ne pas avoir mieux contôlé mon code et en espérant que celle-ci soit plus sur.

Valeurs d'un Userform contenu dans une variable

7 réponses

Votre réponse

Discussions similaires