Linksaved

Commenter

Contenu du snippet

; -------------
; LinkSaved v1.3 by arround
; -------------
; ce code permet de télécharger des images via votre mirc
; pas nimporte quelles images, celle des urls poster sur
; un de vos channels, elle seront télécharger réspectivement
; dans un dossier par default ( $mircdir\HMLP\Downloads\ )
; que vous pourrez vous même changer sur la ligne 56 du script
; possibilité de retourner certaines informations avec
; ajout de l'ident $linkinfo qui vous permet d'avoir des informations
; sur les urls contenant une image poster
; $linkinfo(...).[text|time|chan|server|nick]
; exemple: $linkinfo(http://www.mircscripts.org/screenshots/8197.png).time retournera 15h36m
; il faut imperativement que l'url ($1) sois dans la table link
; -------------

Source / Exemple : 


; A la reception d'un texte nous le traitons pour savoir si oui ou non il y a un lien avec une images
on *:text:*:#:{
  ; Si $_isli($1-,0) (is link) retourne quelque chose autre que 0 nous pouvons continuer
  if $_isli($1-,0) {
    ; Si la table ' Link ' n'est pas crée nous la créeons (ci dessous) et si le fichier %: existe nous le chargons directement dans la table Link
    if !$hget(link) { 
      hmake link
      var %: = $shortfn($mircdir), %: = $+(%:,HMLP\data.dat)
      $iif($exists(%:),hload link %:) 
    }
    ; Nous mettons les liens dans la table nick avec quelques informations sur le(s) lien(s) postés
    var %% = 1
    while $_isli($1-,%%) { 
      hadd link $_isli($1-,%%) $nick $+($asctime(HH),h,$asctime(nn),m) $chan $server $1-
      _dlpic $_isli($1-,%%) 
      inc %% 
    }
    _lsave 
  }
}
; Cette aliases sert a reperer les liens avec des images dans un text (Exp: jpg,png,gif)
; $_isli(test www.scriptsdb.org/test.PNG,0) retourne 1
; $_isli(test www.scriptsdb.org/test.PNG,1) retourne www.scriptsdb.org/test.PNG
; si vous voulez vous en servir pour une autre utilisation enlever le '-l' aprés alias
alias -l _isli { 
  var %. = www,%% = $matchtok($1-,%.,0,32),%- = 1,%* = $1-
  if %% > 0 && %* { 
    while $matchtok(%*,%.,%-,32) {
      var %: = $right($matchtok(%*,%.,%-,32),3)
      if %: == gif || %: == png || %: == jpg { var %§ = $addtok(%§,$matchtok(%*,%.,%-,32),32) }
      inc %-
    }
  }
  return $iif($2 == 0,$matchtok(%§,%.,0,32),$matchtok(%§,%.,$2,32))
}
; permet de sauvegarder la table 'link' dans un dossier qui si il n'existe pas sera crée
alias -l _lsave {
  var %% = $shortfn($mircdir), %% = $+(%%,HMLP\)
  $iif(!$exists(%%),mkdir %%)
  if $hget(link) { hsave $iif($exists($+(%%,data.dat)) == $true,-o) link $+(%%,data.dat) }
}
; aliases de téléchargement de l'image
alias -l _dlpic {
  var %% = $1
  $iif($hget(pic),hfree pic)
  hmake pic
  ; ajout dans la table pic de l'url base du site
  hadd pic url $matchtok(%%,www,1,47)
  ; ajout dans la table pic du fichier
  hadd pic fichier $gettok(%%,$gettok(%%,0,47),47)
  tokenize 46 $hget(pic,url)
  %% = $remove($_shttp(%%),$hget(pic,url)))
  ; ajout dans la table pic de l'host du site
  hadd pic host $replace($2-,$chr(32),$chr(46))
  ; ajout dans la table pic de la direction ou télécharger l'image sur le site $hget(pic,url)
  hadd pic get %% 
  ; connexion à la socket (si ouverte nous la fermons)
  $iif($sock(pic*,0),sockclose pic*) 
  sockopen pic $hget(pic,url) 80
}
on *:sockopen:pic:{
  ; identification + demande de la requette au site $hget(pic,url)
  if $sockerr { echo -a Connexion à la socket $sockname impossible | return }
  sockwrite -n $sockname GET $hget(pic,get) HTTP/1.1
  sockwrite -n $sockname Host: $+($hget(pic,host),$str($crlf,2))
  sockwrite -n $sockname
}
on *:sockread:pic:{ 
  sockread %temp 
  if !%temp { sockrename pic pic2 }
  if Content isin %temp && Length isin %temp { tokenize 32 %temp | hadd pic length $2- }
}
; téléchargement de l'image dans le dossier par default, envoie des informations de téléchargement vers la picwin
on *:sockread:pic2:{
  sockread &bin
  ; calcul en % le nombre de bytes reçus et le nombre de bytes à atteindre
  var %^ = $left($hget(pic,length),2),%° = $sock($sockname,1).rcvd, %_ $int($calc($calc($left(%°,2) / %^) * 100))
  $iif(%_ <= 100,_inpop $hget(pic,fichier) $hget(pic,url) %_)
  ; vous pouvez changer ici le $+(%%,HMLP\Downloads\) par une autre direction ( exemple: $+(%%,Blah\Images\) )
  var %% = $shortfn($mircdir),%% = $+(%%,HMLP\Downloads\)
  ; si la direction %% n'existe pas nous la créons
  $iif(!$exists(%%),mkdir %%)
  ; téléchargement du fichier $hget(pic,fichier) dans %%
  bwrite $+(%%,$hget(pic,fichier)) -1 -1 &bin
}
; si la fenetre @_pop est toujours ouverte lors de la fermeture de la socket nous la fermons
on *:sockclose:pic*:{ $iif($window(@_pop),window -c @_pop) }
; supprime http:// d'une url
alias -l _shttp { return $remove($1-,http://) }
; generation de la picwin avec les informations
alias -l _inpop {
  var %! =  @_pop, %s = $rgb(0,0,0), %? = $rgb(255,255,255)
  if !$window(%!) { window -abBCdop +b %! 100 100 200 100 }
  else clear %!
  drawrect -rf %! %? 1 0 0 200 100
  var %% = 0
  ; dégradé de la titlebar ( vous pouvez modifier la couleur en changant $rgb(%%,%%,255) exemple: $rgb(%%,0,%%) ) 
  while %% <= 255 { drawline -r %! $rgb(%%,%%,255) 1 %% 0 %% 15 | inc %% }
  drawtext -r %! %? tahoma 11 3 0 Telechargement: $+($left($hget(pic,url),8),$str($chr(46),3))
  drawline -r %! %s 1 0 14 200 14
  drawtext -r %! %s tahoma 11 7 20 Nom de l'image: $1
  drawtext -r %! %s tahoma 11 7 35 Url source: $2
  drawrect -r %! %s 1 8 55 181 20
  drawtext -r %! %s tahoma 11 7 79 Progression: $+($3,%)
  var %. = $3
  $iif(%. == 100,.timer! 1 1 window -c %!)
  %. = $calc($calc($3 *178)/ 100)
  var %% = 0
  while %% <= %. {
    drawline -r %! $rgb($calc(%% *1.3),$calc(%% *1.3),255) 1 $calc(%% +9) 56 $calc(%% +9) 74
    inc %%
  }
  drawline -r %! %s 1 $calc(%. +10) 56 $calc(%. +10) 74
}
; permet de récolté les infos d'un lien dans votre table ' link '
alias linkinfo {
  var %^ = $hmatch(link,$+(*,$1,*),1)
  if %^ {
    if !$prop { return %^ }
    var %* = nick,time,chan,server,text,%! = 1
    while %! <= 5 { if $prop == $gettok(%*,%!,44) { var %* = %! } | inc %! }
    tokenize 32 $hget(link,%^)
    return $eval($+($,%*),2)
  }
}
S'inscrire maintenant

Vous n'êtes pas encore membre ?

inscrivez-vous, c'est gratuit et ça prend moins d'une minute !

Les membres obtiennent plus de réponses que les utilisateurs anonymes.

Le fait d'être membre vous permet d'avoir un suivi détaillé de vos demandes et codes sources.

Le fait d'être membre vous permet d'avoir des options supplémentaires.

Du même auteur (arround)