Mettre les nicks en couleur façon x-chat

Commenter

Contenu du snippet

Lorsqu'on a une mauvaise vue, les yeux fatigués, ou encore une résolution très faible sur un écran de petite taille, il peut être utile, plutôt que d'avoir à déchiffrer chaque nick d'une conversation, des les mettre en couleur. mIRC propose cette fonction, mais de façon manuelle. X-Chat le fait automatiquement, j'ai donc tenté de reproduire pour mIRC cette fonctionnalité pratique.

Source / Exemple : 


alias colorfromnick {
  ; #Liste des couleurs choisies.
  ; Mon fond est noir, donc j'évite tout ce qui est sombre.
  ; Je réserve également certaines couleurs pour des modes ou amis.
  var %clist = 6,8,10,11,12
  ; On stocke le nombre de couleurs
  var %nt = $numtok( %clist ,44)
  var %nick = $$1
  var %n = $len( %nick )
  var %a = 1
  var %t = 0
  ; Cette boucle calcule la somme des valeurs ASCII de chaque lettre du nick ciblé
  while ( %a <= %n ) {
    %t = $calc( %t + $asc($mid( %nick , %a , 1)))
    inc %a
  }
  ; On calcule le modulo du résultat par le nombre de couleurs.
  %t = $calc( %t % %nt )
  ; Et on retourne la valeur correspondante au modulo dans la liste des couleurs.
  return $gettok( %clist , %t ,44)
}

alias colorchan {
  ; Cet alias permet de déterminer la couleur pour chaque nick du chan, si la couleur n'est pas déja définie.
  var %chan = $$1
  var %n = $nick( %chan ,0)
  var %a = 1
  while ( %a <= %n ) {
    var %nick = $nick( %chan , %a )
    if ( $cnick( %nick ) == 0 ) .cnick %nick $colorfromnick( %nick )
    inc %a
  }
}

ON *:JOIN:#: {
  if ( $cnick($nick) == 0 ) .cnick $nick $colorfromnick($nick)
}

Conclusion :


Instructions :
- N'oubliez pas d'activer les couleurs. Alt + B => onglet Colors => Cochez la case Enabled.
- Dans l'alias colorfromnick, pensez à choisir les couleurs que vous désirez utiliser.
- Les nicks d'utilisateurs entrant sur un chant sont automatiquements colorés.
- Pour colorer les nicks d'un chan, tapez /colorchan <chan>.

Bugs :
- Aucun bug pour l'instant.

Améliorations :
- Ce code est loin d'être parfait et optimal pour une utilisation confortable, mais il a l'avantage d'être clair, et il vous suffira de quelques modifications pour l'adapter à vos envies.

A voir également

S'inscrire maintenant

Vous n'êtes pas encore membre ?

inscrivez-vous, c'est gratuit et ça prend moins d'une minute !

Les membres obtiennent plus de réponses que les utilisateurs anonymes.

Le fait d'être membre vous permet d'avoir un suivi détaillé de vos demandes et codes sources.

Le fait d'être membre vous permet d'avoir des options supplémentaires.

Du même auteur (Bob le Pointu)