ereur commande set

Question

Bonjour, 
j'ai une ereur au moment de la commande Set sur ce script, vous seriez m'aidé?:

Option explicit
On Error Resume Next
Const ONE_HOUR = 3600000
dim ObjWMIService
dim ObjProcess
dim i

Set ObjWMIService = GetObject("winmgmts:") _
    & .ExecQuery _
    ("SELECT * FROM Win32_Process")
for i = 1 to 8
for each ObjProcess in ObjWMIService
        WSCript.Echo Now
        WSCript.Echo ""
        WScript.Echo "Process: " & ObjProcess.name
        WScript.Echo "Process ID: " & ObjProcess.ProcessID
        WScript.Echo "Thread Count: " & ObjProcess.ThreadCount
        WScript.Echo "Page File Size: " & ObjProcess.PageFileUsage
        WScript.Echo "Page Faults: " & ObjProcess.PageFaults
        WScript.Echo "Working Set Size: " & ObjProcess.WorkingSetSize
Next
WScript.Echo "*****PASS COMPLETE*******"
WScript.Sleep ONE_HOUR
next

en fait je voudrais qu'il ait me chercher les processus dans win 32 mais vue qu'il bloque sur "set" il ne renvoit rien quand il vas chercher dans la collection ObjWMIService, il m'affiche l'heure, la fenetre vide et pass complete mais rien de plus car la commande set ne fonctionne pas.
Savez-vous d'ou sa peut venir, merci d'avance.

kipetro debutant.

kipetro · Answer

Je viens de trouvé, mais disons que c'étais pas simple en fin il fallait que je rajoute 
"{impersonationLevel=impersonate}" dans la commande set, enfin sa fait:
Option explicit
On Error Resume Next
Const ONE_HOUR = 3600000
dim ObjWMIService
dim ObjProcess
dim i

Set ObjWMIService = GetObject("winmgmts:" _
    & "{impersonationLevel=impersonate}").ExecQuery _
    ("SELECT * FROM Win32_Process")
for i = 1 to 8
for each ObjProcess in ObjWMIService
        WSCript.Echo Now
        WSCript.Echo ""
        WScript.Echo "Process: " & ObjProcess.name
        WScript.Echo "Process ID: " & ObjProcess.ProcessID
        WScript.Echo "Thread Count: " & ObjProcess.ThreadCount
        WScript.Echo "Page File Size: " & ObjProcess.PageFileUsage
        WScript.Echo "Page Faults: " & ObjProcess.PageFaults
        WScript.Echo "Working Set Size: " & ObjProcess.WorkingSetSize
Next
WScript.Echo "*****PASS COMPLETE*******"
WScript.Sleep ONE_HOUR
next

enfin sa marche mais j'aimerais finalement qu'en sorti sa parte dans un document texte, vous pouvez m'aidé.

kipetro debutant.

cs_JMO · Answer

Bonsoir,

En utilisant l'objet FSO:

Set objFso = CreateObject("Scripting.FileSystemObject")
Set objFile = objFso.OpenTextFile("c:\processes.txt", 2, True) 

Set objWMIService = GetObject("winmgmts:" _
    & "{impersonationLevel=impersonate}").ExecQuery _
    ("SELECT * FROM Win32_Process")

With objFile
     For i = 1 to 8
         For each ObjProcess in objWMIService
            .WriteLine Now
            .WriteLine ""
            .WriteLine "Process: " & objProcess.name
            .WriteLine "Process ID: " & objProcess.ProcessID
            .WriteLine "Thread Count: " & objProcess.ThreadCount
            .WriteLine "Page File Size: " & objProcess.PageFileUsage
            .WriteLine "Page Faults: " & objProcess.PageFaults
            .WriteLine "Working Set Size: " & objProcess.WorkingSetSize
         Next
     Next
    .Close
End With
Set objFso = Nothing
Set objFile = Nothing
Set objWMIService = Nothing

jean-marc

kipetro · Answer

Merci, c'est genial je vais regardé de plus pres, sa devrait me plaire, en tous cas sa marche.

kipetro debutant.

Ereur commande set

3 réponses

Votre réponse

Discussions similaires