Upload

Signaler
Messages postés
20
Date d'inscription
lundi 17 février 2003
Statut
Membre
Dernière intervention
19 mars 2004
-
Messages postés
224
Date d'inscription
vendredi 14 septembre 2001
Statut
Membre
Dernière intervention
14 juillet 2006
-
Voila, j'utilise un script qui vient d'ici pour uploader des fichiers, et j'aimerai savoir si il est possible de limiter l'upload aux images seulement et aussi si on peut les renomer au passage.
Comme je ne trouve plus la page ou j'ai pris le script, je vous le mets ici. Merci d'avance :
' --------------------------------------------------------------
' UPLOAD de n'importe quel type de fichier sans composant
' Nicolas Chu
' http://www.nc-technologies.com
' --------------------------------------------------------------

Dim Contenu, TailleContenu, ContenuAscii, X, Y, Z, Position

' ---------------------------
Contenu = Request.BinaryRead(Request.TotalBytes)
TailleContenu = Request.TotalBytes

' Grâce à la méthode BinaryRead on lit la totalité du post en mode binaire que l'on place dans une variable Contenu
' La propriété TotalBytes nous Indique le nombre total des octets envoyés par le client dans le corps du message de requête.

' -------------------
ToutOk = 0
' ToutOk est une Variable Test (si tout est Ok, elle prend la valeur 1 sinon elle reste à 0

' -------------------
PosDebutFic=0
' PosDebutFic représente la position de l'octet où se trouve le début du Nom du fichier transmis

' -------------------
PosFinFic=0
' PosFinFic représente la position de l'octet où se trouve la fin du Nom du fichier transmis

' -------------------
PosDebutCont=0
' PosDebutCont représente la position de l'octet où se trouve le début du Content-Type du fichier

' -------------------
PosFinCont=0
' PosFinCont représente la position de l'octet où se trouve la fin du Content-Type du fichier

' -------------------
PosDebutFic2=0
' PosDebutFic2 représente la position de l'octet où se trouve le début du Contenu du fichier

' -------------------
PosFinFic2=0
' PosFinFic2 représente la position de l'octet où se trouve la fin du Contenu du fichier

X = 0
Y = 1
Position = 1

' -------------
' En premier lieu, on recherche la position du terme filename="
' Pour ce faire, on calcul le nombre d'octet (LimitBin) du premier élément jusqu'à filename=" (on effectue une boucle jusqu'au nombre d'octets correspondant au terme filename=")

LimitASCII = "filename=" & chr(34)
LimitBin=""
for Z = 1 to Len(LimitASCII)
LimitBin = LimitBin & chrB(ASC(Mid(LimitASCII, Z, 1)))
next

' -------------------
' On recherche la position de l'octet de la chaîne Contenu jusqu'à LimitBin
' On utilise la fonction InStrB qui est disponible pour être utilisée avec les données de type octet contenues dans une chaîne. Au lieu de renvoyer la position du caractère de la première occurrence d'une chaîne à l'intérieur d'une autre (fonction Instrv), la fonction InStrB renvoie la position de l'octet.

PosDebutFic = InstrB(1, Contenu, LimitBin)

' -------------------
' On lui ajoute ensuite la longueur du terme filename=" ce qui nous permet d'avoir la position de début du nom du fichier (PosDebutFic)

if PosDebutFic <> 0 then
PosDebutFic = PosDebutFic + LenB(LimitBin)
end if

' -------------------
' En premier lieu, on recherche la position du terme Content-Type: d'une façon similaire à notre recherche pour le terme filename="

LimitASCII = "Content-Type:"
LimitBin=""
For Z = 1 to Len(LimitASCII)
LimitBin = LimitBin & chrB(ASC(Mid(LimitASCII, Z, 1)))
next
PosDebutCont = InstrB(1, Contenu, LimitBin)

if PosDebutCont <> 0 then

' -------------------
' On trouve la position de la fin du nom du fichier (PosFinFic) à partir de la position du début du terme Content-Type: à laquelle on retire trois octets (un espace, une " et la première lettre du terme)

PosFinFic = PosDebutCont - 3

' -------------------
' On ajoute à PosDebutCont la longueur du terme Content-Type: , ce qui nous permet d'avoir la position de début du Content-Type (PosDebutCont)

PosDebutCont = PosDebutCont + LenB(LimitBin)
end if

' -------------------
' On en déduit le nombre de caractères composant le nom du fichier en effectuant une soustraction

NomFichier = MidB(Contenu, PosDebutFic , (PosFinFic - PosDebutFic))

' -------------------
' Nous n'avons plus qu'à traduire en texte grâce à la fonction ASCB et trouver ainsi le nom du fichier (NomFichier)

ContenuAscii = ""
for Z = 1 to LenB(NomFichier)
ContenuAscii = ContenuAscii & chr(ASCB(MidB(NomFichier, Z, 1)))
next
NomFichier = ContenuAscii
If NomFichier <> "" Then

' -------------------
' On cherche la position de début du contenu du fichier en sautant les blancs

PosFinCont = InstrB(PosDebutCont, Contenu, chrB(13))
if PosFinCont <> 0 then
PosDebutFic2 = PosFinCont + 4
end if

' -------------------
' On recherche la position de fin du contenu du fichier

LimitASCII = "----"
LimitBin=""
for Z = 1 to Len(LimitASCII)
LimitBin = LimitBin & chrB(ASC(Mid(LimitASCII, Z, 1)))
next

PosFinFic2 = InstrB(PosDebutFic2, Contenu, LimitBin)

' -------------------
' Si la position de fin du contenu du fichier n'est pas 0 alors tout est OK

if PosFinFic2 <> 0 then
ToutOk = 1
end if

' -------------------
' On place le contenu binaire du fichier transmis dans la variable DataFichier

DataFichier = MidB(Contenu, PosDebutFic2 , (PosFinFic2 - PosDebutFic2))

' -------------------
' Si tout est ok, on écrit dans un fichier à la racine du serveur en plaçant d'abord dans une variable NouveauFic le chemin complet du fichier à écrire.

If ToutOk = 1 then
Position = InstrRev(NomFichier, "")
NomFichierCourt = right(NomFichier, (Len(NomFichier) - Position))
NouveauFic = Server.MapPath("\imguser") & "" & NomFichierCourt
Set FileObject = Server.CreateObject("Scripting.FileSystemObject")
Set Out=FileObject.CreateTextFile(NouveauFic, True)
For I = 1 to LenB(DataFichier)
Out.Write chr(AscB(MidB(DataFichier,I,1)))
Next
Out.close
Set Out=nothing
end if

1 réponse

Messages postés
224
Date d'inscription
vendredi 14 septembre 2001
Statut
Membre
Dernière intervention
14 juillet 2006

Voici une fonction qui te permet de checker l'extension. Pour le nom du fichier, regarde tout en bas du code, tu as
NomFichierCourt = right(NomFichier, (Len(NomFichier) - Position))
C'est probablement sur ce NomFichierCourt qu'il faut jouer.

function verif_ext()
{
fichier=document.upl.Fichier1.value;
if(fichier!="")
{
longueur= fichier.length;
where = fichier.lastIndexOf(".");
extension=fichier.slice(where,longueur);
if(extension!=".jpg") //&& extension!=".gif" && extension!=".png")
{
alert("le fichier sélectionné n'est pas un fichier image compatible !!!");
document.upl.Fichier1.select();
document.upl.Fichier1.value="";
return false;
}
else
{
document.upl.extension.value=extension;
return true;
}
}
else
return true;
}