Batnav: jeu de bataille navale pour mirc
Description
Voila un petit jeu de bataille navale en socket/picwin deux joueurs pour votre mIRC.
La qualité graphique au niveau des bateaux est assez rudimentaire mais je comptais vous présenter le système avant de m'aventurer plus loin dans le graphisme. J'attend donc vos avis sur la fonctionalité.
Consultez le readme pour connaîtres les commandes et les phases du jeu.
Amusez vous bien :p
Le zip est necessaire car il contient un .png nécessaire au lancement du jeu (histoire d'avoir une image de sonar pr mettre ds l'ambiance gueguerre :p)
La qualité graphique au niveau des bateaux est assez rudimentaire mais je comptais vous présenter le système avant de m'aventurer plus loin dans le graphisme. J'attend donc vos avis sur la fonctionalité.
Consultez le readme pour connaîtres les commandes et les phases du jeu.
Amusez vous bien :p
Source / Exemple :
on 1:start: hmake batnav 100
on 1:connect: localinfo -u
menu nicklist {
-
BatNav
.Inviter $1:.ctcp $1 batnav | hfree batnav | hmake batnav 100 | hadd batnav status $1 send | .disable #bnav.*
}
alias bataccept if ($hget(batnav,status) == $1 rec) .ctcp $1 batnav accept $ip
ctcp ^1:batnav:*: {
if (!$2) {
hfree batnav
hmake batnav 100
echo -a 2 $+ $timestamp 14››› $nick 2vous invite a jouer à BatNav: Tapez 14/bataccept $nick 2pour accepter
.disable #bnav.*
hadd -u120 batnav status $nick rec
}
elseif ($2 == accept) && ($3) {
socklisten bnavl
sockmark bnavl $3
mk.btlroom
.ctcp $nick batnav batok $ip $sock(bnavl).port
}
elseif ($2 == batok) && ($4) sockopen bnavr $3-4
halt
}
on 1:socklisten:bnavl: sockaccept bnavs | sockclose bnavl
on 1:sockopen:bnavr: {
mk.btlroom
sockwrite -nt bnavr JOIN $me
.disable #bnav.*
%boat.type = 5
%boat.n = $hget(batnav,boat.5)
%boat.pos = h
%boat.y = 0
%boat.x = 0
bnav.boat
.enable #bnav.pos
bnav.addtext status Placez vos bateaux
}
on 1:sockread:bnavs: {
if (!$sock($sockname)) { if (%d) { unset %d } | halt }
sockread %d
tokenize 32 %d
if ($1 == JOIN) {
.disable #bnav.*
%boat.type = 5
%boat.n = $hget(batnav,boat.5)
%boat.pos = h
%boat.y = 0
%boat.x = 0
bnav.boat
.enable #bnav.pos
bnav.addtext status $2 joined in
bnav.addtext status Placez vos bateaux
}
elseif ($1 == READY) && ($hget(batnav,ready1) == 1) { sockrename bnavs bnavu | .enable #bnav.game | bnav.addtext status A votre tour }
elseif ($1 == READY) && ($hget(batnav,ready1) == 0) { hadd batnav ready2 1 }
}
alias -l mk.btlroom {
hadd batnav ready1 0
hadd batnav ready2 0
hadd batnav boat.5 1
hadd batnav boat.4 2
hadd batnav boat.3 3
hadd batnav boat.2 2
hadd batnav score 0
hadd batnav lifes $calc($hget(batnav,boat.5) * 5 + $hget(batnav,boat.4) * 4 + $hget(batnav,boat.3) * 3 + $hget(batnav,boat.2) * 2)
hadd batnav hits 0
var %i1 = 1
while (%i1 <= 15) {
var %i2 = 1
while (%i2 <= 15) { hadd batnav $+($chr($calc(64 + %i1)),%i2) 0 | inc %i2 }
inc %i1
}
window -apdk0 @BatNav 200 200 746 502
window -phB +d @bn.buffer 0 0 0 0
window @bn.buffer 200 200 746 502
drawfill -rs @BatNav 0 $rgb(255,255,255) 1 1
drawrect -r @BatNav $rgb(0,199,77) 0 5 5 180 464
drawline -r @BatNav $rgb(0,199,77) 0 10 15 14 15
drawline -r @BatNav $rgb(0,199,77) 0 180 15 47 15
drawline -r @BatNav $rgb(0,199,77) 0 10 205 180 205
drawline -r @BatNav $rgb(0,199,77) 0 10 15 10 205
drawline -r @BatNav $rgb(0,199,77) 0 180 15 180 206
drawtext -r @BatNav $rgb(0,241,92) Fixedsys 10 15 8 Chat
drawline -r @BatNav $rgb(0,199,77) 0 10 218 14 218
drawline -r @BatNav $rgb(0,199,77) 0 180 218 63 218
drawline -r @BatNav $rgb(0,199,77) 0 10 325 180 325
drawline -r @BatNav $rgb(0,199,77) 0 10 218 10 325
drawline -r @BatNav $rgb(0,199,77) 0 180 218 180 326
drawtext -r @BatNav $rgb(0,241,92) Fixedsys 10 15 210 Unités
drawtext -r @BatNav $rgb(50,250,227) Tahoma 11 15 188 *** Chat session opens
drawtext -r @BatNav $rgb(50,250,227) Tahoma 11 15 227 $+($str($chr(7),5),$chr(160),:) Porte avion $+ $+($str($chr(160),1))
drawtext -r @BatNav $rgb(50,250,227) Tahoma 11 15 239 $+($str($chr(7),4),$str($chr(160),3),:) Sous marin $+ $+($str($chr(160),2))
drawtext -r @BatNav $rgb(50,250,227) Tahoma 11 15 251 $+($str($chr(7),3),$str($chr(160),5),:) Destroyer $+ $+($str($chr(160),4))
drawtext -r @BatNav $rgb(50,250,227) Tahoma 11 15 263 $+($str($chr(7),2),$str($chr(160),7),:) Pédalo $+ $+($str($chr(160),9))
drawtext -bpr @BatNav $rgb(50,250,227) 0 Tahoma 11 15 289 Score :
drawtext -bpr @BatNav $rgb(50,250,227) 0 Tahoma 11 15 301 Tirs :
drawpic -ts @BatNav 0 20 327 147 139 $scriptdirradar.png
drawrect -r @BatNav $rgb(0,199,77) 0 190 5 540 445
drawrect -rf @BatNav $rgb(0,241,92) 0 190 455 540 14
drawrect -r @BatNav $rgb(0,199,77) 0 190 455 540 14
drawline -r @BatNav $rgb(0,199,77) 0 190 30 730 30
drawline -r @BatNav $rgb(0,199,77) 0 215 5 215 450
var %l = 1, %y = 30, %x = 215, %tx = 227, %ty = 38
while (%l <= 15) {
drawline -r @BatNav $iif(%l == 1, $rgb(50,250,227),$rgb(0,199,77)) 0 190 %y 730 %y
drawline -r @BatNav $iif(%l == 1, $rgb(50,250,227),$rgb(0,199,77)) 0 %x 5 %x 450
drawtext -r @BatNav $rgb(0,241,92) Fixedsys 10 %tx 10 $chr($calc(64 + %l))
drawtext -r @BatNav $rgb(0,241,92) Fixedsys 10 $iif(%l < 10,198,193) %ty %l
inc %ty 28
inc %tx 34.4
inc %y 28
inc %x 34.3
inc %l 1
}
drawtext -r @BatNav $rgb(0,241,92) Fixedsys 10 198 10 -
drawcopy @BatNav 0 0 746 502 @bn.buffer 0 0
}
alias -l bnav.refscores {
drawrect -rf @BatNav 0 1 57 289 100 13
drawrect -rf @BatNav 0 1 57 301 100 13
drawtext -r @BatNav $rgb(50,250,227) Tahoma 11 57 289 $hget(batnav,score) $+ pts
drawtext -r @BatNav $rgb(50,250,227) Tahoma 11 57 301 $hget(batnav,hits) $+($chr(40),$round($calc($hget(batnav,score) * 100 / $hget(batnav,hits)),2),$chr(37),$chr(41))
}
alias -l bnav.addtext {
var %s = $1
tokenize 32 $2-
var %t = $1-, %i = 0, %p = %t
:bnlt
while ($width(%t,Tahoma,11) > 160) { var %t = $left(%t,-1), %i = $calc(%i + 1) }
drawcopy @BatNav 11 40 168 164 @BatNav 11 25
drawrect -rf @BatNav 0 1 11 190 168 15
drawtext -r @BatNav $iif(%s == rec,$rgb(50,250,227),$iif(%s = send,$rgb(255,255,255),$rgb(254,77,1))) Tahoma 11 15 188 %t
if ($right(%p,$+(-,$len(%t)))) { var %p = $right(%p,$+(-,$len(%t))), %i = 0, %t = %p | goto bnlt }
}
alias -l bnav.boat {
%boat.able = 1
var %c = %boat.type, %cx = $calc(225 + 34.4 * %boat.x), %cy = $calc(36 + 28 * %boat.y)
while (%c > 0) {
var %rgb = $rgb(50,250,227), %xx = $gettok($bnav.st(%cx,%cy),1,32), %xy = $gettok($bnav.st(%cx,%cy),2,32)
hadd batnav prov $hget(batnav,prov) $+(%xx,%xy)
if ($hget(batnav,$+(%xx,%xy)) == 1) { var %rgb = $rgb(255,255,255) | %boat.able = 0 }
drawrect -rf @BatNav $iif($hget(batnav,$+(%xx,%xy)) == 0.5,$rgb(254,77,1),%rgb) 0 %cx %cy 16 16
if (%boat.pos == h) inc %cx 34.4
else inc %cy 28
dec %c 1
}
}
alias -l bnav.st return $chr($calc(65 + $int($calc(($1 - 215) / 34.3)))) $int($calc(1 + (($2 - 29) / 28)))
alias -l bnav.ts return $calc(($asc($1) - 65) * 34.3 + 215) $calc(($2 - 1) * 28 + 30)
#bnav.pos off
on 1:keydown:@BatNav:*: {
if ($keyval == 37) && ($calc(%boat.x - 1) >= 0) {
dec %boat.x 1
drawcopy @bn.buffer 0 0 746 502 @BatNav 0 0
hdel batnav prov
bnav.boat
}
elseif ($keyval == 39) && ($iif(%boat.pos == v,$calc(%boat.x + 1),$calc(%boat.x + %boat.type)) <= 14) {
inc %boat.x 1
drawcopy @bn.buffer 0 0 746 502 @BatNav 0 0
hdel batnav prov
bnav.boat
}
elseif ($keyval == 38) && ($calc(%boat.y - 1) >= 0) {
dec %boat.y 1
drawcopy @bn.buffer 0 0 746 502 @BatNav 0 0
hdel batnav prov
bnav.boat
}
elseif ($keyval == 40) && ($iif(%boat.pos == v,$calc(%boat.y + %boat.type + 1),$calc(%boat.y + 2)) <= 15) {
inc %boat.y 1
drawcopy @bn.buffer 0 0 746 502 @BatNav 0 0
hdel batnav prov
bnav.boat
}
}
menu @BatNav {
rclick: {
if (%boat.pos == h) && ($calc(%boat.y + %boat.type) <= 15) { %boat.pos = v | drawcopy @bn.buffer 0 0 746 502 @BatNav 0 0 | hdel batnav prov | bnav.boat }
elseif (%boat.pos == v) && ($calc(%boat.x + %boat.type) <= 15) { %boat.pos = h | drawcopy @bn.buffer 0 0 746 502 @BatNav 0 0 | hdel batnav prov | bnav.boat }
}
sclick: {
if (%boat.able == 1) {
var %gn = 1
while (%gn <= $numtok($hget(batnav,prov),32)) { hadd batnav $gettok($hget(batnav,prov),%gn,32) 1 | inc %gn 1 }
drawcopy @BatNav 0 0 746 502 @bn.buffer 0 0
dec %boat.n 1
if (%boat.n > 0) { %boat.pos = h | %boat.y = 0 | %boat.x = 0 | bnav.boat }
elseif (%boat.type > 2) { dec %boat.type 1 | %boat.n = $hget(batnav,$+(boat.,%boat.type)) | %boat.pos = h | %boat.y = 0 | %boat.x = 0 | bnav.boat }
else {
hadd batnav ready1 1
if ($gettok($hget(batnav,status),2,32) == send) && ($hget(batnav,ready2) == 0) { sockwrite -nt bnavs READY }
if ($gettok($hget(batnav,status),2,32) == send) && ($hget(batnav,ready2) == 1) { sockwrite -nt bnavs READY | sockrename bnavs bnavu | .enable #bnav.game | bnav.addtext status A votre tour }
if ($gettok($hget(batnav,status),2,32) == rec) { sockwrite -nt bnavr READY | sockrename bnavr bnavd }
.enable #bnav.chat
.disable #bnav.pos
}
}
}
}
#bnav.pos end
on 1:sockread:bnavu: {
if (!$sock($sockname)) { if (%d) { unset %d } | halt }
sockread %d
tokenize 32 %d
if ($1 == HIT) && ($hget(batnav,$+($2,$3)) == 0) { sockwrite -nt bnavu STAT MISS $2 $3 | .enable #bnav.game | bnav.addtext status A votre tour }
elseif ($1 == HIT) && ($hget(batnav,$+($2,$3)) == 1) {
hadd batnav $+($2,$3) 0.5
%boat.type = 1
%boat.x = $calc($asc($2) - 65)
%boat.y = $calc($3 - 1)
bnav.boat
sockwrite -nt bnavu STAT GOT $2 $3
hdec batnav lifes 1
if ($hget(batnav,lifes) <= 0) { bnav.addtext status Perdu! | sockwrite -nt bnavu WIN | sockclose bnavu | .disable #bnav.* }
.enable #bnav.game | bnav.addtext status A votre tour
}
elseif ($1 == HIT) && ($hget(batnav,$+($2,$3)) == 0.5) { sockwrite -nt bnavu STAT ALR $2 $3 | .enable #bnav.game | bnav.addtext status A votre tour }
elseif ($1 == STAT) && ($2 == MISS) {
drawrect -rf @BatNav $rgb(50,250,227) 0 $bnav.ts($3,$4) 6 6
bnav.addtext status $+($3,$chr(44),$4,:) Raté
}
elseif ($1 == STAT) && ($2 == GOT) {
drawrect -rf @BatNav $rgb(254,77,1) 0 $bnav.ts($3,$4) 6 6
bnav.addtext status $+($3,$chr(44),$4,:) Touché
hinc batnav score 1
bnav.refscores
}
elseif ($1 == STAT) && ($2 == ALR) {
drawrect -rf @BatNav $rgb(0,199,77) 0 $bnav.ts($3,$4) 6 6
bnav.addtext status $+($3,$chr(44),$4,:) Déja joué
}
elseif ($1 == WIN) { bnav.addtext status Gagné! | sockclose bnavu | .disable #bnav.* }
elseif ($1 == TXT) && ($2) bnav.addtext rec $2-
}
on 1:sockread:bnavd: {
if (!$sock($sockname)) { if (%d) { unset %d } | halt }
sockread %d
tokenize 32 %d
if ($1 == HIT) && ($hget(batnav,$+($2,$3)) == 0) { sockwrite -nt bnavd STAT MISS $2 $3 | .enable #bnav.game | bnav.addtext status A votre tour }
elseif ($1 == HIT) && ($hget(batnav,$+($2,$3)) == 1) {
hadd batnav $+($2,$3) 0.5
%boat.type = 1
%boat.x = $calc($asc($2) - 65)
%boat.y = $calc($3 - 1)
bnav.boat
sockwrite -nt bnavd STAT GOT $2 $3
hdec batnav lifes 1
if ($hget(batnav,lifes) <= 0) { bnav.addtext status Perdu! | sockwrite -nt bnavd WIN | .disable #bnav.* }
.enable #bnav.game | bnav.addtext status A votre tour
}
elseif ($1 == HIT) && ($hget(batnav,$+($2,$3)) == 0.5) { sockwrite -nt bnavd STAT ALR $2 $3 | .enable #bnav.game | bnav.addtext status A votre tour }
elseif ($1 == STAT) && ($2 == MISS) {
drawrect -rf @BatNav $rgb(50,250,227) 0 $bnav.ts($3,$4) 6 6
bnav.addtext status $+($3,$chr(44),$4,:) Raté
}
elseif ($1 == STAT) && ($2 == GOT) {
drawrect -rf @BatNav $rgb(254,77,1) 0 $bnav.ts($3,$4) 6 6
bnav.addtext status $+($3,$chr(44),$4,:) Touché
hinc batnav score 1
bnav.refscores
}
elseif ($1 == STAT) && ($2 == ALR) {
drawrect -rf @BatNav $rgb(0,199,77) 0 $bnav.ts($3,$4) 6 6
bnav.addtext status $+($3,$chr(44),$4,:) Déja joué
}
elseif ($1 == WIN) { bnav.addtext status Gagné! | .disable #bnav.* }
elseif ($1 == TXT) && ($2) bnav.addtext rec $2-
}
on 1:sockclose:bnavu: {
if ($window(@BatNav)) bnav.addtext status Connection perdue
.disable #bnav.*
}
on 1:sockclose:bnavd: {
if ($window(@BatNav)) bnav.addtext status Connection perdue
.disable #bnav.*
}
#bnav.game off
menu @BatNav {
sclick: {
if ($inrect($mouse.x,$mouse.y,190,5,540,445) == $true) {
sockwrite -nt $iif($gettok($hget(batnav,status),2,32) == send,bnavu,bnavd) HIT $bnav.st($mouse.x,$mouse.y)
hinc batnav hits 1
bnav.refscores
.disable #bnav.game
}
}
}
#bnav.game end
#bnav.chat off
on 1:keydown:@BatNav:*: {
if ($keychar) && ($keyval != 13) {
drawrect -rf @BatNav $rgb(0,241,92) 0 190 455 540 14
drawrect -r @BatNav $rgb(0,199,77) 0 190 455 540 14
if ($keyval == 8) && ($hget(batnav,text)) && ($left($hget(batnav,text),-1)) hadd batnav text $left($hget(batnav,text),-1)
elseif ($keyval == 8) && ($hget(batnav,text)) && (!$left($hget(batnav,text),-1)) hdel batnav text
elseif ($keyval != 8) && ($width($+($hget(batnav,text),$replace($keychar,$chr(32),$chr(160))),Tahoma,11) <= 530) hadd batnav text $+($hget(batnav,text),$replace($keychar,$chr(32),$chr(160)))
drawtext -r @BatNav 0 Tahoma 11 195 456 $hget(batnav,text)
}
elseif ($keyval == 13) && ($hget(batnav,text)) {
bnav.addtext send $hget(batnav,text)
drawrect -rf @BatNav $rgb(0,241,92) 0 190 455 540 14
drawrect -r @BatNav $rgb(0,199,77) 0 190 455 540 14
sockwrite -nt $iif($gettok($hget(batnav,status),2,32) == send,bnavu,bnavd) TXT $hget(batnav,text)
hdel batnav text
}
}
#bnav.chat end
on 1:close:@BatNav:sockclose bnav?
Conclusion :
Le zip est necessaire car il contient un .png nécessaire au lancement du jeu (histoire d'avoir une image de sonar pr mettre ds l'ambiance gueguerre :p)
Vous n'êtes pas encore membre ?
inscrivez-vous, c'est gratuit et ça prend moins d'une minute !
Les membres obtiennent plus de réponses que les utilisateurs anonymes.
Le fait d'être membre vous permet d'avoir un suivi détaillé de vos demandes et codes sources.
Le fait d'être membre vous permet d'avoir des options supplémentaires.