Mac adresse 0.0.0.0.0.0

Question

Salut,

Ce n'est pas la permi&#232;re fois que quelqu'un demande &#231;a mais les r&#233;ponses donn&#233;es ne sont pas claires et je n'ai pas trouv&#233; de solution.

J'utilise un code trouv&#233; sur VBFrance, et sur certains postes de mon parc informatique l'adresse Mac que me renvoit mon prog est 0.0.0.0.0.0.

Avez-vous une explication?

J-L

cs_ITALIA · Answer

Je ne sais pas ce que tu utilises comme code mais test &#231;a :

http://www.planet-source-code.com/vb/scripts/ShowCode.asp?txtCodeId=44583&lngWId=1

It@li@

JLV1975 · Answer

Ton prog fonctionne mais il demande WMI, mais WMI n'est pas install&#233; sur tous les postes.

J-L

cs_ITALIA · Answer

et ce Code :

http://www.planet-source-code.com/vb/scripts/ShowCode.asp?txtCodeId=6249&lngWId=1

It@li@

JLV1975 · Answer

Il ne s'occupe pas de l'adresse Mac, de plus il utilise Winsock.
Je suis chiant mais je ne peux utiliser ni Winsock, ni WMI.

J-L

cs_CanisLupus · Answer

Salut, ton prog agit &#224; distance ou il est install&#233; sur chaque poste ?

Si c'est &#224; distance, va voir du c&#244;t&#233; SendARP :

http://vbnet.mvps.org/index.html?code/main/tocbyuse.htm

Cordialement, CanisLupus

JLV1975 · Answer

Il est install&#233; sur chaque poste.

J-L

cs_CanisLupus · Answer

Si c'est sur les postes, alors moi j'utilise &#231;a :

Dans un module

Private Const ERROR_SUCCESS                       As Long = 0
Private Const MAX_INTERFACE_NAME_LEN              As Long = 256
Private Const MAXLEN_IFDESCR                      As Long = 256
Private Const MAXLEN_PHYSADDR                     As Long = 8


Private Type MIB_IFROW
  wszName(0 To (MAX_INTERFACE_NAME_LEN - 1) * 2) As Byte
  dwIndex               As Long
  dwType                As Long
  dwMtu                 As Long
  dwSpeed               As Long
  dwPhysAddrLen         As Long
  bPhysAddr(0 To MAXLEN_PHYSADDR - 1) As Byte
  dwAdminStatus         As Long
  dwOperStatus          As Long
  dwLastChange          As Long
  dwInOctets            As Long
  dwInUcastPkts         As Long
  dwInNUcastPkts        As Long
  dwInDiscards          As Long
  dwInErrors            As Long
  dwInUnknownProtos     As Long
  dwOutOctets           As Long
  dwOutUcastPkts        As Long
  dwOutNUcastPkts       As Long
  dwOutDiscards         As Long
  dwOutErrors           As Long
  dwOutQLen             As Long
  dwDescrLen            As Long
  bDescr(0 To MAXLEN_IFDESCR - 1) As Byte
End Type


Private Type Infos_Interface
  Adresse_MAC           As String
  Type_Interface        As String
  Vitesse               As String
  Description           As String
End Type


Public Infos() As Infos_Interface


Private Declare Function GetIfTable _
  Lib "iphlpapi.dll" _
    ( _
      ByRef pIfTable As Any, _
      ByRef pdwSize As Long, _
      ByVal bOrder As Long _
    ) As Long


Declare Sub CopyMemory _
  Lib "kernel32" Alias "RtlMoveMemory" _
    ( _
      pDst As Any, _
      pSrc As Any, _
      ByVal ByteLen As Long _
    )


Public Sub Infos_Carte_Reseau()
Dim IPInterfaceRow As MIB_IFROW
Dim buff() As Byte
Dim cbRequired As Long
Dim nStructSize As Long
Dim nRows As Long
Dim cnt As Long
  
  Call GetIfTable(ByVal 0&, cbRequired, 1)


  If cbRequired > 0 Then


    ReDim buff(0 To cbRequired - 1) As Byte
   
    If GetIfTable(buff(0), cbRequired, 1) = ERROR_SUCCESS Then
   
      ' Sauvegarde de la longueur en octets de IPInterfaceRow
      nStructSize = LenB(IPInterfaceRow)


      ' Nombre d'entr&#233;es de la table (nb d'interfaces r&#233;seau d&#233;tect&#233;es)
      CopyMemory nRows, buff(0), 4
      
      ReDim Infos(nRows)
   
      For cnt = 1 To nRows
        DoEvents
        ' Type d'interface pour chaque entr&#233;e de la table
        CopyMemory IPInterfaceRow, buff(4 + (cnt - 1) * nStructSize), nStructSize
                   
        ' Adresse mac
        Infos(cnt).Adresse_MAC = Replace(Format(Hex(IPInterfaceRow.bPhysAddr(0)), "@@"), " ", "0") & " " & _
                                 Replace(Format(Hex(IPInterfaceRow.bPhysAddr(1)), "@@"), " ", "0") & " " & _
                                 Replace(Format(Hex(IPInterfaceRow.bPhysAddr(2)), "@@"), " ", "0") & " " & _
                                 Replace(Format(Hex(IPInterfaceRow.bPhysAddr(3)), "@@"), " ", "0") & " " & _
                                 Replace(Format(Hex(IPInterfaceRow.bPhysAddr(4)), "@@"), " ", "0") & " " & _
                                 Replace(Format(Hex(IPInterfaceRow.bPhysAddr(5)), "@@"), " ", "0")
        
      Next cnt
      
    End If
    
  End If
  
End Sub


Et tu interroges comme &#231;a :

Dim i As Integer
Infos_Carte_Reseau
For i = 1 To UBound(Infos)
MsgBox Infos(i).Adresse_MAC
Next

Explications : il peut y avoir plusieurs cartes r&#233;seau, voire des cartes virtuelles. Chez moi, c'est le plus souvent la derni&#232;re de la liste qui est la bonne.

Cordialement, CanisLupus

Mac adresse 0.0.0.0.0.0

7 réponses

Discussions similaires