c'est une petite astuce pour eviter de chercher pendant des heures une valeur rgb
le code est assez simple en plus il montre des scroll que je ne vois pas utilisés tres souvent.
Vous pourrez voir en gros comment ça marche parce que ça peut toujours servir un jour
Source / Exemple :
alias -l µ { if ( $did($1).text != $null) { return $ifmatch } | else { return 0 } }
alias rgb.editor {
window -hkp +b @Kerrigan 0 0 50 50
drawfill -r @Kerrigan $rgb(0,0,0) $rgb(0,0,0) 0 0
drawsave @Kerrigan @Kerrigan.bmp
dialog -m rgb.editor rgb.editor
}
alias -l process.rgb {
drawfill -r @Kerrigan $rgb($µ(1),$µ(2),$µ(3)) $rgb($µ(1),$µ(2),$µ(3)) 0 0
drawsave @Kerrigan @Kerrigan.bmp
did -g rgb.editor 4 $mircdir $+ @Kerrigan.bmp
did -ra rgb.editor 10 $ $+ rgb( $+ $µ(1) $+ , $+ $µ(2) $+ , $+ $µ(3) $+ )
did -ra rgb.editor 11 $str(0,$calc(8 -$len($rgb($µ(1),$µ(2),$µ(3))))) $+ $rgb($µ(1),$µ(2),$µ(3))
}
dialog rgb.editor {
title Editeur de valeurs rgb par Kerrigan
size -1 -1 280 95
edit "000" , 1, 180 5 30 20
edit "000" , 2, 180 25 30 20
edit "000" , 3,180 45 30 20
icon 4, 220 7 55 55, $mircdir $+ @Kerrigan.bmp,
scroll "", 5, 20 0 150 20,horizontal ,range 255
scroll "", 6, 20 20 150 20,horizontal ,range 255
scroll "", 7, 20 40 150 20,horizontal ,range 255
edit "rgb(0,0,0)" ,10, 10 70 100 20,center
edit "00000000" ,11, 190 70 78 20,center
text "R" ,12, 5 7 10 15
text "G" ,13, 5 26 10 15
text "B" ,14, 5 46 10 15
text "Interprété :" ,15, 135 72 55 15,
}
on 1:dialog:rgb.editor:edit:*: {
if ( $did = 10 ) || ( $did = 11 ) { goto end }
did -c rgb.editor $calc($did +4) $did($did).text
process.rgb
:end
}
on 1:dialog:rgb.editor:scroll:*: {
did -ra rgb.editor $calc($did -4) $str(0,$calc(3 -$len($did($did).sel))) $+ $did($did).sel
process.rgb
}
on 1:dialog:rgb.editor:close:0: { if ( $window(@kerrigan) ) { window -c @kerrigan } }
Conclusion :
copier le code dans les remotes et ensuite tapez /rgb.editor dans le status
c'est.
C'est n'est pas un code nouveau ni inovant , le truc c'est que je ne l'ai vu qu'avec mdx.dll et la il fonctionne sans dll donc chez tout le monde.
ça flash un peu a cause du did -g et je ne vois pas trop comment faire autrement
dans une version future il y aura de la conversion rgb/hexa et vous pourrez mettre directement la valeur rgb obtenu dans le buffer copier/coller (avec les "objet com" on fait des miracles)
Vous n'êtes pas encore membre ?
inscrivez-vous, c'est gratuit et ça prend moins d'une minute !
Les membres obtiennent plus de réponses que les utilisateurs anonymes.
Le fait d'être membre vous permet d'avoir un suivi détaillé de vos demandes et codes sources.
Le fait d'être membre vous permet d'avoir des options supplémentaires.