Boite de dialogue parcourir repertoire

Soyez le premier à donner votre avis sur cette source.

Snippet vu 7 634 fois - Téléchargée 39 fois

Commenter

Contenu du snippet

J'ai trouve sur ce site une source qui permet d'utiliser la boite de dialogue parcourir repertoire de windows grace aux api.
Mais le probleme etait que lors de l'ouverture de la boite de dialogue on se retrouvait toujours sur poste de travail....
Pauvre utilisateur qui met dix plombes a trouver son repertoire et qui veut en changer...
La source n'est pas de moi mais comme j'ai vraiment gallerer pour la trouver je veux vous en faire profiter :

Source / Exemple : 


'==================================
'  Code trouve sur le site :
'  http://www.c2i.fr/code.asp?IDCode=1083
'==================================
'a mettre dans un module :
'==================================
Private Const BIF_STATUSTEXT = &H4&
Private Const BIF_RETURNONLYFSDIRS = 1
Private Const BIF_DONTGOBELOWDOMAIN = 2
Private Const MAX_PATH = 260

Private Const WM_USER = &H400
Private Const BFFM_INITIALIZED = 1
Private Const BFFM_SELCHANGED = 2
Private Const BFFM_SETSTATUSTEXT = (WM_USER + 100)
Private Const BFFM_SETSELECTION = (WM_USER + 102)

Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hWnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As String) As Long
Private Declare Function SHBrowseForFolder Lib "shell32" (lpbi As BrowseInfo) As Long
Private Declare Function SHGetPathFromIDList Lib "shell32" (ByVal pidList As Long, ByVal lpBuffer As String) As Long
Private Declare Function lstrcat Lib "kernel32" Alias "lstrcatA" (ByVal lpString1 As String, ByVal lpString2 As String) As Long

Private Type BrowseInfo
    hWndOwner As Long
    pIDLRoot As Long
    pszDisplayName As Long
    lpszTitle As Long
    ulFlags As Long
    lpfnCallback As Long
    lParam As Long
    iImage As Long
End Type

Private m_CurrentDirectory As String 'The current directory

Public Function BrowseForFolder(owner As Form, Title As String, StartDir As String) As String
'ouvre la boite de dialogue sélectionnant un dossier

Dim lpIDList As Long
Dim szTitle As String
Dim sBuffer As String
Dim tBrowseInfo As BrowseInfo
m_CurrentDirectory = StartDir & vbNullChar

szTitle = Title
With tBrowseInfo
    .hWndOwner = owner.hWnd
    .lpszTitle = lstrcat(szTitle, "")
    .ulFlags = BIF_RETURNONLYFSDIRS + BIF_DONTGOBELOWDOMAIN + BIF_STATUSTEXT
    .lpfnCallback = GetAddressofFunction(AddressOf BrowseCallbackProc) 'get address of function.
End With

lpIDList = SHBrowseForFolder(tBrowseInfo)
If (lpIDList) Then
    sBuffer = Space(MAX_PATH)
    SHGetPathFromIDList lpIDList, sBuffer
    sBuffer = Left(sBuffer, InStr(sBuffer, vbNullChar) - 1)
    BrowseForFolder = sBuffer
Else
    BrowseForFolder = ""
End If

End Function

Private Function BrowseCallbackProc(ByVal hWnd As Long, ByVal uMsg As Long, ByVal lp As Long, ByVal pData As Long) As Long

Dim lpIDList As Long
Dim ret As Long
Dim sBuffer As String

On Error Resume Next 'Sugested by MS to prevent an error from
'propagating back into the calling process.

Select Case uMsg

    Case BFFM_INITIALIZED
        Call SendMessage(hWnd, BFFM_SETSELECTION, 1, m_CurrentDirectory)
    Case BFFM_SELCHANGED
        sBuffer = Space(MAX_PATH)
        ret = SHGetPathFromIDList(lp, sBuffer)
        If ret = 1 Then
            Call SendMessage(hWnd, BFFM_SETSTATUSTEXT, 0, sBuffer)
        End If
End Select

BrowseCallbackProc = 0

End Function

' This function allows you to assign a function pointer to a vaiable.
Private Function GetAddressofFunction(add As Long) As Long
    GetAddressofFunction = add
End Function

'=====================================
'exemple d'utilisation, dans une procedure
'=====================================
Dim rep as String
rep = BrowseForFolder(Me, "Un texte", "c:\windows\")

Conclusion :


Merci à l'auteur de cette source, qui m'a bien aidée alors j'espere qu'elle vous aidera également
A la prochaine pour d'autres sources...

A voir également

Ajouter un commentaire

Commentaires

Signaler
gmelapet
Messages postés
8
Date d'inscription
lundi 27 octobre 2003
Statut
Membre
Dernière intervention
27 avril 2011
 -
Vraiment super, moi qui insistait à fond avec le composant microsoft common dialog !
Signaler
cs_Jack
Messages postés
14008
Date d'inscription
samedi 29 décembre 2001
Statut
Modérateur
Dernière intervention
28 août 2015
 62 -
Oups ! j'avais pas lu les posts précédents. Désolé
Signaler
econs
Messages postés
4030
Date d'inscription
mardi 13 mai 2003
Statut
Modérateur
Dernière intervention
23 décembre 2008
 19 -
C'est bien pour çà que je lui indiquait le commondialog ... Skalarache voulait pouvoir sélectionner des fichiers et pas juste des dossiers :o)
Signaler
cs_Jack
Messages postés
14008
Date d'inscription
samedi 29 décembre 2001
Statut
Modérateur
Dernière intervention
28 août 2015
 62 -
Econs : de mémoire, le Common Dialog ne permet pas la sélection de répertoire, juste de fichiers
Signaler
econs
Messages postés
4030
Date d'inscription
mardi 13 mai 2003
Statut
Modérateur
Dernière intervention
23 décembre 2008
 19 -
Quand tu es sous l'éditeur VB6, appuies sur les touches CTRL+T, coches la case "Microsoft Common Dialog 6.0".. et hop, tu as un nouveau contrôle dans ta barre d'outils.
Pour l'utiliser, un p'tit coup de recherche sur VBFrance. Il y a tellement de sources et de messages qui en parlent ...
Afficher les 23 commentaires
S'inscrire maintenant

Vous n'êtes pas encore membre ?

inscrivez-vous, c'est gratuit et ça prend moins d'une minute !

Les membres obtiennent plus de réponses que les utilisateurs anonymes.

Le fait d'être membre vous permet d'avoir un suivi détaillé de vos demandes et codes sources.

Le fait d'être membre vous permet d'avoir des options supplémentaires.

Du même auteur (fluminis)