Lecteur rss en asp simple, en un seul fichier

Soyez le premier à donner votre avis sur cette source.

Snippet vu 59 887 fois - Téléchargée 30 fois

Contenu du snippet

Ce lecteur RSS en ASP est encore plus simple que notre version en PHP disponible sur le site codes-sources.com

Si vous disposez d'un hébergement en Windows ASP (Active Server Pages vous pouvez récupérer facilement un fil d'information RSS par exemple d'un Blog et le publier directement sur votre site.

De ce fait, vous pouvez aussi bien utiliser le programme ci-dessous pour afficher n'importe quel RSS.

Voici un exemple d'importation de notre fil RSS sur un de nos site Web en ASP :

http://www34.brinkster.com/itcom3/asprssreader.asp?rssurl=http://ublog.com/itcom3/rss

Veillez à passer un argument rssurl avec l'adresse du fil que vous souhaitez afficher dans votre page ASP

A+,

Pierre

Source / Exemple :


<%  
 Option Explicit 
 Response.Buffer = true 
 Response.ExpiresAbsolute = Now () - 1
 Response.Expires = 0
%>

<%
'-----------------------------------------------------------------------------
' Name   : ASPRSSReader.asp
' Description  : very sample RSS Reader in ASP
' Company  : ITCom3
' Modify by : Pierre Rouarch
' Date : March, 27, 2004
'--------------------------------------------------------------------------------
%>

<%
' Variables
Dim myRSSURL, myRSSDocument,  myNews, mychannelNodes, entry, myChannelTitle, myChannelLink, myChannelDescription, myBase, myitemNodes, item, myitemTitle, myitemLink, myitempubDate, myitemDescription

' get RSS Address e.g : http://www.mysite.com/ASPRSSReader.asp?rssurl=http://www.rsssite.com/rssfile
myRSSURL=request("rssurl")
if Len(myRSSURL)=0 then
 ' Change with  your  default RSS URL
 myRSSURL = "http://www.u-blog.net/itcom3/rss"
end if

' Load RSS file
set myRSSDocument = createObject("Msxml.DOMDocument")
myRSSDocument.async = false
myRSSDocument.setProperty "ServerHTTPRequest", true
myRSSDocument.load(myRSSURL)

' Check if it 's loaded
If (myRSSDocument.parseError.errorCode <> 0) then
 ' Save error in myNews for displaying 
 myNews =  "XML error: " & myRSSDocument.parseError.reason
' Continue if OK
Else

 'Get elements <channel>
 set mychannelNodes = myRSSDocument.selectNodes("//channel/*")

 for each entry in mychannelNodes   ' Normaly one Channel
  if entry.tagName = "title" then
   myChannelTitle = entry.text
  elseif entry.tagName = "link" then
   myChannelLink = entry.text
  elseif entry.tagName = "description" then
   myChannelDescription = entry.text
   ' Save all in myBase for displaying 
   myBase =  myBase & "<h1>" & myChannelTitle & "</h1>"
   myBase =  myBase & "<p>" & myChannelDescription & "</p>"
   myBase =  myBase &  "<p><a href='" & myChannelLink & "'>" & myChannelTitle & "</a></p>" & "<hr>"
 end if
 next ' next <channel> element

 ' Get elements <item>
 set myitemNodes = myRSSDocument.selectNodes("//item/*")

 For each item in myitemNodes
  if item.tagName = "title" then
   myItemTitle =  item.text  
  elseif item.tagName = "link" then
   myItemLink =  item.text 
  elseif item.tagName = "pubDate" then
   myItempubDate =  item.text 
  elseif item.tagName = "description" then
   myItemDescription =  item.text 
   ' Save all in myNews for displaying 
   myNews = myNews &  myItempubDate & "<br>" 
   myNews = myNews & "<h2>" & myItemTitle & "</h2>" 
         myNews = myNews & "<p>" & myItemDescription & "</p>"
   myNews = myNews & "<p><a href='" & myItemLink & "'>" & myItemTitle & "</a></p>" & "<hr>"
  end if

 

 next ' Next <item> element

 ' Liberate Nodes
 set mychannelNodes = nothing
 set myitemNodes = nothing

End If ' if no error

%>

<html>
<head>
<title>Very Sample RSS Reader in ASP</title>
<meta http-equiv="Content-Type" content="text/html charset=iso-8859-1">
</head>
<body>

<%
Response.write myBase
Response.write myNews
%>

</body>
</html>

Conclusion :


Merci à Ublog.com pour l'hébergement de notre Blog
Merci à Brinkster.com pour nos hébergements en ASP

A voir également

Ajouter un commentaire

Commentaires

emcor11
Messages postés
6
Date d'inscription
samedi 8 mai 2004
Statut
Membre
Dernière intervention
9 avril 2010

Petit feedback car nous avons changé de proxy (et de port) et mon lecteur RSS ne fonctionnait plus. Si le port de sortie est différent du port 80, il faut rajouter votre port à la suite de l'adresse du proxy (chez moi ":8080" par exemple).
Voici une petite amélioration dans la ligne de configuration du proxy (cf Post du 01/06/2007 14:26:54) :
xmlServerHttp.setProxy 2, "adresse du proxy:port", ""

Par exemple pour http://www.monproxy.com, avec le port 8080, on aurait :
xmlServerHttp.setProxy 2, "http://www.monproxy.com:8080", ""
badseyar
Messages postés
11
Date d'inscription
mardi 14 mai 2002
Statut
Membre
Dernière intervention
17 septembre 2007

mon code est exactement le même que le tien, mais intégré dans une page lambda
je vais envoyer un MP à emcor11 en espérant qu'il m'apporte la lumière :-)
itcom3
Messages postés
39
Date d'inscription
jeudi 25 mars 2004
Statut
Membre
Dernière intervention
17 septembre 2007

Je ne sais que dire : le code 2147012889 est bien un pb de proxy qui ne peut être contourné,

Fait nous un copié/collé de ton code

Pierre
badseyar
Messages postés
11
Date d'inscription
mardi 14 mai 2002
Statut
Membre
Dernière intervention
17 septembre 2007

oui j'ai essayé, mais sans succès
itcom3
Messages postés
39
Date d'inscription
jeudi 25 mars 2004
Statut
Membre
Dernière intervention
17 septembre 2007

as-tu bien regardé l'explication de Microsoft :

http://support.microsoft.com/kb/315909/fr

et les astuces de Emcor11 ?

Vous n'êtes pas encore membre ?

inscrivez-vous, c'est gratuit et ça prend moins d'une minute !

Les membres obtiennent plus de réponses que les utilisateurs anonymes.

Le fait d'être membre vous permet d'avoir un suivi détaillé de vos demandes et codes sources.

Le fait d'être membre vous permet d'avoir des options supplémentaires.