"encapsuler" un exe dans une form vbRésolu

Question

Bonjour à tous et toutes,

voilà ma question, toujours sans réponse après de multiples recherches :
est'il possible dans une feuille vb, à travers un controle bien précis par exemple, d'insérer/encapsuler un exécutable ?
c'est à dire de faire en sorte qu'il s'éxécute dans un cadre de la feuille et non en tant qu'application tierce à l'application vb.

si quelqu'un d'entre vous à une idée, tenez moi au courant
et merci d'avance pour toutes vos réponses.

cs_niky · Accepted Answer

Parmi les API Windows, tu devrait en trouver une qui s'appelle SetParent (ou un truc du genre) : elle permet de donner à une fenêtre le handle de ta fenêtre comme parent (et donc elle s'exécute à l'intérieur).

jmfmarques · Answer

Bonjour,

J'ai peut-être mal compris ta question...
S'il ne s'agit que de faire exécuter une application tierce dans la tienne : tu peux insérer un objet OLE, tout simplement, et elle tournera dans ton appli si la machine cliente possède également ce logiciel tiers. 
S'il s'agit par contre d'englober dans ton application un exécutable tiers sans que la machine cliente ne possède le dit exécutable, ce n'est pas possible, bien évidemment (et quid, de toutes manières, du Copyright ?)

cs_thephil · Answer

niky --> ok je vais regarder pour l'api
jmfmarques --> oui tu as très bien compris, (c'est dans le but de regrouper deux applis dans un même 'utilitaires'), 
dans ce cas quel est l'ocx/dll à ajouter dans les composants pour avoir un tel controle ?, n'ayant jamais fais de choses similaires ...

encore merci

jmfmarques · Answer

Regrouper dans un même utilitaire : oui, certainement...
Mais à condition que l'utilitaire "inséré" soit présent sur la  machine cliente (et sans que tu ne le distribues... car ce serait illégal).
Est-ce celà que tu veux : réponse oui ou réponse non .
Une autre fois : si réponse non : pas de solution
Si réponse oui : deux solutions (objet OLE et une autre).
Tu dis ... et je te donne la solution simple (si, une autre fois, le logiciel appelé est bien déjà présent sur la machine cliente... hein ...)

cs_thephil · Answer

bon c'est pas parceque j'ai une tête de clown que j'en suis un, enfin pas complètement ! 
donc ok je détaille, même si ça ne me semblait pas nécéssaire (mais je conçois que ma question pouvait etre ambigue ou pas très bien posée) :
On a ici au boulot un programme tout fait qui nous permet de gérer notre parc informatique, donc installé sur tous les micros des gens du service.
dans ce programme, manquaient quelques fonctionnalités pratiques que nous avons développées en vb.

Aujourdhui, pour plus de convivialité, d'ergonomie ..., on voudrait simplement "regrouper visuellement" les applis pour n'avoir plus qu'une appli pour gérer notre parc.

voilà  ... j'ai cédé au chantage  ... de m'expliquer pour avoir la réponse, j'espère que ma cause vous fera parler M. Jmfmarques

donc encore merci !

jmfmarques · Answer

Parler ?
Oui !
Mais tu auras bien deux applis (et pas une seule), bien que la deuxième s'exécutrera dans la première ...

Voilà commentr (exemple, donc) :

ACHTUNG !
Prends connaissance des commentaires mis en rouge dans ce qui suit (Muy importante !!!)

'ATTENTION :'
'' La ligne de code suivante :'
'TerminateProcess GetCurrentProcess, 0 ' on met ici fin à l'application appelante)>>
'met fin à l'application appelante.'
'Il convient donc bien évidemment de compiler la présente application puis de lancer 'son exécutable.
'Il est sinon bien clair que serait fermé VB.Exe (car c'est bien VB.exe qui est
'l'application en cours, au "design Time ' 
Il convient bien évidemment, par ailleurs, de remplacer la ligne :
' Shell("d:\monoutil\modeles\utut\util.exe", vbNormalFocus))
'en y mettant le chamin complet de l'application de ton choix,
'pour faire ton test !


Private Declare Function GetCurrentDirectory Lib "kernel32" Alias "GetCurrentDirectoryA" (ByVal nBufferLength As Long, ByVal lpBuffer As String) As Long


Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As Long, ByVal lpWindowName As Long) As Long
Private Declare Function GetParent Lib "user32" (ByVal hwnd As Long) As Long
Private Declare Function SetParent Lib "user32" (ByVal hWndChild As Long, ByVal hWndNewParent As Long) As Long
Private Declare Function GetWindowThreadProcessId Lib "user32" (ByVal hwnd As Long, lpdwProcessId As Long) As Long
Private Declare Function GetWindow Lib "user32" (ByVal hwnd As Long, ByVal wCmd As Long) As Long
Private Declare Function LockWindowUpdate Lib "user32" (ByVal hwndLock As Long) As Long
Private Declare Function GetDesktopWindow Lib "user32" () As Long
Private Declare Function DestroyWindow Lib "user32" (ByVal hwnd As Long) As Long
Private Declare Function TerminateProcess Lib "kernel32" (ByVal hProcess As Long, ByVal uExitCode As Long) As Long
Private Declare Function GetCurrentProcess Lib "kernel32" () As Long
Private Declare Function Putfocus Lib "user32" Alias "SetFocus" (ByVal hwnd As Long) As Long


Const GW_HWNDNEXT = 2


Dim mWnd As Long


Private Sub Form_Activate()
Dim sSave As String
    sSave = String(255, 0) ' création d'un buffer
    GetCurrentDirectory 255, sSave ' extraction du répertoire en cours
    MsgBox "le répertoire en cours est : " & sSave


    Dim Pid As Long
    LockWindowUpdate GetDesktopWindow ' verrouillage de la fenêtre principale
    'Execution de l'exécutable Windows de votre choix
    'Pid = Shell("c:\winnt
otepad.exe", vbNormalFocus)
    Pid = Shell("d:\monoutil\modeles\utut\util.exe", vbNormalFocus)
    If Pid = 0 Then MsgBox "Erreur / démarrage de l'application"
    mWnd = InstanceToWnd(Pid) ' extraction du handle de la fenêtre
    SetParent mWnd, Me.hwnd ' définition du parent de l'application à ouvrir
    Putfocus mWnd ' on donne maintenant le focus à l'application ouverte
    LockWindowUpdate False ' déverrouillage de la fenêtre principale
End Sub


Function InstanceToWnd(ByVal target_pid As Long) As Long
    Dim test_hwnd As Long, test_pid As Long, test_thread_id As Long
    test_hwnd = FindWindow(ByVal 0&, ByVal 0&) ' recherche de la premère fenêtre
    Do While test_hwnd <> 0
        If GetParent(test_hwnd) = 0 Then ' on vérifie que la fenêtre n'est pas une fenêtre fille
            'on recherche le fil (thread) de la fenêtre
            test_thread_id = GetWindowThreadProcessId(test_hwnd, test_pid)
            If test_pid = target_pid Then
                InstanceToWnd = test_hwnd
                Exit Do
            End If
        End If
        test_hwnd = GetWindow(test_hwnd, GW_HWNDNEXT) ' on extrait le handle de la fenêtre suivante
    Loop
End Function
 
Private Sub Form_Unload(Cancel As Integer)
    DestroyWindow mWnd ' déchargement de la fenêtre de l'application ouverte
    TerminateProcess GetCurrentProcess, 0 ' on met ici fin à l'application appelante
End Sub

Voilà donc !
Lis tout bien et applique en connaissance de cause .
Une précision : tu restes responsable et seul responsable de tout geste inconsidéré, dans cette affaire. (alors lis bien)...

cs_thephil · Answer

Je viens d'essayer, c'est parfait, c'est exactement ce dont j'avais besoin
donc merci beaucoup Jmfmarques

-->> MP

xpert12 · Answer

Comment positionner le programme encapsulé par exemple avec top=0 et left=0

lafume · Answer

Salut,

4 ans plus tard, il y a toujours des gens qui bossent en vb6, mais oui !

Et mon soucis est que le code mentionné plus haut ne fonctionne pas en W7. Quelqu'un aurait-il une solution ?

Merci.

"encapsuler" un exe dans une form vb

9 réponses

Votre réponse

Discussions similaires