Wantibncflood v1.1

Soyez le premier à donner votre avis sur cette source.

Vue 5 436 fois - Téléchargée 112 fois

Description

Un antiflood pour les clones BNC nouvelle version V1.1 ©2009

Si deux lignes identique qui se suivent en moins d'une seconde pour une longueur de caractères précise
Si c'est le cas ça sera considéré FLOOD. Les Pseudos qui postent les même caractères seront BAN sous un mask (* !*@000.000.000.00)

mode +i +m +R seront exécuté automatiquement lors de détection du flood et désactivé après le temps configuré (si la case reste vide le mode +i, +m, ou +R ne seront pas désactivé)

Ensuite tout ceux qui ont eus un BAN seront KICK (kick de tout les clones meme si c'est un OP)

Source / Exemple :


;______________________________Menu_____________________________

menu status,nicklist,menubar {
  -
  WantiBNCflood V1.1
  .Configurer:wf
  .Désinstaller:dwf
}

;_____________________________Alias______________________________

alias wf dialog $iif($dialog(wantibncfloodlog),-v,-m wantibncfloodlog) wantibncfloodlog
alias dwf {
  var %s $input(Attention!! Cette action désinstalle l?addon $crlf $+ voulez-vous désinstaller cet addon?,iy,WorldDMT - WantiBNCflood v1.1)
  if (%s) .unload -rs $qt($scriptdirWantibncflood.mrc) $input(Désinstallation de l'Addon terminé avec succes. $crlf $+ Merci d'avoir utilisé Worlddmt WantiBNCflood,oik7,WorldDMT - WantiBNCflood v1.1)
}
alias -l wbnc.info {
  if ($did(5) != %wbnc.5) {
    if ($did(5) isnum) && ($chr(46) !isin $did(5)) { var %edit.5 Modification de mode +i $iif(%wbnc.5,de $v1,0) à $did(5) sec. $crlf $+ | set %wbnc.5 $did(5) }
    else var %edit.5 Erreur mode +i numéro non valide $crlf $+
  }
  if ($did(8) != %wbnc.8) {
    if ($did(8) isnum) && ($chr(46) !isin $did(8)) { var %edit.8 Modification de mode +m $iif(%wbnc.8,de $v1,0) à $did(8) sec. $crlf $+ | set %wbnc.8 $did(8) }
    else var %edit.5 Erreur mode +m numéro non valide $crlf $+
  }
  if ($did(11) != %wbnc.11) {
    if ($did(11) isnum) && ($chr(46) !isin $did(11)) { var %edit.11 Modification de mode +R $iif(%wbnc.11,de $v1,0) à $did(11) sec. $crlf $+ | set %wbnc.11 $did(11) }
    else var %edit.5 Erreur mode +R numéro non valide $crlf $+
  }
  if ($did(16) != %wbnc.16) { var %edit.16 Modification du message raison de kick. | set %wbnc.16 $v1 }
  var %x %edit.5 $+ %edit.8 $+ %edit.11 $+ %edit.16
  if (%x) did -ra wantibncfloodlog 15 %x
  else did -ra wantibncfloodlog 15 Aucune modification n'a été effectuée
}
alias wantibncflood {
  var %tk $strip($1-),%x $modespl,%i,%b,%ban
  if ($hfind(fld $+ #,%tk,0).data) {
    %i = $v1
    notice # 4flood detectée 1by WorldDMT Script
    .raw mode # +imR
    while (%i) var %host %host $hfind(fld $+ #,%tk,%i).data,%i %i - 1
    tokenize 32 %host
    %i = $numtok(%host,32)
    while %i {
      %b = $+(+,$str(b,%x))
      %ban = $iif($eval(%i,2) > $eval(%x,2),$eval($+($,$calc($eval(%i,2) - $eval(%x,2) + 1),-,$eval(%i,2)),2),$eval($+($,1-,$eval(%i,2)),2))
      .raw mode # %b %ban
      dec %i $numtok(%ban,32)
    }
    if (%wbnc.5) .timer1 1 $v1 mode # -i
    if (%wbnc.8) .timer2 1 $v1 mode # -m
    if (%wbnc.11) .timer3 1 $v1 mode # -R
  }
  else if ($len($1-) > 110) hadd -mu1 fld $+ # $wildsite $1-
}

;_____________________________Dialog______________________________

dialog wantibncfloodlog {
  title WorldDMT Anti BNC Flood
  size -1 -1 109 136
  option dbu
  text WorldDMT? © 2009 v1.1, 1, 73 3 32 14, disable
  check Activer Anti BNC Flood, 2, 3 4 65 9
  box Désactivation des modes, 3, 2 16 105 41
  text Désactiver mode +i après, 4, 7 25 65 8
  edit %wbnc.5, 5, 76 24 15 9, limit 2
  text Sec., 6, 92 25 10 8
  text Désactiver mode +m après, 7, 7 35 65 8
  edit %wbnc.8, 8, 76 34 15 9, limit 2
  text Sec., 9, 92 35 10 8
  text Désactiver mode +R après, 10, 7 45 65 8
  edit %wbnc.11, 11, 76 44 15 9, limit 2
  text Sec., 12, 92 45 10 8
  box , 13, 2 56 105 34
  text Message après kick pour $crlf $+ les pseudos banni, 14, 5 61 100 15, center
  text info status et modifications..., 15, 6 92 100 27
  edit %wbnc.16, 16, 4 78 101 9, autohs
  button Enregistrer, 17, 2 122 52 12
  box , 18, 2 88 105 32
  button info versions, 19, 55 122 52 12
}
on *:dialog:wantibncfloodlog:*:*: {
  if ($devent == init) if (%wbnc.wp) did -c $dname 2
  elseif ($devent == sclick) {
    if ($did == 2) set %wbnc.wp $did(2).state
    elseif ($did == 17) wbnc.info
    elseif ($did == 19) var %x $input(WorldDMT - WantiBNCflood $crlf $+ Version 1.0 © 2008 $crlf $+ Version 1.1 © 2009 $crlf $crlf $+ World Design Multi Technology $crlf $+ E-mail: worlddmt@hotmail.com,io,WorldDMT - WantiBNCflood  v1.1)
  }
}

;_____________________________Event______________________________

on @*:NOTICE:*:#:if (%wbnc.wp) wantibncflood
on @*:ACTION:*:#:if (%wbnc.wp) wantibncflood
on @*:TEXT:*:#:if (%wbnc.wp) wantibncflood
on @*:ban:#:{
  if ($nick == $me) {
    var %i $ialchan($banmask,#,0).nick,%ban
    while (%i) {
      %ban = $ialchan($banmask,#,%i).nick
      if (%ban != $me) kick # %ban %wbnc.16 1WorldDMT Script
      dec %i
    }
  }
}
on *:load: {
  set %wbnc.5 0
  set %wbnc.8 0
  set %wbnc.11 0
  var %s $input(WorldDMT - WantiBNCflood a été bien installé. $crlf $+ Voulez-vous ouvrir l'addon?,iy,WorldDMT - WantiBNCflood v1.1)
  if (%s) wf
}
on *:unload:unset %wbnc.*

Conclusion :


le fichier zip contient le fichier wBNCv1.1.data, Loadez le.

vous avez de probleme?
copier/coller dans l'editbox de votre mIRC cette ligne comme elle est

//.load -rs $qt($sfile(*.data))

cherchez le fichier wBNCv1.1.data là où vous aviez dezipé puis validez

après avoir installé dans les menubar vous trouverez WantiBNCflood V1.1 tu choisis configurer pour configurer bien sur et désinstaller pour désinstaller l'addon

Codes Sources

A voir également

Ajouter un commentaire Commentaires
Messages postés
58
Date d'inscription
mercredi 21 novembre 2007
Statut
Membre
Dernière intervention
7 mars 2009

bjr,
WorldDMT oui tu a raison, et justement pour ceux qui le son voire qui posséde un tchat et qui son casi seul a le gérer ses bien d'avoire un automatisme de ban kick , pour sa je dit vut que ton code es bien penser il ne vira que les attack de bnc, et meme le proxy attack, bref ses pour l'améliorer que je dit sa, je parle en conaissance, car j'ai deja passser ses expérience ou on es seul sur des attack "FLOOD", alor si tu peut lui ajouter une option en plus si on es oper ben croit moi je suis preneur,et chui pas le seul j'en suis sur :)
++
Messages postés
871
Date d'inscription
jeudi 6 juillet 2006
Statut
Membre
Dernière intervention
6 janvier 2012
1
c'est pas tout le monde qui est ircop :)

@+
Messages postés
58
Date d'inscription
mercredi 21 novembre 2007
Statut
Membre
Dernière intervention
7 mars 2009

ses domage quant, mai bon, sinon tant cas faire pk pas ajouter un auto kill ou meme un auto gline quant on es sur du flood et de l'attack en question ..
++
Messages postés
58
Date d'inscription
mercredi 21 novembre 2007
Statut
Membre
Dernière intervention
7 mars 2009

slt,
oui je sais ses quoi ses mode :), je vouler dire dans le code que l'on puise choisir les mode que on veut activer ou pas genre un croix a cocher,
@+
Messages postés
871
Date d'inscription
jeudi 6 juillet 2006
Statut
Membre
Dernière intervention
6 janvier 2012
1
Un flood est un flood op ou pas ce n’est pas une blague ^^

Pour les modes +imR
Dans ce genre de flood, les clones partent du chan ensemble et rentrent ensemble tu auras un join/part flood
Avec +i tu va interdire ce jarre de chose même si c'est interdit les +i dans le chan mais tu le fait juste pour un temps a cause d'un problème de protection :)

Le +m pour qu'ils n'arrivent plus à envoyer un message sur le chan donc tu les interdis de continué leurs flood

Et enfin pour le +R car la plupart des clones ne sont pas regiter donc ils ne pourront plus rentrer sur le chan

Le mode +imR ne s'exécute qu’au cas que le code détecte un flood si non rien n'est exécuté

Et si c'est interdit les +i, c'est simple une petite commande qui s'appel "/mode #chan -i" va arranger le problème :)

La version 1.1 a le même but que la version précédente, mais il y a eut une amélioration au niveau du code

Regarde le nouveau code et l'ancien (tu dois l'avoir chez toi normalement) et tu verras la différance


@+
Afficher les 20 commentaires

Vous n'êtes pas encore membre ?

inscrivez-vous, c'est gratuit et ça prend moins d'une minute !

Les membres obtiennent plus de réponses que les utilisateurs anonymes.

Le fait d'être membre vous permet d'avoir un suivi détaillé de vos demandes et codes sources.

Le fait d'être membre vous permet d'avoir des options supplémentaires.