Creer un menuRésolu

Question

Bonjour,

Je vous explique mon probl&#232;me :
J'ai cr&#233;e une macro que je voudrai d&#233;ployer sur plusieurs postes. Pour cela, j'ai cr&#233;e un .xla et je voudrai dans xla rajouter une proc&#233;dure qui me fabrique un menu (a cot&#233; du menu "aide") et dans lequel je glisserai un bouton qui lancerai la macro.

La seule chose que j'arrive a faire est une barre d'outil flotante qui se trouve en plein milieu de la feuille de calcul. Quelqu'un peut il m'aider svp ??

Merci d'avance....

Ci dessous le code pour la barre d'outil que j'arrive &#224; faire :
Sub CreeBO()


Dim MonMenu
Dim MonBouton


On Error Resume Next


Set MonMenu = Application.MenuBars.Add("Prelevement")


With MonMenu
       
   Set MonBouton = .Controls.Add(msoControlButton)
    
   With MonBouton
       .FaceId = 29
       .OnAction = "Macro1"
   End With
    
    .Visible = True
End With
End Sub

Nag

Utilisateur anonyme · Accepted Answer

Bonjour,



Voil&#224;, un code pour cr&#233;e un menu avec un bouton dans ce menu



Sub CreeBO()

  

  Dim MonMenu As CommandBarPopup

  Dim MonBouton As CommandBarButton

  

  Set MonMenu = Application.CommandBars("Worksheet Menu Bar").Controls.Add(msoControlPopup)

  MonMenu.Caption = "Prelevement"

  

  Set MonBouton = MonMenu.Controls.Add(msoControlButton)

  MonBouton.Caption = "MyBtn"

  MonBouton.FaceId = 29

  MonBouton.OnAction = "Macro1"



End Sub



ChRB



<hr size="2" width="100%">
Merci de cliquer sur "R&#233;ponse accept&#233;e" si une r&#233;ponse vous convient.

nagattaque · Answer

Niquel tout ca.... Ca marche tr&#232;s tr&#232;s bien....

Bon je vais pousser le visse un peu plus loin maintenant :
 - Comment tester si la barre est pr&#233;sente ?
 - Comment la supprimer ?

Merci encore (apres promis j'embette plus !)

Nag

Utilisateur anonyme · Answer

Bonjour,



Au contraire, tu ne m&#146;emb&#234;tes pas du tout.

Voil&#224;, la fonction MenuExist renvoie si le menu sp&#233;cifi&#233; existe, la DeleteMenu le supprime





Option Explicit



Private Const MnuCaption As String = "Prelevement"



Sub CreeBO()

  

  If MenuExist(MnuCaption) = False Then

  

    Dim MonMenu As CommandBarPopup

    Dim MonBouton As CommandBarButton



    Set MonMenu = Application.CommandBars("Worksheet Menu Bar").Controls.Add(msoControlPopup)

    MonMenu.Caption = MnuCaption

  

    Set MonBouton = MonMenu.Controls.Add(msoControlButton)

    MonBouton.Caption = "MyBtn"

    MonBouton.FaceId = 29

    MonBouton.OnAction = "Macro1"

  

  End If

  

  Call DeleteMenu(MnuCaption)

End Sub



Private Function MenuExist(ByVal Caption As String) As Boolean

  Dim iControl As Integer

  For iControl = 1 To Application.CommandBars("Worksheet Menu Bar").Controls.Count

    If Application.CommandBars("Worksheet Menu Bar").Controls(iControl).Caption = Caption Then

      MenuExist = True

      Exit Function

    End If

  Next iControl

End Function



Private Function DeleteMenu(ByVal Caption As String)

  If MenuExist(Caption) = True Then

    Application.CommandBars("Worksheet Menu Bar").Controls(Caption).Delete

  End If

End Function







 ChRB



<hr size="2" width="100%">
Merci de cliquer sur "R&#233;ponse accept&#233;e" si une r&#233;ponse vous convient.

nagattaque · Answer

Mervellous.....Faboulous.... Genious.... Congratulationous !!!!

Bon ba je crois que c'est tip top et que c'est exactement ce que je voulais.....

Merci BCP !!

Nag

Creer un menu

4 réponses

Discussions similaires