Conjugaison - picwin qui conjugue tous les verbes

Soyez le premier à donner votre avis sur cette source.

Vue 22 375 fois - Téléchargée 218 fois

Description

Encore une PicWin, je commence à bien les aimer :)

Celle la a été faite en pensant à Wims :p
Simplicité et facilité sont au rendez-vous.

Tapez /conjugaison pour lancer la PicWin.
Ensuite cliquez sur l'editbox (le chariot apparaîtra), rentrer votre verbe au clavier, faites Entrée ou cliquez sur OK.
Le chariot peut être déplacé à l'aide d'un clic gauche, pour modifier/corriger plus rapidement le verbe.
La conjugaison de votre verbe s'affichera en moins d'une seconde :)
Selectionnez ensuite le mode puis le temps souhaité

J'espère ne plus voir d'erreurs de grammaire après ça :p
(surtout "tu mange" sans S, n'est-ce pas Wims ? :p)

Source / Exemple :


;*****************
;  Conjugaisons
;   By ArKanis
;   arkanis.eu
;*****************

;Conjugaison provenant du site www.leconjugueur.com
;Commande : /conjugaison

;*******
;Sockets
;*******
alias -l s.conj {
  if (!$1-) return
  conj.freehash
  sockclose conjugaison
  hadd -m Conjugaison Verbe $lower($1-)
  hadd -m Conjugaison Existance existe
  sockopen conjugaison www.leconjugueur.com 80
}
on *:sockopen:conjugaison:{
  if ($sockerr) return
  sockwrite -n $sockname GET $+(http://www.leconjugueur.com/php/newconjugue.php?lang=fr&oblige=N&verbe=,$replace($hget(Conjugaison,Verbe),$chr(165),$+($chr(37),20)))
  sockwrite -n $sockname Host: conjugueur.com
  sockwrite -n $sockname $crlf
}
on *:sockopen:conjugaison2:{
  if ($sockerr) return
  sockwrite -n $sockname GET $+(http://www.leconjugueur.com/php/newconjugue.php?lang=fr&oblige=Y&verbe=,$replace($hget(Conjugaison,Verbe),$chr(165),$+($chr(37),20)))
  sockwrite -n $sockname Host: conjugueur.com
  sockwrite -n $sockname $crlf
}

on *:sockread:conjugaison*:{
  var %a
  sockread %a
  if (Il s'agit peut-être d'une faute d'orthographe isin %a) {
    hadd -m Conjugaison Existance peut ne pas exister
    sockclose conjugaison2
    sockopen conjugaison2 www.leconjugueur.com 80
  }
  elseif (<p class="verbe">Recherche isin %a) {
    if ($hget(ConjRecherche)) hfree ConjRecherche
    sockrename $sockname ConjRecherche
    hdel Conjugaison Existance
  }
  elseif (Ceci n'est pas un verbe. isin %a) hadd -m Conjugaison Existance ne peut pas exister !
  elseif ($regex(%a,class="mode">(.+)</p>)) { hadd -m Temp Mode $regml(1) | sockmark $sockname 1 }
  elseif (<div id="conjug"> isin %a) {
    hadd -m Temp Pers 1
    var %u = $replace($+($hget(Temp,Mode),£,$hget(Temp,$+(Temps,$hget(Temp,Current)))),$chr(32),$chr(165))
    hadd -m Conjugaison $replace($+($hget(Temp,Mode),£,$hget(Temp,$+(Temps,$hget(Temp,Current))),£,$hget(Temp,Pers)),$chr(32),$chr(165)) $conjug.rem.balises(%a)
  }
  elseif ($regex(Conj,%a,/<li>(.+)</li>/Ug)) {
    var %t = 1
    while $remove($regml(Conj,%t),&nbsp;) {
      hadd -m Temp $+(Temps,%t) $conjug.rem.balises($ifmatch)
      inc %t
    }
    hadd -m Temp Current 1
  }
  elseif (</li><li> isin %a) {
    hinc Temp Current
    hadd -m Temp Pers 1
    var %u = $replace($+($hget(Temp,Mode),£,$hget(Temp,$+(Temps,$hget(Temp,Current)))),$chr(32),$chr(165))
    hadd -m Conjugaison $replace($+($hget(Temp,Mode),£,$hget(Temp,$+(Temps,$hget(Temp,Current))),£,$hget(Temp,Pers)),$chr(32),$chr(165)) $conjug.rem.balises(%a)
  }
  elseif (<div style="clear: both"> isin %a) sockmark $sockname 2
  elseif ($sock($sockname).mark == 2) {
    hinc Temp Pers
    hadd -m Conjugaison $replace($+($hget(Temp,Mode),£,$hget(Temp,$+(Temps,$hget(Temp,Current))),£,$hget(Temp,Pers)),$chr(32),$chr(165)) $$conjug.rem.balises(%a)
  }
}
alias -l conjug.rem.balises { var %o, %r = $regsub($1-,/(<[^>]+>)/g,,%o) | return $remove(%o,&nbsp;) }

on *:sockclose:conjugaison*:{
  if (($sockname == conjugaison) && ($hget(Conjugaison,Existance) == peut ne pas exister)) return
  if (($window(@Conjugaison)) && ($window(@Conjugaison.copy))) drawcopy -n @Conjugaison.copy -1 -1 455 260 @Conjugaison 0 0 455 260
  else conjugaison
  w.conjugaison.draw
  window -a @Conjugaison
}

;*********
;Recherche
;*********
on *:sockread:ConjRecherche:{
  var %a
  sockread %a
  if ($regex(%a,href="newconjugue.php\?.+>(.+)</a>)) hadd -m ConjRecherche $regml(1) 1
}
on *:sockclose:ConjRecherche:{
  if (($window(@Conjugaison)) && ($window(@Conjugaison.copy))) drawcopy -n @Conjugaison.copy -1 -1 455 260 @Conjugaison 0 0 455 260
  else conjugaison
  w.conjugaison.draw.recherche
  window -a @Conjugaison
}

;******
;Dessin
;******

alias conjugaison {
  if ($hget(WConj)) hfree WConj
  if ($window(@Conjugaison)) window -a @Conjugaison
  else window -BCdg0k0pRz +dl @Conjugaison 0 0 455 260
  w.conjugaison
}

alias -l w.conjugaison {
  drawrect -fnr @Conjugaison 16777215 1 0 0 455 260
  drawrect -dfnr @Conjugaison 8553090 1 3 3 453 258 20 20
  drawrect -dnr @Conjugaison 0 1 1 1 453 258 20 20
  drawfill -nr @Conjugaison 14999520 0 10 10
  drawtext -nr @Conjugaison 0 Tahoma 10 15 25 Conjuguer :
  drawrect -fnr @Conjugaison 16773360 1 75 25 100 15
  drawrect -fnr @Conjugaison 14141640 1 177 25 30 15
  drawtext -fnr @Conjugaison 0 Tahoma 10 185 26 OK
  ;titlebar
  drawrect -fnr @Conjugaison 16777215 1 1 1 453 20
  drawline -nr @Conjugaison 0 1 1 20 1 17 4 14 9 12 12 11 16 10 21 8 25 6 29 2 35 1 453 1 453 20 1 20
  drawfill -nr @Conjugaison 7895160 0 18 15
  drawline -nr @Conjugaison 5921370 1 1 21 453 21
  drawtext -onr @Conjugaison 1315860 Tahoma 10 37 6 Conjugaison - By ArKanis
  drawtext -onr @Conjugaison 16777215 Tahoma 10 36 5 Conjugaison - By ArKanis
  ;Fermer
  drawrect -dfnr @Conjugaison 9868950 1 430 3 18 17 5 5
  drawrect -dfnr @Conjugaison 3289650 1 429 2 18 17 5 5
  drawrect -dfnr @Conjugaison 255 1 430 3 16 15 5 5
  drawtext -fonr @Conjugaison 16777215 Tahoma 10 435 4 X
  ;Réduire
  drawrect -dfnr @Conjugaison 9868950 1 410 3 18 17 5 5
  drawrect -dfnr @Conjugaison 3289650 1 409 2 18 17 5 5
  drawrect -dfnr @Conjugaison 58880 1 410 3 16 15 5 5
  drawtext -fonr @Conjugaison 16777215 Tahoma 10 415 4 _
  drawdot @Conjugaison
  window -a @Conjugaison
  if (!$window(@Conjugaison.copy)) window -g0hk0p +d @Conjugaison.copy 0 0 455 260
  drawcopy @Conjugaison 0 0 455 260 @Conjugaison.copy -1 -1 455 260
}
menu @Conjugaison {
  sclick:conj.sclick $mouse.x $mouse.y
  mouse:conj.mouse $mouse.x $mouse.y
}
alias -l conj.send {
  if ($hget(WConj,Editbox)) {
    s.conj $remove($ifmatch,$chr(124))
    drawrect -r @Conjugaison 11509920 2 177 25 30 15
    .timer -m 1 200 drawrect -r @Conjugaison 14141640 2 177 25 30 15
    .timerconjcli off
  }
}
on *:keydown:@Conjugaison:*:{
  if ($keyval == 16) hadd -m Temp Remember Shift
  elseif ($keyval == 221) hadd -m Temp Remember $iif($hget(Temp,Remember) == shift,¨,^)
  elseif ($keyval == 13) conj.send
  if ($hget(WConj,Selected)) {
    if (($keychar isalpha) || ($keychar == $chr(32)) || ($istok(à-é-è-ç-',$keychar,45))) {
      var %a = $keychar
      if ($istok(¨-^,$hget(Temp,Remember),45)) {
        var %b = $findtok(a-e-i-o-u,$keychar,45)
        if (%b) {
          if ($hget(Temp,Remember) == ¨) var %l = ä-ë-ï-ö-ü
          else var %l = â-ê-î-ô-û
          var %a = $gettok(%l,%b,45)
        }
      }
      if ($hget(Temp)) hdel Temp Remember
      if ($width($+($hget(WConj,Editbox),$keychar),Tahoma,10) > 97) return
      if ($left($hget(WConj,Editbox),1) == $chr(124)) {
        hadd -m WConj Editbox $replace($+(%a,$chr(124),$gettok($hget(WConj,Editbox),1,124)),$chr(32),$chr(165))
      }
      else hadd -m WConj Editbox $replace($+($gettok($hget(WConj,Editbox),1,124),%a,$chr(124),$gettok($hget(WConj,Editbox),2,124)),$chr(32),$chr(165))
    }
    elseif ($keyval == 8) {
      ;effacer à gauche du chariot
      if ($left($hget(WConj,Editbox),1) == $chr(124)) return
      else hadd -m WConj Editbox $+($left($gettok($hget(WConj,Editbox),1,124),-1),$chr(124),$gettok($hget(WConj,Editbox),2,124))
    }
    elseif ($keyval == 46) {
      ;effacer à droite du chariot
      if ($left($hget(WConj,Editbox),1) == $chr(124)) hadd -m WConj Editbox $replace($+($chr(124),$right($hget(WConj,Editbox),-2)),$chr(32),$chr(165))
      else hadd -m WConj Editbox $replace($+($gettok($hget(WConj,Editbox),1,124),$chr(124),$right($gettok($hget(WConj,Editbox),2,124),-1)),$chr(32),$chr(165))
    }
    elseif ($istok(37 39,$keyval,32)) {
      ;Deplacement gauche et droite
      var %p = $calc($pos($hget(WConj,Editbox),$chr(124)) $iif($keyval == 37,-2)), %c = $remove($hget(WConj,Editbox),$chr(124))
      if (($keyval == 37) && (%p == 0)) hadd -m WConj Editbox $replace($+($chr(124),%c),$chr(32),$chr(165))
      elseif (%p < 0) return
      else hadd -m WConj Editbox $replace($+($left(%c,%p),$chr(124),$right(%c,$+(-,%p))),$chr(32),$chr(165))
    }
    elseif ($keyval == 35) hadd -m WConj Editbox $replace($+($remove($hget(WConj,Editbox),$chr(124)),$chr(124)),$chr(32),$chr(165))
    elseif ($keyval == 36) hadd -m WConj Editbox $replace($+($chr(124),$remove($hget(WConj,Editbox),$chr(124))),$chr(32),$chr(165))
    else return
    .timerconjcli -m 0 500 conj.cli
    conj.editbox
    drawdot @Conjugaison
  }
}
alias -l conj.editbox {
  drawrect -fnr @Conjugaison 16773360 1 75 25 100 15
  var %b = $iif($1 == force,$2,$hget(WConj,Editbox)), %p = $pos(%b,$chr(124)), %c = $replace($remove(%b,$chr(124)),$chr(165),$chr(32)), %x = $calc(76 + $width($left(%c,$calc(%p -1)),Tahoma,10))
  if (%c) drawtext -cnr @Conjugaison 0 Tahoma 10 77 26 97 13 %c
  if (%p) drawline -nr @Conjugaison 0 1 %x 26 %x 39
}
alias -l conj.sclick {
  if (!$window(@Conjugaison)) return
  if ($inrect($1,$2,75,25,100,15)) {
    hadd -m WConj Selected 1
    var %c = $hget(WConj,Editbox), %t = 0, %l = $len(%c), %d = 0, %e
    while %t < %l {
      if ($mid(%c,%t,1) == $chr(124)) var %d = 0
      var %a = $calc(75 + $width($left(%c,%t),Tahoma,10))
      if ($1 >= %a) var %e = $remove(%c,$chr(124)), %e = $+($left(%e,%t),$chr(124),$right(%e,$calc(%l - %t - $iif($chr(124) isin %c,1,0))))
      inc %t
    }
    if (($chr(124) !isin %c) && ($1 > %a)) var %e = $+(%c,$chr(124))
    if (!%e) var %e = $chr(124)
    hadd -m WConj Editbox %e
    if (!$timer(conjcli)) .timerconjcli -m 0 500 conj.cli
    conj.editbox force %e
    drawdot @Conjugaison
  }
  else {
    if ($hget(WConj,Selected)) hdel WConj Selected
    hadd -m WConj Editbox $remove($hget(WConj,Editbox),$chr(124))
    if ($hget(WConj,Editbox)) conj.editbox force $ifmatch
    if ($inrect($1,$2,177,25,30,15)) conj.send
    elseif ($inrect($1,$2,429,2,18,17)) {
      window -c @Conjugaison
      if ($window(@Conjugaison.copy)) window -c @Conjugaison.copy
      .timerconjcli off
      conj.freehash
      return
    }
    elseif ($inrect($1,$2,409,2,18,17)) window -n @Conjugaison
    ;Selectionner la conjugaison
    elseif ($inrect($1,$2,30,60,120,130)) {
      var %t = $calc($2 - 60), %n = 1, %l = Indicatif Subjonctif Conditionnel Impératif Temps¥impersonnels
      while %t > 15 { dec %t 15 | inc %n }
      if (%n isnum 1-5) {
        var %s = $gettok(%l,%n,32), %c = $hget(Conjugaison,%s)
        conj.list 30 60 120 130 $replace(%l,%s,$+(%s,!))
        conj.list 160 60 120 130 $+($gettok(%c,1,32),!) $gettok(%c,2-,32)
        conj.make.list %s $gettok(%c,1,32)
      }
    }
    elseif ($inrect($1,$2,160,60,120,130)) {
      var %t = $calc($2 - 60), %n = 1, %l = $hget(Conjugaison,$hget(Temp,Mode)), %m = $numtok(%l,32)
      while %t > 15 { dec %t 15 | inc %n }
      if (%n isnum $+(1-,%m)) {
        var %s = $gettok(%l,%n,32)
        conj.list 160 60 120 130 $replace(%l,%s,$+(%s,!))
        conj.make.list $hget(Temp,Mode) %s
      }
    }
    elseif ($getdot(@Conjugaison,$1,$2) == 7895160) conj.move $1-
    drawdot @Conjugaison
  }
}
alias -l conj.mouse {
  if ($inrect($1,$2,75,25,100,15)) {
    if (!$hget(Temp,ConjBorder)) { drawrect -r @Conjugaison 13801110 1 74 24 102 17 | hadd -m Temp ConjBorder 1 }
  }
  elseif ($hget(Temp,ConjBorder)) { hdel Temp ConjBorder | drawrect -r @Conjugaison 14999520 1 74 24 102 17 }
  if ($inrect($1,$2,177,25,30,15)) {
    if (!$hget(Temp,ConjOK)) { drawrect -r @Conjugaison 13801110 1 176 24 32 17 | hadd -m Temp ConjOK 1 }
  }
  elseif ($hget(Temp,ConjOK)) { hdel Temp ConjOK | drawrect -r @Conjugaison 14999520 1 176 24 32 17 }
  if ($inrect($1,$2,429,2,18,17)) {
    if (!$hget(Temp,ConjCroix)) { drawfill -rs @Conjugaison 5921370 16777215 438 10 | hadd -m Temp ConjCroix 1 }
  }
  elseif ($hget(Temp,ConjCroix)) { drawfill -rs @Conjugaison 16777215 5921370 438 10 | hdel Temp ConjCroix }
  if ($inrect($1,$2,409,2,18,17)) {
    if (!$hget(Temp,ConjReduire)) { drawfill -rs @Conjugaison 5921370 16777215 418 15 | hadd -m Temp ConjReduire 1 }
  }
  elseif ($hget(Temp,ConjReduire)) { drawfill -rs @Conjugaison 16777215 5921370 418 15 | hdel Temp ConjReduire }
}
alias -l w.conjugaison.draw {
  if (!$window(@Conjugaison)) return
  if ($hget(Conjugaison,Verbe)) {
    var %i = $ifmatch
    hadd -m WConj Editbox %i
    conj.editbox force %i
    drawtext -nr @Conjugaison 0 Tahoma 10 210 25 $+(",$replace(%i,$chr(165),$chr(32)),") $hget(Conjugaison,Existance)
    if ($hget(Conjugaison,Existance) == ne peut pas exister !) { drawdot @Conjugaison | return }
  }
  hadd -m Conjugaison Indicatif Présent Passé¥Composé Imparfait Plus-que-parfait Passé¥simple Passé¥antérieur Futur¥simple Futur¥antérieur
  hadd -m Conjugaison Subjonctif Présent Passé Imparfait Plus-que-parfait
  hadd -m Conjugaison Conditionnel Présent Passé¥1re¥forme Passé¥2e¥forme
  hadd -m Conjugaison Impératif Présent Passé
  hadd -m Conjugaison Temps¥impersonnels Participe¥présent Participe¥passé Infinitif¥présent Infinitif¥passé Gérondif¥présent Gérondif¥passé
  conj.make.list Indicatif Présent
  drawdot @Conjugaison
}
alias -l conj.make.list {
  if (!$2) return
  if (!$hget(Conjugaison,$1)) return
  if (!$window(@Conjugaison)) return
  hadd -m Temp Mode $1
  drawtext -nr @Conjugaison 13816530 Tahoma 10 34 44 Modes
  drawtext -nr @Conjugaison 11842740 Tahoma 10 38 48 Modes
  drawtext -nr @Conjugaison 0 Tahoma 10 36 46 Modes
  drawtext -nr @Conjugaison 13816530 Tahoma 10 164 44 Temps
  drawtext -nr @Conjugaison 11842740 Tahoma 10 168 48 Temps
  drawtext -nr @Conjugaison 0 Tahoma 10 166 46 Temps
  conj.list 30 60 120 130 $replace(Indicatif Subjonctif Conditionnel Impératif Temps¥impersonnels,$1,$+($1,!))
  conj.list 160 60 120 130 $replace($hget(Conjugaison,$1),$2,$+($2,!))
  conj.usage
  drawrect -fnr @Conjugaison 14999520 1 300 60 150 110
  w.conjugaison.write $hget(Temp,Mode) $2 300 60
}
alias -l conj.list {
  if (!$4) return
  drawrect -nr @Conjugaison 10790052 1 $1-4
  drawrect -fnr @Conjugaison 7237230 1 $calc($1 +1) $calc($2 +1) $calc($3 +1) $calc($4 +1)
  drawrect -fnr @Conjugaison 16777215 1 $calc($1 +1) $calc($2 +1) $calc($3 -1) $calc($4 -1)
  var %t = 5, %m = $0
  while %t <= %m {
    var %c = $gettok($1-,%t,32), %o = $calc(%t * 15 - 75 + $2)
    if ($right(%c,1) == !) drawrect -fnr @Conjugaison 11827320 1 $calc($1 +1) %o $calc($3 +1) 15
    drawtext -cnr @Conjugaison 0 Tahoma 10 $calc($1 +5) %o $calc($3 -10) 15 $remove($replace(%c,$chr(165),$chr(32)),!)
    inc %t
  }
}
alias -l w.conjugaison.write {
  if (!$window(@Conjugaison)) return
  var %g = $+($1,£,$2), %o = $calc($4 + 11), %te = $replace($2,$chr(165),$chr(32))
  var %t = 1, %posy = $4, %x = $calc($3 + 10)
  while %t <= 6 {
    inc %posy 15
    if ($hget(Conjugaison,$+(%g,£,%t))) drawtext -cnr @Conjugaison 0 Tahoma 10 %x %posy 150 20 $ifmatch
    inc %t
  }
}
alias -l conj.usage {
  if (!$window(@Conjugaison)) return
  var %c = $hget(Conjugaison,Usage£Règle£1)
  if (!%c) return
  var %t = 1, %max = $len(%c), %posy = 200
  while %t <= %max {
    var %p = $left(%c,%t)
    if ($width(%p,Tahoma,10) > 425) {
      if ($mid(%c,$calc(%t +1),1) != $chr(32)) var %p = $+(%p,-)
      drawtext -cnr @Conjugaison 0 Tahoma 10 10 %posy 680 20 %p
      var %c = $right(%c,$+(-,%t)), %t = 1, %max = $len(%c)
      inc %posy 10
    }
    inc %t
  }
  if (%c) drawtext -cnr @Conjugaison 0 Tahoma 10 10 %posy 680 20 %c
}
alias -l w.conjugaison.draw.recherche {
  var %t = 1, %m = $hget(ConjRecherche,0).item
  if ($hget(Conjugaison,Verbe)) {
    drawtext -cnr @Conjugaison 0 Tahoma 10 77 26 97 13 $ifmatch
    if (%m) drawtext -nr @Conjugaison 0 Tahoma 10 30 60 $+(",$hget(Conjugaison,Verbe),") se retrouve dans $iif(%m >= 2,les verbes suivants,le verbe suivant) :
    else drawtext -nr @Conjugaison 0 Tahoma 10 30 60 Voir $iif(%m >= 2,les verbes suivants,le verbe suivant) :
  }
  while %t <= %m { drawtext -onr @Conjugaison 0 Tahoma 10 40 $calc(65 + %t * 10) $hget(ConjRecherche,%t).item | inc %t }
  drawdot @Conjugaison
  hfree ConjRecherche
}
alias -l conj.cli {
  if (!$window(@Conjugaison)) { .timerconjcli off | return }
  hinc -m Temp cli
  var %e = $hget(WConj,Editbox), %t = $hget(Temp,cli)
  conj.editbox force $iif(%t == 1,$remove(%e,$chr(124)),%e)
  if (%t >= 2) hdel Temp cli
  drawdot @conjugaison
}
alias -l conj.freehash {
  if ($hget(Temp)) hfree Temp
  if ($hget(Conjugaison)) hfree Conjugaison
  if ($hget(WConj)) hfree WConj
}
;****
;Move
;****
alias -l conj.move {
  var %x = $mouse.dx, %y $mouse.dy
  if ($mouse.key & 1) {
    hadd -m Temp Move 1
    .timerconj.move -h 0 0 conj.move $1-
    window @Conjugaison $calc(%x - $1) $calc(%y - $2)
  }
  elseif ($hget(Temp,Move)) { hdel Temp Move | .timerconj.move off }
}
;End Of File

Conclusion :


Il est en niveau initié car il utilise des fonctions qui ne sont pas du niveau de débutant (regex, ...)
Pourtant le code en lui-même n'a pas été difficile à écrire, il a même été assez simple ^^

Ca vous rappellera très probablement vos années en école primaire :)
Pas de bugs connus (à part un décalage d'un pixel des caractères à droite du chariot quand celui-ci clignote)
Si le verbe n'existe pas, il forcera la conjugaison, mais l'accompagnera d'un petit message.
Si le verbe ne peut pas exister, il affichera uniquement une erreur.

Codes Sources

A voir également

Ajouter un commentaire Commentaires
Messages postés
840
Date d'inscription
vendredi 28 janvier 2005
Statut
Membre
Dernière intervention
25 février 2009
1
Enfin une source qui mérite son niveau initié (contrairement à d'autres...)
Bref avec toi c'est pas marrant à commenter parce que y'a rien à dire niveau code :-(
C'est propre, (très) rapide, et assez "cute" (bon la picwin a une drôle de forme :p)
D'ailleurs, tu as l'air de tellement aimer les pw que tu devrais faire un moteur de gui ;-)
Sinon, il aurait (peut être) été sympa de pouvoir copier/coller certains résultats, mais c'est sur que ça aurait demandé pas mal de travail en plus sachant qu'avec les pw, tout est à faire.
Essayes de faire des codes plus nazes la prochaine fois :(
Messages postés
1052
Date d'inscription
samedi 10 juillet 2004
Statut
Membre
Dernière intervention
30 novembre 2009
2
* respect *
Franchement bien vu, c'est propre, ca va super vite et tout et tout

Note a tous les utilisateurs du forum :
Servez vous un peu de ca avant de poster svp :$
Messages postés
2466
Date d'inscription
vendredi 23 juillet 2004
Statut
Membre
Dernière intervention
1 août 2010
1
(problème à ce niveau vu que le $width du chr 160 est différent)

ALORS LÀ ! je proteste fortement et il sait pourquoi :D
Messages postés
1287
Date d'inscription
mercredi 21 avril 2004
Statut
Membre
Dernière intervention
21 février 2009

c'étaiT :p
J'espère que maintenant vous comprenez pourquoi j'ai fait ce code xD

un verbe, ça prend vraiment pas beaucoup de lettres, si t'es flemmard à ce point :(


J'ai mis à jour, ERREUR 500, pour pas changer :p
On va bien voir si le changement a été pris en compte ou pas ^^
Messages postés
2466
Date d'inscription
vendredi 23 juillet 2004
Statut
Membre
Dernière intervention
1 août 2010
1
Ben si on veuT savoir ce qu'on recherche le plus souvent, enfin c'étais pour le rendre plus pratique !
ok pour les espaces
Afficher les 12 commentaires

Vous n'êtes pas encore membre ?

inscrivez-vous, c'est gratuit et ça prend moins d'une minute !

Les membres obtiennent plus de réponses que les utilisateurs anonymes.

Le fait d'être membre vous permet d'avoir un suivi détaillé de vos demandes et codes sources.

Le fait d'être membre vous permet d'avoir des options supplémentaires.