Petites fonctions pour utiliser les dates

Soyez le premier à donner votre avis sur cette source.

Snippet vu 9 974 fois - Téléchargée 35 fois

Commenter

Contenu du snippet

Voilà qqs fonction qui failite l'utilisation des dates

Source / Exemple : 


<%
	' Converti une date en chaine
	Function DateToString(dDate)
		DateToString = Year(dDate) & Right("0" & Month(dDate), 2) & Right("0" & Day(dDate), 2)
	End Function

	' Converti datetime en chaine
	Function DateTimeToString(dDateTime)
		DateTimeToString = Year(dDateTime) & Right("0" & Month(dDateTime), 2) & Right("0" & Day(dDateTime), 2) & " " & Right("0" & Hour(dDateTime), 2) & ":" & Right("0" & Minute(dDateTime), 2) & ":" & Right("0" & Second(dDateTime), 2)
	End Function

	' converti time  en chaine
	Function TimeToString(dTime)
		TimeToString = Right("0" & Hour(dTime), 2) & ":" & Right("0" & Minute(dTime), 2) & ":" & Right("0" & Second(dTime), 2)
	End Function

	' converti une chaine en date ou datetime
	Function StringToDate(sDate)
		Dim dDate
		dDate = DateSerial(Left(sDate, 4), Mid(sDate, 5, 2), Mid(sDate, 7, 2))
		If Len(sDate) > 8 Then dDate = dDate + TimeSerial(Mid(sDate, 10, 2), Mid(sDate, 13, 2), Mid(sDate, 16, 2))
		StringToDate = dDate
	End Function

	' Date au format : Jour mois année
	Function GetDateLitteralDDMMYYYY(dDate)
		Dim sDate
		sDate = Day(dDate) & " " & MonthName(Month(dDate)) & " " & Year(dDate)

		GetDateLitteralDDMMYYYY = sDate
	End Function

	' Date au format : Jour mois année à Heure minutes secondes
	Function GetDateLitteralDDMMYYYYHHMMSS(dDate)
		Dim sDate
		sDate = GetDateLitteralDDMMYYYY(dDate)
		
		If (Hour(dDate) <> 0 or Minute(dDate) <> 0) Then sDate = sDate & " " & LANG_AT & " " & Right("0" & CStr(Hour(dDate)), 2) & "h" & Right("0" & CStr(Minute(dDate)), 2)
		GetDateLitteralDDMMYYYYHHMMSS = sDate
	End Function

	' Date au format : Jour/Mois/Année
	Function GetDateDDMMYY(dDate)
		GetDateDDMMYY = Right("0" & Day(dDate), 2) & "/" & Right("0" & Month(dDate), 2) & "/" & Right(Year(dDate), 2)
	End Function

	' Idem sauf que anné avec 4 chiffres
	Function GetDateDDMMYYYY(dDate)
		GetDateDDMMYYYY = Right("0" & Day(dDate), 2) & "/" & Right("0" & Month(dDate), 2) & "/" & Year(dDate)
	End Function

	' Date au format Jour/Mois/Année Heure:Minutes:Secondes
	Function GetDateDDMMYYHHMMSS(dDateTime)
		GetDateDDMMYYHHMMSS = GetDateDDMMYY(dDateTime) & " " & Right("0" & Hour(dDateTime), 2) & ":" & Right("0" & Minute(dDateTime), 2) & ":" & Right("0" & Second(dDateTime), 2)
	End Function
%>

Conclusion :


Vélà ça peut tjs servir ;)

@tte et bonn' prog'
pi0up51

A voir également

Ajouter un commentaire

Commentaires

Commenter la réponse de Utilisateur anonyme
S'inscrire maintenant

Vous n'êtes pas encore membre ?

inscrivez-vous, c'est gratuit et ça prend moins d'une minute !

Les membres obtiennent plus de réponses que les utilisateurs anonymes.

Le fait d'être membre vous permet d'avoir un suivi détaillé de vos demandes et codes sources.

Le fait d'être membre vous permet d'avoir des options supplémentaires.

Du même auteur (pi0up51)