Iconisation dans la barre des tâches.Résolu

Question

Bonjour &#224; tous ! 



J'aimerais savoir si il est possible de faire pour qu'un programme se mette en icone dans la barre des t&#226;che en bas &#224; droite.



Si c'est possible qu'elle est la proc&#233;dure &#224; suivre ?



Merci d'avance.

philippe laschweng 1 · Accepted Answer

Dans un module :
'type d&#233;fini par l'utilisateur requis par Shell_NotifyIcon API call
   Public Type NOTIFYICONDATA
   cbSize As Long
   hwnd As Long
   uId As Long
   uFlags As Long
   uCallBackMessage As Long
   hIcon As Long
   szTip As String * 64
   End Type


   'constantes requises par l'appel API Shell_NotifyIcon :
   Public Const NIM_ADD = &H0
   Public Const NIM_MODIFY = &H1
   Public Const NIM_DELETE = &H2
   Public Const NIF_MESSAGE = &H1
   Public Const NIF_ICON = &H2
   Public Const NIF_TIP = &H4
   Public Const WM_MOUSEMOVE = &H200
   Public Const WM_LBUTTONDOWN = &H201     'Button down
   Public Const WM_LBUTTONUP = &H202       'Button up
   Public Const WM_LBUTTONDBLCLK = &H203   'Double-click
   Public Const WM_RBUTTONDOWN = &H204     'Button down
   Public Const WM_RBUTTONUP = &H205       'Button up
   Public Const WM_RBUTTONDBLCLK = &H206   'Double-click


   Public Declare Function SetForegroundWindow Lib "user32" _
   (ByVal hwnd As Long) As Long
   Public Declare Function Shell_NotifyIcon Lib "shell32" _
   Alias "Shell_NotifyIconA" _
   (ByVal dwMessage As Long, pnid As NOTIFYICONDATA) As Boolean


   Public nid As NOTIFYICONDATA


Sur ta Form principale :
Private Sub Form_Load()
'la forme doit &#234;tre enti&#232;rement visible avant d'appeler Shell_NotifyIcon
   Me.Show
   Me.Refresh
   With nid
    .cbSize = Len(nid)
    .hwnd = Me.hwnd
    .uId = vbNull
    .uFlags = NIF_ICON Or NIF_TIP Or NIF_MESSAGE
    .uCallBackMessage = WM_MOUSEMOVE
    .hIcon = Me.Icon
    .szTip = "Compteur horaire" & vbNullChar
   End With
   Shell_NotifyIcon NIM_ADD, nid
   End Sub


   Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
   'cette proc&#233;dure re&#231;oit les rappels de l'ic&#244;ne de barre d'&#233;tat syst&#232;me.
   Dim Result As Long
   Dim msg As Long
    'the value of X will vary depending upon the scalemode setting
    If Me.ScaleMode = vbPixels Then
     msg = X
    Else
     msg = X / Screen.TwipsPerPixelX
    End If
    Select Case msg
     Case WM_LBUTTONUP                  '514 restore form window
      
      Me.WindowState = vbNormal
      Result = SetForegroundWindow(Me.hwnd)
      Me.Show
    Case WM_LBUTTONDBLCLK     '515 restore form window
      Me.WindowState = vbNormal
      Result = SetForegroundWindow(Me.hwnd)
      Me.Show
     Case WM_RBUTTONUP                  '517 display popup menu
      Result = SetForegroundWindow(Me.hwnd)
      PopupMenu mpop 'NOM du menu cr&#233;er dans le 'cr&#233;ateur de menus' ==> menu Outils
    End Select
   End Sub


   Private Sub Form_Resize()
    'N&#233;cessaire pour assurer que la fen&#234;tre r&#233;duite soit masqu&#233;e
    If Me.WindowState = vbMinimized Then Me.Hide
   End Sub


   Private Sub Form_Unload(Cancel As Integer)
    'cela supprime l'ic&#244;ne de la barre d'&#233;tat syst&#232;me
    Shell_NotifyIcon NIM_DELETE, nid
   End Sub


   Private Sub mPopExit_Click()
    'appel&#233;e quand l'utilisateur clique sur le menu contextuel Exit command
    'Faut pas mettre End sinon l'ic&#244;ne peut rester dans le Systray une fois l'appli ferm&#233;e
   Unload Me
   End Sub


   Private Sub mPopRestore_Click()
    'appel&#233;e quand l'utilisateur clique sur le menu contextuel Restore command
    Me.WindowState = vbNormal
    Result = SetForegroundWindow(Me.hwnd)
    Me.Show
    End Sub

mPopExit et mPopestore sont dans un menu de la Form (cr&#233;ateur de menu)

Le code fonctionne nickel et est issu de microsoft. Essayes et dis moi si tu as des probl&#232;mes (compr&#233;hension ou logicielle). Y'ara peut &#234;tre des petits changements !

En esp&#233;rant t'aider !

cs_hassen · Answer

il existe plusieur source sur vbfrance qui traite le sujet. et ca s'appelle un Tray
fait une recherche sur "tray" ou "tray icon" et tu trouvera des sources qui t'explique
comment faire


Hassen TUNISIE

Mood_ · Answer

Merci vous m'avez bien aid&#233;

Iconisation dans la barre des tâches.

3 réponses

Discussions similaires