Voici un petit snippet qui vous permettra d'afficher du texte dans une @window. Le texte défile dans un sens ou dans l'autre :)
Source / Exemple :
alias dbar {
if ($1 isnum 0-15 && $2 isnum && $3-) {
var %ù $calc($width($3-,tahoma,12) +25)
window -hbk0p +Ld @BDBar -1 -1 %ù 20
drawrect -f @BDBar $1 0 0 0 %ù 20
drawtext -pb @BDBar 1 $1 tahoma 12 2 2 $3-
window -abCdk0p +Led @DBar -1 -1 %ù 20
drawrect -f @DBar $1 0 0 0 %ù 20
set %dbar.ref $2
set %dbar.sens 37
dbar.refresh %ù %ù
}
else echo $color(info) * /dbar: invalid parameters
}
alias -l dbar.refresh {
if ($2 == $+(-,$1)) tokenize 32 $1 $1
elseif ($2 == $calc($1 *2)) tokenize 32 $1 $+(-,$1)
drawcopy @BDBar 0 0 $window(@BDBar).w $window(@BDBar).h @DBar $2 0
.timerdbar -m 1 $gettok(%dbar.ref,1,32) dbar.refresh $1 $calc($2 $iif(%dbar.sens == 37,-,+) 1)
}
on *:KEYDOWN:@DBar:37,39:{
%dbar.sens = $keyval
if (!$gettok(%dbar.ref,2,32)) %dbar.ref = $calc(%dbar.ref /2) 1
}
on *:KEYUP:@DBar:37,39:{ %dbar.ref = $calc($gettok(%dbar.ref,1,32) *2) }
menu @DBar {
Fermer:.timerdbar off | close -@ @DBar | close -@ @BDBar | unset %dbar.*
}
Conclusion :
Utilisation :
/dbar <background> <vitesse> <texte>
<background> est la couleur de fond de la barre.
<vitesse> est le délai en millisecondes au bout duquel la barre sera rafraichie.
<texte> est le texte a afficher dans la barre (supporte les codes couleurs mIRC)
En appuyant sur les touches directionnelles "Gauche" et "Droite", vous influerez sur le sens de défilement du texte.
En maintenant appuyées l'une des touches "Gauche" ou "Droite", vous accélèrerez la vitesse de défilement du texte jusqu'au relachement du bouton.
Vous n'êtes pas encore membre ?
inscrivez-vous, c'est gratuit et ça prend moins d'une minute !
Les membres obtiennent plus de réponses que les utilisateurs anonymes.
Le fait d'être membre vous permet d'avoir un suivi détaillé de vos demandes et codes sources.
Le fait d'être membre vous permet d'avoir des options supplémentaires.