Voila une classe toute bete et sans pretention, qui est une adaptation en .Net d'un code que j'avais fait en Delphi, et qui permet de chercher toute les machines de votre reseau via l'API WNetEnumResource.
Source / Exemple :
'----------------------------------------------------------------------------
' Enumération des machines de votre réseau
' Ecrit par LEVEUGLE Damien
' Elguevel Software (c) 2010
'
' Mise à jour de code pour CodeSource le 27/01/2010
'----------------------------------------------------------------------------
Imports System.Runtime.InteropServices
Imports System.Runtime.InteropServices.Marshal
Imports System.Threading
''' <summary>
''' Classe de recherche des machines d'un réseau
''' </summary>
''' <auteur>LEVEUGLE Damien</auteur>
''' <remarks></remarks>
Public Class ElgNetwork
#Region "Evenements"
Public Event OnSuccess(ByVal sender As Object, ByVal e As EventArgs)
#End Region
#Region "Attributs"
Private _ListMachine As List(Of String)
Private _Provider As String = ""
#End Region
#Region "Proprietés"
''' <summary>
''' Liste des machines trouvées
''' </summary>
''' <remarks></remarks>
Public ReadOnly Property Machines() As List(Of String)
Get
Return _ListMachine
End Get
End Property
''' <summary>
''' Provider
''' </summary>
''' <remarks>Vous pouvez specifier ici le nom de votre réseau/domaine</remarks>
Public Property Provider() As String
Get
Return _Provider
End Get
Set(ByVal value As String)
_Provider = value
End Set
End Property
#End Region
#Region "Structures"
Public Structure NETRESOURCE
Dim dwScope As Integer
Dim dwType As Integer
Dim dwDisplayType As Integer
Dim dwUsage As Integer
Dim lpLocalName As String
Dim lpRemoteName As String
Dim lpComment As String
Dim lpProvider As String
End Structure
#End Region
#Region "Constantes"
Private Const RESOURCEDISPLAYTYPE_DOMAIN = &H1
Private Const RESOURCE_GLOBALNET = &H2
Private Const RESOURCETYPE_DISK = 1
Private Const RESOURCE_CONTEXT = 5
Private Const RESOURCEUSAGE_CONTAINER = &H2
Private Const RESOURCETYPE_ANY = &H0
Private Const ERROR_NO_MORE_ITEMS = 259&
Private Const BUFFER_SIZE = 131072
#End Region
#Region "Importation librairies (API Win32)"
''' <documentation>
''' http://msdn.microsoft.com/en-us/library/aa385478(VS.85).aspx
''' </documentation>
<DllImport("mpr.dll", CharSet:=CharSet.Auto)> _
Public Shared Function WNetOpenEnumA(ByVal dwScope As Integer, ByVal dwType As Integer, ByVal dwUsage As Integer, ByRef lpNetResource As NETRESOURCE, ByRef lphEnum As Integer) As Integer
End Function
''' <documentation>
''' http://msdn.microsoft.com/en-us/library/aa385449(VS.85).aspx
''' </documentation>
<DllImport("mpr.dll", CharSet:=CharSet.Auto)> _
Public Shared Function WNetEnumResourceA(ByVal hEnum As Integer, ByRef lpcCount As Integer, ByVal lpBuffer As Integer, ByRef lpBufferSize As Integer) As Integer
End Function
''' <documentation>
''' http://msdn.microsoft.com/en-us/library/aa385431(VS.85).aspx
''' </documentation>
<DllImport("mpr.dll", CharSet:=CharSet.Auto)> _
Public Shared Function WNetCloseEnum(ByVal hEnum As Integer) As Integer
End Function
#End Region
#Region "Méthodes"
''' <summary>
''' Recherche les machines du reseau et les stocks dans _ListMachine
''' </summary>
''' <remarks></remarks>
Public Sub Chercher()
Me._ListMachine.Clear()
Dim Resource As NETRESOURCE = Nothing
Dim pBuffer As IntPtr = AllocHGlobal(BUFFER_SIZE)
Dim Buffer As Integer = pBuffer.ToInt32
Dim NetCount As Integer = -1
Dim NetHandle As Integer = 0
' On rempli la structure NetResource
Resource.dwDisplayType = RESOURCEDISPLAYTYPE_DOMAIN
Resource.dwScope = RESOURCE_GLOBALNET
Resource.dwType = RESOURCETYPE_ANY
Resource.dwUsage = RESOURCEUSAGE_CONTAINER
Resource.lpProvider = Me._Provider
' http://msdn.microsoft.com/en-us/library/aa385478(VS.85).aspx
Dim RetourWNetOpenEnum As Integer = WNetOpenEnumA(RESOURCE_CONTEXT, RESOURCETYPE_DISK, 0, Resource, NetHandle)
Thread.Sleep(10)
' Si erreur on stop immédiatement
If (RetourWNetOpenEnum <> 0) Then
If (NetHandle <> 0) Then
WNetCloseEnum(NetHandle)
End If
Return
End If
Dim RetourWNetEnumResource As Integer = 0
Do
' http://msdn.microsoft.com/en-us/library/aa385449(VS.85).aspx
RetourWNetEnumResource = WNetEnumResourceA(NetHandle, NetCount, Buffer, BUFFER_SIZE)
Thread.Sleep(10)
' Si fini on libère la mémoire, et on stop
If ((RetourWNetEnumResource > 0) And (RetourWNetEnumResource <> ERROR_NO_MORE_ITEMS)) Then
FreeHGlobal(pBuffer)
WNetCloseEnum(NetHandle)
RaiseEvent OnSuccess(Me, Nothing)
Return
End If
For Boucle As Integer = 1 To NetCount
Dim iPtr As New IntPtr(Buffer) ' 4
Resource = CType(PtrToStructure(iPtr, GetType(NETRESOURCE)), NETRESOURCE) ' 32
Buffer += SizeOf(Resource) ' Incremente position pointeur
' Ajoute nom de la machine à la collection.
If (Not Resource.lpRemoteName Is Nothing) Then
Dim Poste As String = Resource.lpRemoteName
' Ici le SubString permet de virer les "\\"
Me._ListMachine.Add(Poste.Trim.Substring(2))
End If
Next
Loop While (RetourWNetEnumResource <> ERROR_NO_MORE_ITEMS)
FreeHGlobal(pBuffer)
' http://msdn.microsoft.com/en-us/library/aa385431(VS.85).aspx
WNetCloseEnum(NetHandle)
' On est arrivé à la fin, on lance l'evenement
Thread.Sleep(10)
RaiseEvent OnSuccess(Me, Nothing)
End Sub
#End Region
#Region "Constructeur"
''' <summary>
''' Constructeur par defaut
''' </summary>
''' <remarks></remarks>
Public Sub New()
_ListMachine = New List(Of String)
End Sub
''' <summary>
''' Constructeur surchargé
''' </summary>
''' <remarks></remarks>
Public Sub New(ByVal Provider As String)
MyClass.New()
_Provider = Provider
End Sub
#End Region
End Class
Conclusion :
Notes, commentaires et surtout améliorations sont les bienvenues ...
Vous n'êtes pas encore membre ?
inscrivez-vous, c'est gratuit et ça prend moins d'une minute !
Les membres obtiennent plus de réponses que les utilisateurs anonymes.
Le fait d'être membre vous permet d'avoir un suivi détaillé de vos demandes et codes sources.
Le fait d'être membre vous permet d'avoir des options supplémentaires.