favicon et url longRésolu

Question

Mes cher(e)s ami(e)s
Voici mon problème
Je suis entrain de développer un navigateur internet, avec d'ouvrir plusieurs onglets,
J'ai pus connaître le favicon de chaque site
Par exp.  : google.fr/favicon.ico
Pour insérer le logo dans l'image de l'onglet, mais mon problème ce pose quand une personne rentre un url long comme : exp : 
http://www.vbfrance.com/infomsg.aspx?ajout=1
Je veux que soit par une méthode affiche dans un label la racine du site comme : http://www.vbfrance.com pour que je puis lui ajouter après 
http://www.vbfrance.com/favicon
Ou un autre moyen qui peut m'afficher la page principale du site
J'ai essayé avec le control inet et webbrowser mais pas de résultat.

Aidez moi svp, je suis vraiment désespérer.

merci à l'équipe

Renfield · Accepted Answer

Option Explicit

Private Declare Function InternetCrackUrl Lib "wininet.dll" Alias "InternetCrackUrlA" (ByVal lpszURL As String, ByVal dwUrlLength As Long, ByVal dwFlags As Long, lpUrlComponents As URL_COMPONENTS) As Long
Private Declare Function InternetCanonicalizeUrl Lib "wininet.dll" Alias "InternetCanonicalizeUrlA" (ByVal lpszURL As String, ByVal lpszBuffer As String, lpdwBufferLength As Long, ByVal dwFlags As Long) As Long
Private Const ICU_BROWSER_MODE = &H2000000
Private Const ICU_ESCAPE = &H80000000

Private Type URL_COMPONENTS
    StructSize As Long
    Scheme As String
    SchemeLength As Long
    nScheme As Long
    HostName As String
    HostNameLength As Long
    nPort As Long
    UserName As String
    UserNameLength As Long
    Password As String
    PasswordLength As Long
    URLPath As String
    UrlPathLength As Long
    ExtraInfo As String
    ExtraInfoLength As Long
End Type

Private Sub Form_Load()
    MsgBox FavIcon("http://www.windowsmedia.com/mg/Radio.asp?rf=1#radTop")
End Sub

Private Function FavIcon(ByVal vsURL As String) As String
Dim tURL As URL_COMPONENTS
Dim sBuffer As String
Dim nLength As Long
    sBuffer = Space$(1024)
    nLength = 1024
    If InternetCanonicalizeUrl(vsURL, sBuffer, nLength, ICU_BROWSER_MODE) Then
        vsURL = Strings.Left$(sBuffer, nLength)
        With tURL
            .StructSize = LenB(tURL)
            .Scheme = Space$(32)
            .SchemeLength = 32
            .nScheme = -1
            .HostName = Space$(256)
            .HostNameLength = 256
        End With
        InternetCrackUrl vsURL, Len(vsURL), ICU_ESCAPE, tURL
        With tURL
            FavIcon = Strings.Left$(.Scheme, .SchemeLength) & "://" & Strings.Left$(.HostName, .HostNameLength) & "/favicon.ico"
        End With
    End If
End Function


Renfield - Admin CodeS-SourceS - MVP Visual Basic

cs_Jack · Answer

Salut
"Je veux que soit par une méthode affiche dans un label la racine du site comme" : pas compris
Et quelle est ta question ?
Est-ce que c'est dans la transformation de la chaine :
http://www.vbfrance.com/infomsg.aspx?ajout=1
en
http://www.vbfrance.com/favicon
--> Voir les instructions Instr, InstrRev, Left, Mid, Right

ou bien c'est le téléchargement du fichier favicon.ico qui te bloque ?
Une icone n'est qu'un fichier --> Chercher comment télécharger des fichiers

Vala
Jack, MVP VB
NB : Je ne répondrai pas aux messages privés

Le savoir est la seule matière qui s'accroit quand on la partage (Socrate)

cs_amita · Answer

merci mon ami de vouloir m'aider
c'est mon problème c'est comment 
transformer :

http://www.vbfrance.com/infomsg.aspx?ajout=1 
en 
http://www.vbfrance.com/favicon 

si vous arrivez a me donner un expl d'utilisation de la transformation avec les instrucions  Instr, InstrRev, Left, Mid, Right 
aidez moi svp

merci à vous

Renfield · Answer

possible d'utiliser WinHttpCrackURL

ou InternetCrackUrl

Renfield - Admin CodeS-SourceS - MVP Visual Basic

cs_Jack · Answer

Amita : Ce que tu cherches à faire est simple. Chacune de ces instructions est explicitée dans l'aide de VB6
Le forum n'est pas là pour donner des cours particuliers, c'est à toi de faire l'effort de comprendre ce que tu écris, de faire des tests. 
Une fois que tu auras écrit quelques lignes de programme, montre-les nous et on te dira ce qui peut clocher, mais on ne fera pas le programme à ta place.

cs_amita · Answer

ma question est simple mon ami

j'ai essayé partout de changer ça par exp 
WB1.Navigate "http://www.windowsmedia.com/mg/Radio.asp?rf=1#radTop"

en ça

WB1.Navigate "http://www.windowsmedia.com/favicon.ico"

et que chaque 

adresse ajouter a WB1.Navigate " adresse longue"
ce tronsforme en WB1.Navigate "adresse.nomdedomaine/favicon.ico"
pour pouvoir récupérer et enregistrer la favicon et l'utiliser après.
le problème que l'adresse peutre par exp

www.hhhhh.co.fr/kkkkkk/mmmmm/mmm.html

merci à l'équipe

Renfield · Answer

ta question est bien comprise.

on t'a donné des éléments de réponse, utilises les...

Renfield - Admin CodeS-SourceS - MVP Visual Basic

cs_amita · Answer

dommage j'ai pas su comment
je suis bloqué.
aidez moi svp

merci à l'équipe

Renfield · Answer

Je sais, je devrais pas donner du code tout fait, mais ca montre bien que c'est faisable et que les solutions proposées fonctionnent.

la question expliquée et comprise, pas besoin de la répeter n fois en attendant d'avoir une réponse toute faite. Le but est que tu apprenne quelque chose.

là, ok, ça va fonctionner, mais saura tu pour autant lire la doc MSDN concernant les APIs ?
saura tu en déduire le code VB6 à utiliser, j'en doute :/


dommage, encore un avec les paumes poilues

Renfield - Admin CodeS-SourceS - MVP Visual Basic

cs_amita · Answer

Que dieux te protège Renfield
Merci mille fois

merci à l'équipe

Renfield · Answer

Laisse Dieu où il est...

en gros, tu as ton code, mais tu n'a rien lu de ce qu'on a pu te dire à coté....

s'rait temps de relever ses manches.

Renfield - Admin CodeS-SourceS - MVP Visual Basic

cs_amita · Answer

Si mon ami je vais m'y mêttre pour mieux apprendre.
merci a vous tous pour les conseils


merci à l'équipe

Renfield · Answer

je tiens à RE préciser que cette fonction n'est pas respectueuse de la norme HTML, mais d'une habitude établie que de nommer ce fichier favicon.ico

rien n'empeche techniquement d'utiliser un png, gif ou autre, nommé de la manière que l'on souhaite, simplement en indiquant ce fichier dans une entete de la page web visitée...


Renfield - Admin CodeS-SourceS - MVP Visual Basic

Favicon et url long

13 réponses

Votre réponse

Discussions similaires