Calculateur de sous reseaux ip.

Soyez le premier à donner votre avis sur cette source.

Vue 13 252 fois - Téléchargée 1 198 fois

Description

Programme qui permet a partir d'une ip est d'un masque de caculer (reelement avec operation logique et décalage) l' adresse de reseau, l'adresse de broadcast, le nombre de sous reseau possible et le nombre d'hote.

il n'y a pas de switch case, c'est vraiment une methode de calcul en vb.
le code est super simple, la methode est sur commenté.

tout pour comprendre comment fonctionne les calculs de masque !
application stricte d'un cours ip v4.

Source / Exemple :


Public Class IPSubNetCalculateur
 
    ''' <summary>
    ''' Calculateur Ip.
    ''' Source libre de droit (Domaine Publique) 
    ''' VB.NET 2008 Framework 3.5; je pense que cela compile avec n'importe quel VB.NET
    ''' la source est longue mais elle est sur commenté, c'etait une explication pour un pote.
    ''' </summary>
    ''' <remarks>jyropp#nospam#(at)hotmail.fr</remarks>
    ''' 
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click

        Dim ip1, ip2, ip3, ip4, mask1, mask2, mask3, mask4 As Byte
        Dim sub1, sub2, sub3, sub4, iplast1, iplast2, iplast3, iplast4 As Byte
        ' en VB les byte sont non signé, cela tombe bien...
        ' par exemple en C il aurait fallut metre Ubyte (unsigned).

        Dim masque, ip As String
        Dim total, tmp As Integer

        Subnet.Text = ""
        iplast.Text = ""
        IP_1.Text = ""
        nbhosts.Text = "0"
        nbsubnet.Text = "0"

        Try
            ' convertit le MaskedTextBox IP (192.168.0.1) > ip1=192 ; ip2=168 ; ip3=19 ; ip4=34
            ip = MaskedTextBox1.Text
            ip1 = CByte(ip.Substring(0, 3))
            ip2 = CByte(ip.Substring(4, 3))
            ip3 = CByte(ip.Substring(8, 3))
            ip4 = CByte(ip.Substring(12, 3))

            ' convertit le MasquedTextBox masq. > 255.255.240.0 > mask1=255 ; mask2=255; mask3=240 ; mask4 =0
            masque = MaskedTextBox2.Text
            mask1 = CByte(masque.Substring(0, 3))
            mask2 = CByte(masque.Substring(4, 3))
            mask3 = CByte(masque.Substring(8, 3))
            mask4 = CByte(masque.Substring(12, 3))

            'calcul du subnet
            ' ex   : 192.168.019.34
            ' masq : 255.255.240.0
            ' AND  ----------------
            '  =     192.168.016.0

            sub1 = ip1 And mask1
            sub2 = ip2 And mask2
            sub3 = ip3 And mask3
            sub4 = ip4 And mask4

            Subnet.Text = sub1.ToString + "." + sub2.ToString + "." + sub3.ToString + "." + sub4.ToString

            'affiche la premiere ip ( subnet + 1)
            ' 192.168.016.0 + 1 = 192.168.016.1

            IP_1.Text = sub1.ToString + "." + sub2.ToString + "." + sub3.ToString + "." + CStr(sub4 + CByte(1))

            'calcul de la derniere ip :
            'ip du subnet : 192.168.016.000
            ' not masque :  000.000.015.255     
            '       +        -------------
            '       =       192.168.31.255
            '   - 1 =       192.168.31.254

            iplast1 = sub1 + (Not mask1)
            iplast2 = sub2 + (Not mask2)
            iplast3 = sub3 + (Not mask3)
            iplast4 = sub4 + (Not mask4) - CByte(1)

            iplast.Text = iplast1.ToString + "." + iplast2.ToString + "." + iplast3.ToString + "." + iplast4.ToString

            'nb de sous reseau possible :
            'ex: mask 240 = 11110000 
            'décalage = 00001111 = 15
            '-1 = 14 et hop ;) on peut faire +1 si on veut comptabilisé l'adresse de reseau et le broadcast
            'perso j'aime bien la jouer a l'ancienne.
            'attention, si le mask n'est pas correcte : du genre 255.255.0.255 ; resultat incoherent.
            'il faudrait metre plus de controle d'erreur de saisie mais bon quant on a besoins
            'de calculer les subnets on est grand...

            If mask1 > 0 And mask2 = 0 Then nbsubnet.Text = CStr(nbnet(mask1))
            If mask2 > 0 And mask3 = 0 Then nbsubnet.Text = CStr(nbnet(mask2))
            If mask3 > 0 And mask4 = 0 Then nbsubnet.Text = CStr(nbnet(mask3))
            If mask4 > 0 And mask4 <= 255 Then nbsubnet.Text = CStr(nbnet(mask4))

            ' Nb hotes possible par sous reseaux
            ' on reconstitue le mask par decalage : 
            ' ---------- MASK1 --- MASK2 --MASK3----MASK4
            ' Integer = 11111111 11111111 11110000 00000000
            ' ensuite on complente a 1
            '           00000000 00000000 00001111 11111111
            ' on retire 1 et nous avons notre nb d'hote.

            total = Not (mask1)
            total = total << 24

            tmp = Not (mask2)
            tmp = tmp << 16
            total = total Or tmp

            tmp = Not (mask3)
            tmp = tmp << 8
            total = total Or tmp
            total = total Or (Not mask4)
            nbhosts.Text = CStr(total - 1)

            ' en cas d"exception c'est que vous vous ête gouré dans les valeurs de masque et d'ip....
            ' un peut simpliste comme methode mais bon... pour une source de demo. ;)

        Catch
            MsgBox("Erreur d' @IP et/ou de masque." _
                   & vbCrLf & " valeur ok : de 0.0.0.0 a 255.255.255.255", _
                   MsgBoxStyle.Critical)

        End Try

    End Sub
    Function nbnet(ByVal mask As Byte) As Integer
        ' provoque le décalage des bit de poid fort pour les transformer en bit de poid faible.
        ' ensuite, on retire 1 est on a notre nb de reseau possible...
        ' 254 = 1111 1110 > 0111 1111 = 127 - 1 return 126

        While (CByte(mask And 1) = 0)
            mask = mask >> 1
        End While

        'ex: avec 240 (11110000)
        ' tant que 1111 0000 AND 0000 0001 = FALSE
        ' décale les bit vers la droite de 1.
        ' donc : 0111 1000
        ' puis : 0011 1100
        '        0001 1110
        '        0000 1111 = TRUE = Fin de boucle !

        'ensuite 15 - 1 = 14 et renvoie cette valeur.
        Return (mask - CByte(1))
    End Function

End Class

Conclusion :


Bonne lecture, bonne revision.
esperant avoir été util.
A+

Codes Sources

A voir également

Ajouter un commentaire

Commentaire

DX90
Messages postés
40
Date d'inscription
dimanche 24 janvier 2010
Statut
Membre
Dernière intervention
14 septembre 2018
1 -
Excellente source; très bien commenté, je suis tombé sur ta source par hasard mais c'est ce qu'il me fallait exactement, ca va mettre utile pour mon taff, bien joué.

Vous n'êtes pas encore membre ?

inscrivez-vous, c'est gratuit et ça prend moins d'une minute !

Les membres obtiennent plus de réponses que les utilisateurs anonymes.

Le fait d'être membre vous permet d'avoir un suivi détaillé de vos demandes et codes sources.

Le fait d'être membre vous permet d'avoir des options supplémentaires.