Systeme pour récuperer informations allopass dialog/socket/hash table

Soyez le premier à donner votre avis sur cette source.

Snippet vu 21 013 fois - Téléchargée 26 fois

Commenter

Contenu du snippet

un petit addon pour savoir combien vous avez gagné d'argent sur allopass (ça évite de mettre 1h a chaque fois à s'identifier).
amusez vous bien ;)

Source / Exemple : 


menu menubar {
  -
  allopass:/dialog -m allopass allopass
}
dialog allopass {
  title "Allopass"
  size -1 -1 109 119
  option dbu
  link "Allopass v1.0 by win", 1, 28 110 49 8
  text "Login (e-mail):", 2, 5 9 36 8
  text "Mot de passe:", 3, 5 20 36 8
  edit "", 4, 43 8 61 10, autohs
  box "Configuration", 5, 2 1 105 56, disable
  edit "", 6, 43 19 61 10, autohs
  button "Sauvegarder", 7, 16 30 37 12
  button "Effacer", 8, 54 30 37 12
  box "Allopass", 9, 2 57 105 33, disable
  button "Identification", 10, 16 43 37 12
  button "Logout", 11, 54 43 37 12, disable
  text "Gains:", 12, 5 65 17 8
  text "", 13, 24 65 22 8, right
  text "?", 14, 48 65 4 8
  button "Mise à jour", 15, 70 62 34 12, disable
  text "Code:", 16, 5 75 17 8
  edit "", 17, 23 75 42 10, autohs limit 10 disable
  button "Vérifier", 18, 70 75 34 12, disable
  box "Status", 19, 2 91 105 18, disable
  text "Status:", 20, 4 98 19 8
  text "En attente...", 21, 25 98 79 8
}
on *:DIALOG:allopass:init:0:{ allopass_default | did -h $dname 16,17,18 }
on *:DIALOG:allopass:SClick:*:{
  if ($did = 7) {
    if ($did($dname,4)) writeini $dname $+ .win config login $encode($did($dname,4),m)
    if ($did($dname,6)) writeini $dname $+ .win config pass $encode($did($dname,6),m)
  }
  elseif ($did = 8) $dname $+ _default 1
  elseif ($did = 10) {
    if ($hget($dname)) hfree $dname
    hmake $dname
    hadd $dname i 0
    sockopen $dname $dname $+ .com 80
    did -b $dname 4,6,7,8,10
    did -ra $dname 21 Identification en cours...
  }
  elseif ($did = 11) {
    hfree $dname
    did -e $dname 4,6,7,8,10
    did -b $dname 11,15,17,18
    did -ra $dname 21 En attente...
  }
  elseif ($did = 15) {
    did -ra $dname 21 Mise à jour en cours...
    $dname $+ _stats
  }
  elseif ($did = 17) did -r $dname $did
  elseif ($did = 18) {
    if ($did($dname,17)) { did -ra $dname 21 Vérification en cours... | $dname $+ _code $ifmatch }
    else did -ra $dname 21 Veuillez entrer un code !
  }
}
alias allopass_default {
  if ((!$exists(allopass.win)) || ($1)) {
    writeini allopass.win config login dm90cmVAZW1haWw=
    writeini allopass.win config pass cGFzc3dvcmQ=
    writeini allopass.win allopass gains 0000.00
  }
  did -ra allopass 4 $decode($readini(allopass.win,config,login),m)
  did -ra allopass 6 $decode($readini(allopass.win,config,pass),m)
  did -ra allopass 13 $readini(allopass.win,allopass,gains)
}
alias allopass_stats {
  did -b allopass 15
  hadd allopass action stats
  sockopen allopass allopass.com 80
}
alias allopass_code {
  did -b allopass 17,18
  hadd allopass action code
  hadd allopass i 0
  hadd allopass code $1
  sockopen allopass allopass.com 80
}
on *:SOCKOPEN:allopass:{
  if ($sockerr > 0) { did -e $sockname 4,6,7,8,10 | did -b $sockname 15,17,18 | did -ra $sockname 21 Erreur d'ouverture du socket | halt }
  if (!$hget($sockname,cookie)) {
    sockwrite -n $sockname GET /login2.php4?EMAIL= $+ $did($sockname,4) $+ &PASSWORD= $+ $did($sockname,6) HTTP/1.1
    sockwrite -n $sockname Host: $sockname $+ .com
    sockwrite -n $sockname
  }
  else {
    if ($hget($sockname,action) == stats) {
      sockwrite -n allopass GET /webm_stats.php4 HTTP/1.1
      sockwrite -n allopass Host: $sockname $+ .com
      sockwrite -n allopass Cookie: $hget($sockname,cookie)
      sockwrite -n $sockname
    }
    elseif ($hget($sockname,action) == code) {
      sockwrite -n $sockname GET /webm_rechcode.php4?R_CODE= $+ $hget($sockname,code) HTTP/1.1
      sockwrite -n $sockname Host: $sockname $+ .com
      sockwrite -n $sockname Cookie: $hget($sockname,cookie)
      sockwrite -n $sockname
    }
  }
}
on *:SOCKREAD:allopass:{
  var %temp | sockread %temp
  if (!%temp) halt
  elseif (ERRMSG=&OKMSG= isin %temp) { did -ra $sockname 21 Vous avez bien été identifié! | did -e $sockname 11,15,17,18 | did -b $sockname 10 | sockclose $sockname | .timerallopass 1 2 allopass_stats }
  elseif (index.php4?ERRMSG= isin %temp) { did -ra $sockname 21 Erreur, login/pass incorrect(s) | did -e $sockname 4,6,7,8,10 | did -b $sockname 11,15,17,18 }
  elseif ($gettok(%temp,1,32) == Set-Cookie:) hadd $sockname cookie $gettok(%temp,2,32)
  if ($hget($sockname,action) == stats) {
    if (TOTAL DE VOTRE REVERSEMENT DISPONIBLE A CE JOUR isin %temp) hadd $sockname stats 1
    elseif ((*<span class="verdana_10_bleu_gras">* €&nbsp;</span>* iswm %temp) && ($hget($sockname,stats)) ) { did -e $sockname 15 | did -ra $sockname 13 $gettok($gettok(%temp,2,62),1,32) | did -ra $sockname 21 Mise à jour terminée! | hdel $sockname stats,action }
  }
  elseif ($hget($sockname,action) == code) {
    if ($hget($sockname,i) == 307) {
      if (est soit invalide, soit non-utilisé isin %temp) did -ra $sockname 21 Code $sockname invalide/déja utilisé
      else did -ra $sockname 21 Code $sockname pas utilisé (peut être invalide)
      did -e $sockname 17,18
      hdel $sockname action,code,i
    }
    hinc $sockname i
  }
}

Conclusion :


Mettez le dans vos remote et pour le lancer -> Menubar -> Allopass
J'ai juste testé sur moi donc normalement il marche (si allopass fait pas de mises a jour sur leur site lol)

J'attend vos critiques =]

A voir également

Ajouter un commentaire

Commentaires

Signaler
cs_ReMi34
Messages postés
1025
Date d'inscription
vendredi 29 août 2003
Statut
Membre
Dernière intervention
28 mars 2005
 -
Manque plus que la picwin ;)
Signaler
Xer0z
Messages postés
3
Date d'inscription
jeudi 13 mai 2004
Statut
Membre
Dernière intervention
18 janvier 2005
 -
Tres chouette addon remote enfain je c est pas sa commant on apelle tres utilie et tres pratique ! :) 9/10 aufait il exsiste un moyen de voire si le code est valide sens l utilisée ? Ôô
Signaler
winwarrior
Messages postés
654
Date d'inscription
jeudi 3 avril 2003
Statut
Membre
Dernière intervention
10 février 2009
 1 -
ReMi34 -> picwin pour quoi faire lol ?
Xer0z -> Pour vérifier si un code est bon tu vas sur le site d'allopass (tu t'identifie) et tu clik sur "recherche codes" :p
Signaler
cs_SornDrixer
Messages postés
2087
Date d'inscription
jeudi 12 décembre 2002
Statut
Modérateur
Dernière intervention
30 janvier 2011
 2 -
Utile et original, que demander de + ?
Signaler
Kerrigan
Messages postés
708
Date d'inscription
lundi 15 juillet 2002
Statut
Membre
Dernière intervention
17 mars 2005
 -
picwin parce que vu le dialogue c'est facile a faire et picwin parce que c'est très stylé :)
Afficher les 14 commentaires
S'inscrire maintenant

Vous n'êtes pas encore membre ?

inscrivez-vous, c'est gratuit et ça prend moins d'une minute !

Les membres obtiennent plus de réponses que les utilisateurs anonymes.

Le fait d'être membre vous permet d'avoir un suivi détaillé de vos demandes et codes sources.

Le fait d'être membre vous permet d'avoir des options supplémentaires.

Du même auteur (winwarrior)