création d'un fichier texte par le réseau

Question

Bonjour,

j'ai fais une macro VBA qui me permet de r&#233;cup&#233;rer certaines valeurs pour les enregistrer dans un fichier texte.
La macro commence dabord par cr&#233;er un fichier texte vierge et ensuite enregistre les valeurs les unes apr&#232;s les autres, et finit enfin par refermer le fichier texte.

Le soucis que je rencontre concerne la cr&#233;ation du fichier texte vierge. En effet, lorsque je veux cr&#233;er un fichier en local, aucun probl&#232;me ne se pose, tout fonctionne bien. Mais lorsque je veux que le fichier soit cr&#233;e sur un ordinateur distant, une erreur apparait.
ca me dit que le chemin ou le nom de fichier est incorrect. 
j'ai l'impression que VBA ne comprend pas qu'il s'agit d'une adresse r&#233;seau.
voici une partie de ma macro :

nom2 = nom & ".txt" 'permet d'avoir l'extension txt
nom3 = "C:/OSCAR/GS4/RCP/" & nom2 'donne le chemin complet ou le fichier doit etre cr&#233;e

Set fs = CreateObject("Scripting.FileSystemObject")
Set a = fs.CreateTextFile(nom3, True)

si je laisse le chemin local dans la variable "nom3" : aucun probleme

si je met "//10.142.32.63/DataRcp/" & nom2 dans "nom3" : ca bloque &#224; la ligne : "Set a = fs.CreateTextFile(nom3, True)" en me disant chemin ou nom de fichier incorrect.

Y a t'il une syntaxe particuli&#232;re pour rentrer une adresse r&#233;seau. Faut-il une fonction sp&#233;ciale. J'ai pourtant essay&#233; plein de m&#233;thoque sans aucun succ&#232;s !

Pouvez vous m'aider SVP ?
Merci d'avance

cs_Stephane · Answer

slu essaye des slash au lieu des anti slash, sinon je sais pas A+

Utilisateurs du forum : Merci de lire http://www.vbfrance.com/forum.v2.aspx?ID=445871

cs_bob87 · Answer

j'ai essay&#233; de mettre des slash au lieu des anti slash et le r&#233;sultat est le m&#234;me, toujours la m&#234;me erreur.

merci quand m&#234;me

cs_CanisLupus · Answer

Avec FileSystemObject (comme avec plein d'autre), je crois qu'il n'est pas possible de travailler avec des adresses r&#233;seau. Il faut d'abord, leur allouer une lettre logique &#224; condition que ces ressources soient partag&#233;es.
Ainsi, &#224; la place de 
[file://10.142.32.63/DataRcp/ \10.142.32.63\DataRcp\
] tu mettras "z:" par exemple.

Pour faire &#231;a, il faut utiliser les API's  WNetAddConnection2 et WNetCancelConnection2.

Un exemple venant de 
http://www.mentalis.org/apilist/WNetAddConnection2.shtml

et que j'ai francis&#233;, &#224; mettre dans un module :

Option Explicit


'***************************************************************************
  
  ' POUR CONNECTER LA RESSOURCE RESEAU
  'If AddConnection(RemoteName, UserName, UserPwd, LocalName) Then
  ' c'est bon
  'Else
  ' c'est pas bon
  'End If
    
  ' POUR DECONNECTER LA RESSOURCE RESEAU
  'CancelConnection "LocalName"
  
  ' Avec RemoteName = "\nom ou ip de la machine\dossier partag&#233;"
  ' Avec UserName = "" ou "Invit&#233;" ou "Anonymous" ou le nom d'utilisateur d&#233;fini pour le partage
  ' Avec UserPwd = TonPassword (d&#233;fini pour le partage)
  ' Avec LocalName = "Z:" par ex


'***************************************************************************


' Constantes d'erreur
Private Const NO_ERROR As Long = 0 ' The function was successful
Private Const ERROR_BAD_USERNAME As Long = 2202& ' Mauvais nom d'utilisateur
Private Const ERROR_INVALID_PASSWORD As Long = 86& ' The password was invalid.
Private Const ERROR_ALREADY_ASSIGNED As Long = 85& ' LocalName d&#233;j&#224; assign&#233;
Private Const ERROR_BAD_DEVICE As Long = 1200& ' LocalName invalide
Private Const ERROR_BAD_NET_NAME As Long = 67& ' RemoteName invalide ou introuvable


' Constantes de Type de ressource
Private Const RESOURCETYPE_DISK = &H1


'
Private Type NETRESOURCE
  dwScope As Long
  dwType As Long
  dwDisplayType As Long
  dwUsage As Long
  lpLocalName As String
  lpRemoteName As String
  lpComment As String
  lpProvider As String
End Type


' Fonctions API
Private Declare Function WNetAddConnection2 _
  Lib "mpr.dll" Alias "WNetAddConnection2A" _
    ( _
      lpNetResource As NETRESOURCE, _
      ByVal lpPassword As String, _
      ByVal lpUserName As String, _
      ByVal dwFlags As Long _
    ) As Long
    
Private Declare Function WNetCancelConnection2 _
  Lib "mpr.dll" Alias "WNetCancelConnection2A" _
  ( _
    ByVal lpName As String, _
    ByVal dwFlags As Long, _
    ByVal fForce As Long _
  ) As Long


Function AddConnection(RemoteName As String, UserName As String, UserPwd As String, LocalName As String) As Boolean
Dim Retour As Long
Dim SharedResource As NETRESOURCE


  SharedResource.lpRemoteName = RemoteName
  SharedResource.lpLocalName = LocalName
  SharedResource.dwType = RESOURCETYPE_DISK


  ' Tentative de connexion &#224; la ressource partag&#233;e
  Retour = WNetAddConnection2(SharedResource, UserPwd, UserName, 0)
  
  Select Case Retour
    Case NO_ERROR ' Ca se passe bien
      AddConnection = True
    Case ERROR_BAD_USERNAME
      'MsgBox "Mauvais nom d'utilisateur"
      AddConnection = False
    Case ERROR_INVALID_PASSWORD
      'MsgBox "Password invalide"
      AddConnection = False
    Case ERROR_ALREADY_ASSIGNED
      'MsgBox "LocalName d&#233;j&#224; assign&#233;"
      AddConnection = False
    Case ERROR_BAD_DEVICE
      'MsgBox "LocalName invalide"
      AddConnection = False
    Case ERROR_BAD_NET_NAME
      'MsgBox "RemoteName invalide ou introuvable"
      AddConnection = False
    Case Else
      'MsgBox "Erreur n&#176; " & Retour & " non g&#233;r&#233;e par l'appli."
      AddConnection = False
  End Select
  
End Function


Function CancelConnection(LocalName As String)
Dim Retour As Long


  ' Pour fermer la connexion
  Retour = WNetCancelConnection2(LocalName, 0, 0)
  
End Function

-------------------------------------------------
Dresseur de puces, .... normal pour un loup  !?

cs_bob87 · Answer

Merci beaucoup pour cette solution
le probl&#232;me c'est que je suis d&#233;butant et que je ne sais pas trop comment faire pour int&#233;ger ce code au mien.
est ce que je dois mettre tous ce code dans ma macro ?
a quoi correspond la partie encadr&#233;e par des *** ?

Création d'un fichier texte par le réseau

4 réponses

Discussions similaires