Impression avec une imprimante a bacs ...

Question

Je dois imprimer sur une imprimante a bacs et je voudrais savoir si il y a un moyen de sortir les feuilles sur des bacs diffferents. Par ex, la 1ere page sur le 1er bac et le reste sur le second.

Thx

ac2n · Answer

-------------------------------
 Réponse au message :          
-------------------------------

Je dois imprimer sur une imprimante a bacs et je voudrais savoir si il y a un moyen de sortir les feuilles sur des bacs diffferents. Par ex, la 1ere page sur le 1er bac et le reste sur le second.

Thx

-------------------------------------
Salut,
L'objet qui t'interesse est Print.PaperBin, voici un ex d'un
prog qui t'affiche les possibilités de ton imprimante:

Option Explicit

Private Declare Function DeviceCapabilities Lib "winspool.drv" _
   Alias "DeviceCapabilitiesA" (ByVal lpDeviceName As String, _
   ByVal lpPort As String, ByVal iIndex As Long, lpOutput As Any, _
   ByVal dev As Long) As Long

Private Const DC_BINS = 6
Private Const DC_BINNAMES = 12

Private Sub Command1_Click()
   Dim prn As Printer
   Dim dwbins As Long
   Dim ct As Long
   Dim nameslist As String
   Dim nextString As String
   Dim numBin() As Integer

   Text1.Font.Name = "Courier New"
   Text1.Font.Size = 12
   Text1.Text = ""
   For Each prn In Printers
        dwbins = DeviceCapabilities(prn.DeviceName, prn.Port, _
          DC_BINS, ByVal vbNullString, 0)
        ReDim numBin(1 To dwbins)
        nameslist = String(24 * dwbins, 0)
        dwbins = DeviceCapabilities(prn.DeviceName, prn.Port, _
          DC_BINS, numBin(1), 0)
        dwbins = DeviceCapabilities(prn.DeviceName, prn.Port, _
          DC_BINNAMES, ByVal nameslist, 0)
        If Text1.Text <> "" Then
           Text1.Text = Text1.Text & vbCrLf & vbCrLf
        End If
        Text1.Text = Text1.Text & prn.DeviceName
        For ct = 1 To dwbins
           nextString = Mid(nameslist, 24 * (ct - 1) + 1, 24)
           nextString = Left(nextString, InStr(1, nextString, _
             Chr(0)) - 1)
           nextString = String(6 - Len(CStr(numBin(ct))), " ") & _
           numBin(ct) & "  " & nextString
           Text1.Text = Text1.Text & vbCrLf & nextString
        Next ct
   Next prn
End Sub

Private Sub Form_Load()
   Me.Height = 7000
   Me.Width = 7000
   Text1.Top = 100
   Text1.Left = 100
   Text1.Height = 6450
   Text1.Width = 5000
   Text1.Text = ""
   Command1.Left = 5300
   Command1.Top = 1000
   Command1.Width = 1500
   Command1.Caption = "List Bins"
End Sub

Fait un projet avec un form1, un command1 et un textbox1 avec option multiligne true et scrollbar 2-vertical.
Les chiffres obtenus sont ceux que tu peux donner à la propriété Printer.PaperBin.
J'espère que ca te mettra sur la voie...
N'ayant pas d'imprimante à plusieurs bacs je n'ai pas pu tester.
Si tu réussi peux-tu me passer le code SVP ?
A+
Ac2n 8-)

cs_pimousse75 · Answer

J'espere que vous etes tjs la... malgre ces 6 mois. Ce code modifie t il les parametres par default de l'imprimante ???

Impression avec une imprimante a bacs ...

2 réponses

Discussions similaires