Amélioration code vba

Question

Bonjour à tous,

J'utilise une macro qui permet de vérrouiller les données automatiquement dès que l'on renregistre. Elle fonctionne très bien mais lorsque il y a une fusion dans le documents, il y a une erreur :  
Erreur d'éxécution ' ': Impossible de définir la propiété Locked de la classe Range.

La macro est la suivante : 

Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)

For Each c In Sheets("Feuil1").Range("A1:J1000")
If c <> "" Then
ActiveSheet.Unprotect Password:=""
c.Locked = True
ActiveSheet.Protect Password:="", DrawingObjects:=False, Contents:=True, Scenarios:= _
False, AllowFormattingCells:=True, AllowFormattingColumns:=True, _
AllowFormattingRows:=True, AllowInsertingColumns:=True, AllowInsertingRows _
:=True, AllowInsertingHyperlinks:=True, AllowDeletingColumns:=True, _
AllowDeletingRows:=True, AllowSorting:=True, AllowFiltering:=True, _
AllowUsingPivotTables:=True
ActiveSheet.EnableSelection = xlNoRestrictions
End If
Next c

End Sub

Est-ce quelqu'un à une solution à mon problême ?

Merci d'avance de votre aide. Garion27

Garion27 · Answer

PS: L'erreur est la 1004.

Garion27 · Answer

Je suis touours bloqué et j'ai chercher sur d'autre sujet et apparamment c'est bien la fusion qui fait tout buguer. Je ne sais pas comment faire pour régler ce problême : peut-être nommé la cellule fusionné pour qu'elle soit pris en compte dans la macro thisworkbook. Mais bon je viens de débuté dans le vba et je ne maitrise pas trop cette progammation.

Merci de votre aide

Garion.

cnt · Answer

Bonjour Garion27
Je ne vois qu'une façon de palier au problème, c'est de gérer les erreurs, comme suite :

On Error Resume Next
c.Locked = True
If Err.Number <> 0 Then
    Err.Clear
End If

Est ce suffisant?
Sachant que si les cellules fusionnées ne sont pas protégées, elles peuvent être modifiées, même si la feuille l'est.

Salut

r1r2 · Answer

Bonjour,

L'erreur vient peut-etre de la presence de cellules fusionnees.

Voici un exemple de code qui a des chances de fonctionner si c'est bien la cause de ton probleme :

Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)

    ActiveSheet.Unprotect Password:=""
    For Each c In Sheets("Feuil1").Range("A1:J1000")
        If c <> "" Then
            If c.MergeCells Then
                c.MergeArea.Locked = True
            Else
                c.Locked = True
            End If
        End If
    Next
    ActiveSheet.Protect Password:="", DrawingObjects:=False, Contents:=True, Scenarios:= _
    False, AllowFormattingCells:=True, AllowFormattingColumns:=True, _
    AllowFormattingRows:=True, AllowInsertingColumns:=True, AllowInsertingRows _
    :=True, AllowInsertingHyperlinks:=True, AllowDeletingColumns:=True, _
    AllowDeletingRows:=True, AllowSorting:=True, AllowFiltering:=True, _
    AllowUsingPivotTables:=True
    ActiveSheet.EnableSelection = xlNoRestrictions
End Sub

Au passage, est-ce la feuille active ou "Feuil1" que tu veux traiter? Si c'est un autre onglet qui est actif que "Feuil1" lors de la sauvegarde, tu risques d'avoir des problemes.

Garion27 · Answer

Merci beaucoup r1r2, sa fonctionne très bien. Pour répondre à ta question, pour l'instant c'est la Feuil1 uniquement qui est gérer par la macro Mais j'avoue que je sais pas comment la mettre pour toutes les feuilles. Sinon est-ce que tu sais si dans la partie ou ont autorise les modifications des cellules vérrouillé, si c'est possible de rajouter la possibilité de fusionner les cellules d'à coter si elle est ou sont vide.

Merci encore pour ton aide.

Garion27

Amélioration code vba

5 réponses

Votre réponse

Discussions similaires