Contrôler les instances de ms access

0/5 (4 avis)

Snippet vu 3 827 fois - Téléchargée 42 fois

Contenu du snippet

Salut à tous,

Qui n'utilise jamais la fonction App.PrevInstance de Visual Basic pour contrôler que son appli n'a pas été lancée deux fois sur le même poste ? C'est fort pratique pour éviter les problèmes... Mais sous Access ? Rien du tout...

Ce petit code source va pouvoir vous permettre de contrôler la présence d'une instance de Microsoft Access en mémoire.
Malheureusement, ce code ne vous permettra pas de contrôler quelle base est ouverte, si vous utilisez plusieurs bases de données... Mais en cas d'utilisation d'une seule base, vous serrez ainsi sur qu'elle ne serra ouverte qu'une seule fois !!!!

Source / Exemple :


' Voici le code à ajouter dans un module...
Option Compare Database

Const TH32CS_SNAPHEAPLIST = &H1
Const TH32CS_SNAPPROCESS = &H2
Const TH32CS_SNAPTHREAD = &H4
Const TH32CS_SNAPMODULE = &H8
Const TH32CS_SNAPALL = (TH32CS_SNAPHEAPLIST Or TH32CS_SNAPPROCESS Or TH32CS_SNAPTHREAD Or TH32CS_SNAPMODULE)
Const TH32CS_INHERIT = &H80000000
Const MAX_PATH As Integer = 260

Private Type PROCESSENTRY32
    dwSize As Long
    cntUsage As Long
    th32ProcessID As Long
    th32DefaultHeapID As Long
    th32ModuleID As Long
    cntThreads As Long
    th32ParentProcessID As Long
    pcPriClassBase As Long
    dwFlags As Long
    szExeFile As String * MAX_PATH
End Type

Private Declare Function CreateToolhelp32Snapshot Lib "Kernel32" (ByVal lFlags As Long, ByVal lProcessID As Long) As Long
Private Declare Function Process32First Lib "Kernel32" (ByVal hSnapShot As Long, uProcess As PROCESSENTRY32) As Long
Private Declare Function Process32Next Lib "Kernel32" (ByVal hSnapShot As Long, uProcess As PROCESSENTRY32) As Long
Private Declare Sub CloseHandle Lib "Kernel32" (ByVal hPass As Long)

Public Function IsProcessRunning(pExeName As String, Optional CompletePath As Boolean = False) As Boolean
    Dim i As Long
    Dim tProcess As String
    Dim hSnapShot As Long
    Dim uProcess As PROCESSENTRY32
    
    IsProcessRunning = False
    'Takes a snapshot of the processes and the heaps, modules, and threads used by the processes
    hSnapShot = CreateToolhelp32Snapshot(TH32CS_SNAPALL, 0&)
    'set the length of our ProcessEntry-type
    uProcess.dwSize = Len(uProcess)
    'Retrieve information about the first process encountered in our system snapshot
    i = Process32First(hSnapShot, uProcess)
    'set graphics mode to persistent
    
    Do While i
        tProcess = Left$(uProcess.szExeFile, IIf(InStr(1, uProcess.szExeFile, Chr$(0)) > 0, InStr(1, uProcess.szExeFile, Chr$(0)) - 1, 0))
        
        If CompletePath = False Then
            tProcess = Dir(tProcess, vbNormal + vbHidden + vbArchive + vbSystem)
        Else
            tProcess = Trim(tProcess)
        End If
        
        If tProcess <> "" Then
            If Trim(UCase(tProcess)) = Trim(UCase(pExeName)) Then
                IsProcessRunning = True
                Exit Function
            End If
        End If
        'Retrieve information about the next process recorded in our system snapshot
        i = Process32Next(hSnapShot, uProcess)
    Loop
    'close our snapshot handle
    CloseHandle hSnapShot
End Function

Public Function ProcessCount(pExeName As String, Optional CompletePath As Boolean = False) As Long
    Dim i As Long
    Dim j As Long
    Dim tProcess As String
    Dim hSnapShot As Long
    Dim uProcess As PROCESSENTRY32
    
    ProcessCount = 0
    j = 0
    
    'Takes a snapshot of the processes and the heaps, modules, and threads used by the processes
    hSnapShot = CreateToolhelp32Snapshot(TH32CS_SNAPALL, 0&)
    'set the length of our ProcessEntry-type
    uProcess.dwSize = Len(uProcess)
    'Retrieve information about the first process encountered in our system snapshot
    i = Process32First(hSnapShot, uProcess)
    'set graphics mode to persistent
    
    Do While i
        tProcess = Left$(uProcess.szExeFile, IIf(InStr(1, uProcess.szExeFile, Chr$(0)) > 0, InStr(1, uProcess.szExeFile, Chr$(0)) - 1, 0))
        
        If CompletePath = False Then
            tProcess = Dir(tProcess, vbNormal + vbHidden + vbArchive + vbSystem)
        Else
            tProcess = Trim(tProcess)
        End If
        
        If tProcess <> "" Then
            If Trim(UCase(tProcess)) = Trim(UCase(pExeName)) Then
                j = j + 1
            End If
        End If
        'Retrieve information about the next process recorded in our system snapshot
        i = Process32Next(hSnapShot, uProcess)
    Loop
    'close our snapshot handle
    CloseHandle hSnapShot
    ProcessCount = j
End Function

' --------------------------------------------------------------
' Et maintenant le code à executer au lancement de la base de données
' --------------------------------------------------------------
Public Sub Start()
    If ProcessCount("MSACCESS.EXE", False) > 1 Then
        MsgBox "Access ne peut être lancé qu'une seule fois !"
        DoCmd.Quit acQuitSaveAll
    End If
End Sub

Conclusion :


Esperons que ce code vous soit utile !

A+
Cyril

A voir également

Ajouter un commentaire Commentaires
Il y a une erreur dans le code :
....
Do While i
tProcess = Left$(uProcess.szExeFile, IIf(InStr(1, uProcess.szExeFile, Chr$(0)) > 0, InStr(1, uProcess.szExeFile, Chr$(0)) - 1, 0))

If CompletePath = False Then
.....
c'est If CompletePath = true Then
Mumuri
Messages postés
320
Date d'inscription
mercredi 9 octobre 2002
Statut
Membre
Dernière intervention
6 avril 2008

12 oct. 2002 à 11:10
merci
cs_cyrilp
Messages postés
140
Date d'inscription
mercredi 4 octobre 2000
Statut
Membre
Dernière intervention
12 août 2009

23 avril 2002 à 14:02
... J'ai aussi oublié de préciser que ce petit code permet de contrôler.... au dela de MS Access... N'importe quel executable...
Par exemple :

IsProcessRunning("SOL.EXE") => Renvoie Vrai si SOL.EXE est en mémoire
IsProcessRunning("C:WINDOWSPAINT.EXE",True) => Renvoie vrai si PAINT est en mémoire

Etc...

A+
Cyril
cs_cyrilp
Messages postés
140
Date d'inscription
mercredi 4 octobre 2000
Statut
Membre
Dernière intervention
12 août 2009

23 avril 2002 à 12:23
Au fait, j'ai oublié de préciser...
Une partie de ce code est extrait de API Guide de KPD Team, je l'ai modifié pour atteindre le but souhaité.

De plus, une petite information :
Le 2nd paramètre de la fonction ProcessCount permet de définir si on passe en paramêtre le nom d'un executable ou son chemin complet.


Concernant KPD Team, j'ai oublié de remettre les copyrights, alors les voici :
KPD-Team 2000
URL: http://www.allapi.net/
E-Mail: KPDTeam@Allapi.net

Vous n'êtes pas encore membre ?

inscrivez-vous, c'est gratuit et ça prend moins d'une minute !

Les membres obtiennent plus de réponses que les utilisateurs anonymes.

Le fait d'être membre vous permet d'avoir un suivi détaillé de vos demandes et codes sources.

Le fait d'être membre vous permet d'avoir des options supplémentaires.