Changement office 2003 / 2007 pour les graphs en vba ???

Question

Bonjour,

J'ai créé un module pour la création d'un  graph , je l'ai fait sous office 2007 , en alimentant 2 tableaux (abscisses et ordonnées) le souci c'est que sous 2003, il aime pas et me dit : xvalues non reconnus....

Quelqu'un aurait une idée ? est ce une incompatibilité entre versions ?

Sub graphique_parties() 

    nombre_ligne = Sheets("Statistiques").Range("a1").CurrentRegion.Rows.Count                            
        
    Abscisses2(0) = "Q rue"                                                                      
    Abscisses2(1) = "Q quartier"                                                                  
    Abscisses2(2) = "Q voies"                                                                  
    
    Ordonnees2(0) = Application.CountIf(Sheets("Statistiques").Range("g2:g" & nombre_ligne), "=rue")     

    Ordonnees2(1) = Application.CountIf(Sheets("Statistiques").Range("g2:g" & nombre_ligne), "=quartier")   

    Ordonnees2(2) = Application.CountIf(Sheets("Statistiques").Range("g2:g" & nombre_ligne), "=voie")    
        
    
    Charts.Add                                                                                             

        ActiveChart.Location Where:=xlLocationAsNewSheet, Name:="Répartition"                   
    
            With ActiveChart
    
                .SeriesCollection.NewSeries
                .SeriesCollection(1).XValues = Abscisses2()                                                  
                .SeriesCollection(1).Values = Ordonnees2()                                                   
                .ChartType = xl3DPieExploded                                                               
                .HasTitle = True
                .ChartTitle.Characters.Text = "Répartitions " 
                .ChartArea.Width = 640                                                                       
                .ChartArea.Height = 480
                .ApplyDataLabels Type:=xlDataLabelsShowLabelAndPercent, LegendKey _
                :=False, HasLeaderLines:=True
                     
            End With

Renfield · Answer

étrange... la doc 2003 le mentionne bien:

http://msdn.microsoft.com/en-us/library/aa215988(office.11).aspx


quel est le message d'erreur exact ?

romain3430 · Answer

Erreur d'éxecution 1004:

Impossible de définir la propriété x values de la classe Series ...

Renfield · Answer

comment est définit ton tableau ?

romain3430 · Answer

Public Abscisses2(0 To 2) As String
Public Ordonnees2(0 To 2) As Integer

Renfield · Answer

tentes d'en faire un tableau de Variant (la doc est pas claire claire)

romain3430 · Answer

ok merci, je tente...

romain3430 · Answer

Marche pas .... ça me rends  fou, ça tourne sur 2007 !

Renfield · Answer

c'est surtout bête de l'avoir codé en 2007 sachant qu'il fallait une compatibilité avec 2003 ^^

romain3430 · Answer

Disons que je pensais pas que ça marcherai pas sur 2003, et sur mon portable c'est 2007 et en cours c'est 2003 ...

Renfield · Answer

Dim oChart As Chart
Dim oSeries As Series
Dim Abscisses2 As Variant
Dim Ordonnees2 As Variant

    ReDim Abscisses2(2)
    Abscisses2(0) = "Rue"
    Abscisses2(1) = "Route"
    Abscisses2(2) = "Avenue"
    
    ReDim Ordonnees2(2)
    Ordonnees2(0) = 5
    Ordonnees2(1) = 8
    Ordonnees2(2) = 3

    Set oChart = Charts.Add
    With oChart
        .Location xlLocationAsNewSheet, "Répartition"
        .ChartType = xl3DPieExploded
        
        Set oSeries = .SeriesCollection.NewSeries
        oSeries.XValues = Abscisses2
        oSeries.Values = Ordonnees2
    End With




testé avec succès en 2003.

romain3430 · Answer

ok je teste et je te dis si ça fonctionne chez moi,

A quoi sert le redim ?

merci beaucoup !

Renfield · Answer

redim ?
changer la taille d'un tableau

ici, pour en spécifier la taille 
j'utilise des Variant ; des variables qui peuvent stocker tous types de données

le Redim, là, permet de faire savoir que c'est un tableau (de trois cases)

romain3430 · Answer

ok merci !

Changement office 2003 / 2007 pour les graphs en vba ???

13 réponses

Votre réponse

Discussions similaires