Desactiver la croix d'un formulaire d'excel?!

Question

Je voudrais desactiver la croix d'un formulaire excel pour eviter que les utilisateurs sortent sans passer par MON bouton "Fermer".
Merci d'avance

sonoboss · Answer

essaye ca : 

Public Declare Function GetSystemMenu Lib "user32" (ByVal hwnd As Long, ByVal bRevert As Long) As Long
Public Declare Function GetMenuItemCount Lib "user32" (ByVal hMenu As Long) As Long
Public Declare Function RemoveMenu Lib "user32" (ByVal hMenu As Long, ByVal nPosition As Long, ByVal wFlags As Long) As Long
Public Declare Function DrawMenuBar Lib "user32" (ByVal hwnd As Long) As Long

Public Function DesactiveX(ByVal frm As Form)
     Dim hMenu As Long
     Dim nCount As Long
     hMenu = GetSystemMenu(frm.hwnd, 0)
     nCount = GetMenuItemCount(hMenu)
     Call RemoveMenu(hMenu, nCount - 1, MF_REMOVE Or MF_BYPOSITION)
     Call RemoveMenu(hMenu, nCount - 2, MF_REMOVE Or MF_BYPOSITION)
     DrawMenuBar frm.hwnd
End Function

et tu l'appelle comme ca : 

call desactiveX(Me)

Bon courage!

Le jour où la merde vaudra de l'or, les pauvres naîtons sans trou du cul!

cs_tisa · Answer

Merci...Mais....

J'ai un petit pb... 
au moment de compiler la fonction DesactiveX
le compileur me dit "type defini par l'utilisateur non defini"

je pense qu'il manque une declaration...
peux encore m'aider stp???

BasicInstinct · Answer

passe tout dans 1 module  ;) 

 :clown)  BasicInstinct  :clown)

cs_tisa · Answer

J'ai tout passé dans un module et appeler la fonction dans l'activation du formulaire, mais j'ai toujours cette erreur de complilation:
"type defini par l'utilisateur non defini"

Merci de m'aider...

BasicInstinct · Answer

effectivement, pas de hwnd sous excel & pas de type form :(
je sais pas si c'est possible par ce code la :(

 :clown)  BasicInstinct  :clown)

pelw · Answer

Essaye ceci :

1. Dans un module

Public Const MF_BYPOSITION = &H400
Public Const MF_REMOVE = &H1000

Public Declare Function DrawMenuBar Lib "user32" (ByVal hWnd As Long) As Long
Public Declare Function GetMenuItemCount Lib "user32" (ByVal hMenu As Long) As Long
Public Declare Function GetSystemMenu Lib "user32" (ByVal hWnd As Long, ByVal bRevert As Long) As Long
Public Declare Function RemoveMenu Lib "user32" (ByVal hMenu As Long, ByVal nPosition As Long, ByVal wFlags As Long) As Long
Public Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long

Public Sub DesactiveX(hWnd As Long)

 Dim hMenu As Long
 Dim nCount As Long
 
 hMenu = GetSystemMenu(hWnd, 0)
 nCount = GetMenuItemCount(hMenu)
 Call RemoveMenu(hMenu, nCount - 1, MF_REMOVE Or MF_BYPOSITION)
 Call RemoveMenu(hMenu, nCount - 2, MF_REMOVE Or MF_BYPOSITION)
 Call DrawMenuBar(hWnd)
 
End Function

2. Dans une UserForm

Private Sub UserForm_Activate()

Call DesactiveX(FindWindow(vbNullString, Me.Caption))

End Sub

@+

pelw

pelw · Answer

On pourrait aussi imaginer une solution un peu plus simple, en laissant la croix active, mais en affichant un message d'erreur si l'utilisateur clique dessus :

Dans une UserForm

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
    If CloseMode = vbFormControlMenu Then
        Cancel = True
        MsgBox "Veuillez quitter à l'aide du bouton ""Fermer"" !"
    End If
End Sub

@+

pelw

pelw · Answer

Oups, désolé... Il faut remplacer "End Function" par "End Sub" !

@+

pelw

Desactiver la croix d'un formulaire d'excel?!

8 réponses

Discussions similaires