Outlook : Récupérer les mails présents dans la boite de réception

Question

Après quelques recherches concernant  la récupération des mails présents dans la boite de réception de outlook

en VB on trouve du code de type :


1-  Set objOutlook = CreateObject("Outlook.Application")

2-  Set objSession = objOutlook.GetNamespace("MAPI")

3-  Set myfolder = objSession.GetDefaultFolder(olFolderInbox)


La ligne 3- permet de recupérer l'objet myfolder qui permet alors dans une boucle de récupérer tous

les mail présents dans la boite de réception de outlook.


Par contre cette ligne 3- ne fonctionne pas en VBscript


Si donc quelqu'un a la solution en VBScript, merci d'avance !!

cs_JMO · Answer

Bonjsoir à tous....

Un petit exemple:

Dim myOlApp     : Set myOlApp = CreateObject("Outlook.Application")
Dim WshShell    : Set WshShell = CreateObject("WScript.Shell")
Dim myNamespace : Set myNamespace = myOlApp.GetNamespace("MAPI")
Dim myFolder    : Set myFolder = myOlApp.ActiveExplorer.CurrentFolder
  
   For i = 1 To myFolder.Items.Count
      Set MyObjMail = myFolder.Items.Item(i)
      MsgBox MyObjMail
   Next
Set myOlApp     = Nothing
Set WshShell    = Nothing
Set myNamespace = Nothing
Set myFolder    = Nothing

jean-marc

cavo789 · Answer

Salut

A voir ton code et parce que tu précises que c'est du VBS, il me semble que le problème vient du fait que la constante olFolderInbox est inconnue.

Remplacer la constante par le chiffre 6 et réessaie.

Christophe

cs_JMO · Answer

Bonjour à tous....

pas terrible google sur la recherche de vbs et outlook, hormis les virus.

Dim myOlApp     : Set myOlApp     = CreateObject("Outlook.Application")
Dim WshShell    : Set WshShell    = CreateObject("WScript.Shell")
Dim myNamespace : Set myNamespace = myOlApp.GetNamespace("MAPI")
Dim myFolder    : Set myfolder    = myNamespace.GetDefaultFolder(6)



For i = 1 To myFolder.Items.Count
    If i <= myFolder.Items.Count Then 
       MsgBox myFolder.Items.Count &vbCrLf&_
              myFolder.Name &vbCrLf&_
              myFolder.Items(i) &vbCrLf&_
              MyFolder.Items(i).Subject
    End If
Next



Set myOlApp     = Nothing
Set WshShell    = Nothing
Set myNamespace = Nothing
Set myFolder    = Nothing





abelee_fr , merci de poster l'avancement de ton topic.
je découvre, en vbs,  l'utilisation d'outlook dans l'autre sens (réception de mail + actions).

jean-marc

abelee_fr · Answer

Un grand merci à jean-marc et Christophe pour votre aide !


Le code tourne impeccable.


Je rajoute les précisions suivantes pour ceux qui sont intéressés:


' Elements supprimés

Set myFolder = myNameSpace.GetDefaultFolder(3)


' Boite d'envoi

Set myFolder  = myNameSpace.GetDefaultFolder(4)


' Eléments envoyés

Set myFolder  = myNameSpace.GetDefaultFolder(5)


' Boite de réception

Set myFolder  = myNameSpace.GetDefaultFolder(6)

...


Alain

Outlook : Récupérer les mails présents dans la boite de réception

4 réponses

Votre réponse

Discussions similaires