Question de débutant

Question

Comment faire le .exe final qui peut être éxécuté sur mon ppc ?
J'ai fait un petit programme sous embedded visual basic 3.0 et voilà apres je ne sait pas comment il faut faire...

cs_SylMat · Answer

Salut,

il suffit juste de faire le .vb qui se trouve dans le menu file de evb3.0 etvoila tu le copie sur ton pocket et ca roule :o)

Sylvain  :big) 
Webmaster de pdafr.
sylmat@codes-sources.com

Mrx3 · Answer

Ah ok merci je savais pas que le pocket pc pouvais executer un .vb  :)

Mrx3 · Answer

Autre chose : il faut visual tools runtime, je l'ai téléchargé ici http://www.microsoft.com/windowsmobile/resources/downloads/developer/eula/evb_eula.mspx mais dans le fichier il y a plein de fichier et aucun executable et enfin bon voilà comment est-ce qu'on fait pour installer tout ça sur le ppc ?

netnrv · Answer

j'ai exactement le meme probleme je ne vois pas comment installer le runtime pour mon PPC 2003. ya pleins de fichier. apparememt j'ai lu kil fallais le mettre dans la rom. mais ou? help us svp

mais c supeeeer !

Du_Bo · Answer

copier le dans votre PDA et cliquer dessus il s'installe tout seul !!!

gboulay · Answer

J'ai un petit programme que je fais tourner sur un pc standart avec qbasic. Je voudrais le faire tourner sur mon pocket pc. Comment faire ? Je ne connais rien au langage pour PDA.
Voici le programme en texte.
Merci de votre aide
5 PRINT"programme 3 cpts PROPOFOL   "
10 PRINT"modele de KATARIA  P=28.5 kg   "
15 PRINT"temps en minutes et doses microgrammes   "
20 PRINT"concentrations cibles de 3 a 7 mcg/ml  "
25 PRINT
30 PRINT
35 INPUT"taper return  ";Z$
40 CLS
45 REM K1 K2 K3 K4 K5 sont  K31  K21  K12  K13 K10 respectivement
50 K1=.0025
55 K2=.039
60 K3=.069
65 K4=.029
70 K5=.062
75 V1=14820
80 V2=28785
85 V3=233985!
90 VD=V1+V2+V3
91 INPUT"concentration Css    ";C9
92 LD=C9*V1
93 MP=C9*V1*K5
94 PRINT"loading dose  ";LD:PRINT" maintenance infusion  ";MP
95 P=K1+K2+K3+K4+K5
100 Q=K2*K1+K3*K1+K4*K2+K5*K1+K5*K2
105 R=K2*K1*K5
110 AA=(3*Q-P*P)/3!
115 BB=(2*P*P*P-9*P*Q+27*R)/27!
120 TT=(-BB/2!)/(SQR((-AA*AA*AA/27!)))
125 PY=3.141592654#/180!
130 PI=3.141592654#
135 TH=PI/2!-ATN(TT/SQR(-TT*TT+1))
140 X1=2*(SQR((-AA/3!)))*COS(TH/3!)
145 X2=2*(SQR((-AA/3!)))*COS((TH/3!+120*PY))
150 X3=2*(SQR((-AA/3)))*COS((TH/3!+240*PY))
155 AL=P/3-X1
160 BE=P/3!-X2
165 DE=P/3!-X3
170 PRINT"      MENU PRINCIPAL  "
175 PRINT"1- remise a zero des 3 compartiments  "
180 PRINT"2- entrer un segment  "
185 PRINT"3- fin du programme   "
190 INPUT"choix ?   ";Z
195 IF Z=1 THEN GOTO 210
200 IF Z=2 THEN GOTO 240
205 IF Z=3 THEN GOTO 950
206 GOTO 190
210 C1=0!
215 C2=0!
220 C3=0!
230 GOTO 170
240 INPUT"entrer duree du segment en minutes    ";TS
245 INPUT"entrer increment d'affichage en minutes    ";I
250 INPUT"entrer bolus en microgrammes    ";X9:XD=X9*28.5*1000
255 INPUT"entrer perfusion en microgrammes par minute    ";X8:K6=X8*28.5/60*1000
260 C1=C1+XD/V1
270 F1=K6/V1+C1*(K2+K1)+C2*K3+C3*K4
275 G1=K6/V1*(K2+K1)+C1*K2*K1+C2*K3*K1+C3*K4*K2
280 H1=K6/V1*K2*K1
285 J1=C1
290 F2=C1*K2+C2*(K3+K4+K1+K5)
295 G2=K6/V1*K2+C1*K2*K1+C2*K1*(K3+K5)+C3*K4*K2
300 J2=C2
310 F3=C1*K1+C3*(K2+K3+K4+K5)
315 G3=K6/V1*K1+C1*K2*K1+C2*K1*K3+C3*K2*(K4+K5)
320 J3=C3
330 A1=(AL*(J1*AL-F1)+G1-H1/AL)/((BE-AL)*(DE-AL))
340 A2=(AL*(J2*AL-F2)+G2-H1/AL)/((BE-AL)*(DE-AL))
350 A3=(AL*(J3*AL-F3)+G3-H1/AL)/((BE-AL)*(DE-AL))
360 B1=(BE*(J1*BE-F1)+G1-H1/BE)/((AL-BE)*(DE-BE))
370 B2=(BE*(J2*BE-F2)+G2-H1/BE)/((AL-BE)*(DE-BE))
380 B3=(BE*(J3*BE-F3)+G3-H1/BE)/((AL-BE)*(DE-BE))
390 D1=(DE*(J1*DE-F1)+G1-H1/DE)/((AL-DE)*(BE-DE))
400 D2=(DE*(J2*DE-F2)+G2-H1/DE)/((AL-DE)*(BE-DE))
410 D3=(DE*(J3*DE-F3)+G3-H1/DE)/((AL-DE)*(BE-DE))
420 E=K6/(V1*K5)
430 T=0!
435 FOR T=0! TO TS STEP I
440 C1=(A1*EXP(-1*(AL*T))+B1*EXP(-1*(BE*T))+D1*EXP(-1*(DE*T))+E)
450 C2=(A2*EXP(-1*(AL*T))+B2*EXP(-1*(BE*T))+D2*EXP(-1*(DE*T))+E)
460 C3=(A3*EXP(-1*(AL*T))+B3*EXP(-1*(BE*T))+D3*EXP(-1*(DE*T))+E)
500 PRINT" ";T;
505 PRINT"    ";INT((C1*10000))/10000;
510 PRINT"     ";INT((C2*10000))/10000;
515 PRINT"     ";INT((C3*10000))/10000
520 NEXT T
550 INPUT"choix 1-nouvel increment 2-nouveau segment 3-retour menu 4-simuprojection  ";Z
555 IF Z=1 THEN GOTO 430
560 IF Z=2 THEN GOTO 240
570 IF Z=3 THEN GOTO 170
572 IF Z=4 THEN GOTO 600
575 GOTO 550
600 REM
605 PRINT"menu simulation projection  "
610 PRINT"1-entrer un segment  "
615 PRINT"2-retour a l'etat de depart des compartiments  "
620 INPUT"choix ?  ";Z
625 IF Z=1 THEN GOTO 650
630 IF Z=2 THEN GOTO 550
635 GOTO 600
650 REM
655 CA1=C1
660 CA2=C2
665 CA3=C3
670 INPUT"entrer duree du segment en mn  ";TS
675 INPUT"entrer increment d'affichage en mn  ";I
680 INPUT"entrer bolus -unites-  ";X9:XD=X9*28.5*1000
685 INPUT"entrer perfusion en mcg ou ng par mn  ";X8:K6=X8*28.5/60*1000
690 CA1=CA1+XD/V1
695 FA1=K6/V1+CA1*(K2+K1)+CA2*K3+CA3*K4
700 GA1=K6/V1*(K2+K1)+CA1*K2*K1+CA2*K3*K1+CA3*K4*K2
705 HA1=K6/V1*K2*K1
710 JA1=CA1
715 FA2=CA1*K2+CA2*(K3+K4+K1+K5)
720 GA2=K6/V1*K2+CA1*K2*K1+CA2*K1*(K3+K5)+CA3*K4*K2
725 JA2=CA2
730 FA3=CA1*K1+CA3*(K2+K3+K4+K5)
735 GA3=K6/V1*K1+CA1*K2*K1+CA2*K1*K3+CA3*K2*(K4+K5)
740 JA3=CA3
745 AA1=(AL*(JA1*AL-FA1)+GA1-HA1/AL)/((BE-AL)*(DE-AL))
750 AA2=(AL*(JA2*AL-FA2)+GA2-HA1/AL)/((BE-AL)*(DE-AL))
755 AA3=(AL*(JA3*AL-FA3)+GA3-HA1/AL)/((BE-AL)*(DE-AL))
760 BA1=(BE*(JA1*BE-FA1)+GA1-HA1/BE)/((AL-BE)*(DE-BE))
765 BA2=(BE*(JA2*BE-FA2)+GA2-HA1/BE)/((AL-BE)*(DE-BE))
770 BA3=(BE*(JA3*BE-FA3)+GA3-HA1/BE)/((AL-BE)*(DE-BE))
775 DA1=(DE*(JA1*DE-FA1)+GA1-HA1/DE)/((AL-DE)*(BE-DE))
780 DA2=(DE*(JA2*DE-FA2)+GA2-HA1/DE)/((AL-DE)*(BE-DE))
785 DA3=(DE*(JA3*DE-FA3)+GA3-HA1/DE)/((AL-DE)*(BE-DE))
790 E=K6/(V1*K5)
795 T=0!
800 FOR T=0 TO TS STEP I
805 CA1=(AA1*EXP(-1*(AL*T))+BA1*EXP(-1*(BE*T))+DA1*EXP(-1*(DE*T))+E)
810 CA2=(AA2*EXP(-1*(AL*T))+BA2*EXP(-1*(BE*T))+DA2*EXP(-1*(DE*T))+E)
815 CA3=(AA3*EXP(-1*(AL*T))+BA3*EXP(-1*(BE*T))+DA3*EXP(-1*(DE*T))+E)
820 PRINT" ";T;
825 PRINT"       ";INT((CA1*10000))/10000;
830 PRINT"       ";INT((CA2*10000))/10000;
835 PRINT"      ";INT((CA3*10000))/10000
840 NEXT T
845 INPUT"choix 1-nouvel increment  2-nouveau segment  3-retour menu simuprojection   ";Z
850 IF Z=1 THEN GOTO 600
855 IF Z=2 THEN GOTO 600
860 IF Z=3 THEN GOTO 550
865 GOTO 845
950 PRINT"fin du programme   "
1000 END


Question de débutant

6 réponses

Votre réponse

Discussions similaires