dectecter la présence d'une imprimanteRésolu

Question

slt a tous ,j'ai cherché le code et j'ai pas trouvé...
j'aimerais un code qui me rend un message lorsque il y une imprimante qui est connectée
a mon ordinateur.
j'aimerais l'inserer dans un projet dans lequel l'impression se fait directement sans "Apercu avant impression"..
Merci d'avance..

      Eridyms.......

cs_Jack · Accepted Answer

Salut

    Dim a As String
    On Error Resume Next
        a = Printer.DeviceName
        If Err.Number = 0 Then
            MsgBox "Imprimante présente : " & a
        Else
            MsgBox "Pas d'imprimante"
        End If
    On Error GoTo 0
Vala
Jack, MVP VB
NB : Je ne répondrai pas aux messages privés

Le savoir est la seule matière qui s'accroit quand on la partage (Socrate)

cs_lermite222 · Answer

Bonjour,
Plus compliquer mais aussi plus "conventionnel",
Option Explicit
Private Declare Function EnumPrintersA Lib "Winspool.drv" _
  (ByVal flags As Long, ByVal name As String, ByVal Level As Long, _
  pPrinterEnum As Long, ByVal cdBuf As Long, pcbNeeded As Long, pcReturned As Long) As Long
Private Declare Function lstrlenA Lib "Kernel32" (ByVal lpString As Any) As Long
Private Declare Function lstrcpyA Lib "Kernel32" (ByVal lpString1 As String, ByVal lpString2 As Long) As Long
  
Public ImprEnum() As String

Public Function NbPrinter() As Integer
  Dim PrinterEnum() As Long
  Dim Needed As Long, Returned As Long, I As Integer
 
  EnumPrintersA 2, vbNullString, 5, 0, 0, Needed, 0
  ReDim PrinterEnum(Needed / 4)
  EnumPrintersA 2, vbNullString, 5, PrinterEnum(0), _
    Needed, Needed, Returned
  ReDim ImprEnum(1 To Returned)
  For I = 1 To Returned
    ImprEnum(I) = Space$(lstrlenA(PrinterEnum(I * 5 - 5)))
    lstrcpyA ImprEnum(I), PrinterEnum(I * 5 - 5)
  Next I
  NbPrinter = I - 1
End Function
A+

eridyms · Answer

merci..... mais comment appelé la fonction....
je peux avoir un exemple....

cs_lermite222 · Answer

Mais oui,
If NbPrinter > 0 then ' Il y a au moins une imprimantes

Mais avec cette fonction tu a aussi le nom de la/les imprimante(s). Ce qui permet éventuellement de sélectionner une autre imprimante.
A+

eridyms · Answer

ok...Dans le cas ou j'aurai plusieurs imprimante
[code=vb]
NbPrinter > 0 then
 for i=1 to NbPrinter
    combo1.addItem Printer.DeviceName
next
je pense que c'est ca 
et comment montrer que c'est le choix qu'aura fait l'utilisateur qui servira a l'impression

cs_lermite222 · Answer

Tu dis, sans "Apercu avant impression".. 
Tu travail avec VBA ou VB.. ?

eridyms · Answer

vb

cs_lermite222 · Answer

Grrr..  Quel VB ?

eridyms · Answer

excuse moi vb6

cs_lermite222 · Answer

C'est rien 
En premier je pensais que tu était sur Excel et j'avais prépare le code en ce sens.
Tu ouvre un nouveau projet
dans la forme tu colle un bouton, un label.
une list avec la propriété Style à 1 (option)
et tu colle le code...
Option Explicit

Private Sub Command1_Click()
Dim PRt As Printer, NomPr As String, e As Integer, Im
    NomPr = List1.List(List1.ListIndex)
    For Each PRt In Printers
        If PRt.DeviceName = NomPr Then
            Set Printer = PRt
            Exit For
        End If
    Next
    NomPr = Printer.DeviceName
    Label1 = NomPr
End Sub

Private Sub Form_Load()
Dim i
Dim PRt As Printer, NomPr As String, e As Integer, Im
    NomPr = Printer.DeviceName
    Label1 = NomPr
    'List1.Style = 1  : A déterminer dans le design
    For Each PRt In Printers
        List1.AddItem PRt.DeviceName
        If PRt.DeviceName NomPr Then Im e
       e = e + 1
    Next
    List1.Selected(Im) = True
End Sub

Private Sub List1_Click()
Dim i
    For i = 0 To List1.ListCount - 1
        If i <> List1.ListIndex Then List1.Selected(i) = False
    Next i
End Sub
A+

cs_lermite222 · Answer

J'ai oublié..
Juste pour savoir s'il y a une imprimante
If Printers.count>0 then 'Il y a une (ou des) imprimante(s)
La fonction NbPrinter n'est plus nécessaire.
A+

eridyms · Answer

Excellent....
très heureux et très émue pour l'attention que tu m'a accorder...merci j'ai bien envie de garder le contact avec toi..
                                   eridyms..

cs_Jack · Answer

En fait, si tu avais commencé par faire une SIMPLE recherche de code avec le mot "imprimante", tu aurais trouvé des exemples tout fait.

Prends cette habitude, le forum ne doit être là qu'en cas de problème insurmontable, pas pour remplacer l'aide de VB.

Dectecter la présence d'une imprimante

13 réponses

Votre réponse

Discussions similaires