Enregistrer le contenu d'une liste

Question

Comment je fais pour enregistrer le contenu d'une liste dans un fichier, et comment je fais ensuite pour l'ouvrir?

NitRic · Answer

Colle ca dans un module:

' Sauvegarder le contenue d'une ListBox
Public Sub SaveList(ListName As ListBox, ByVal Fichier As String)

' ListName -> Nom de la ListBox à sauvegarder
' Fichier -> Nom du fichier dans lequel sauvegarder le contenue de la ListBox

Dim I As Integer
Dim iFile As Integer

iFile = FreeFile
' Ouvre le fichier en écriture(si le fichier n'existe pas il seras créé automatiquement)
Open Fichier For Output As #iFile

 ' Passe tous les items de la ListBox 1 à 1 et les sauvegarde dans le fichier
 For I = 0 To ListName.ListCount - 1

 Print #iFile, ListName.List(I)

 ' Passe au suivant
 Next I

' Ferme le fichier(important)
Close #iFile

End Sub

' Ouvrir un fichier et mettre sont contenue dans une ListBox
Public Sub LoadList(ListName As ListBox, ByVal Fichier As String)

' ListName -> Nom de la ListBox qui va contenir toutes les lignes du fichier
' Fichier -> Nom du fichier à lire

Dim iFile As Integer
Dim Ligne As String

' Si le fichier existe
If Dir$(Fichier) <> "" Then

' Vide la ListBox
ListName.Clear

iFile = FreeFile
' Ouvre le fichier en lecture seulement
Open Fichier For Input As #iFile

' Commence la boucle
Do

 ' Récupère la ligne pointer dans le fichier
 Line Input #iFile, Ligne
 ' L'envoie dans la ListBox
 ListName.AddItem Ligne

' Boucle tant qu'on est pas rendu à la fin du fichier
Loop Until EOF(iFile)

' Ferme le fichier(important)
Close #iFile

End If

End Sub

' Exemple:
Private Sub Form_Load()

 ' Lire le fichier
 Call LoadList(List1, "c:\Mon Fichier.txt")

End Sub

Private Sub Form_Unload(Cancel As Integer)

 ' Sauvegarder dans le fichier
 Call SaveList(List1, "c:\Mon Fichier.txt")

End Sub

FIN!!!

Enregistrer le contenu d'une liste

1 réponse

Discussions similaires