CommonDialog et répertoireRésolu

Question

Bonjour,

Ets-il possible de s&#233;lectionner un r&#233;pertoire avec le controle CommonDialog . Pour s&#233;lectionner un fichier pas de probl&#232;me mais pour indiquer un r&#233;pertoire de destination par exemple comment faire ?

Merci

crenaud76 · Accepted Answer

Il te faut utiliser l'API SHBrowseForFolder()
Voici un bout de code issu de l'API-Guide ...

Private Type BrowseInfo
    hWndOwner As Long
    pIDLRoot As Long
    pszDisplayName As Long
    lpszTitle As Long
    ulFlags As Long
    lpfnCallback As Long
    lParam As Long
    iImage As Long
End Type
Const BIF_RETURNONLYFSDIRS = 1
Const MAX_PATH = 260
Private Declare Sub CoTaskMemFree Lib "ole32.dll" (ByVal hMem As Long)
Private Declare Function lstrcat Lib "kernel32" Alias "lstrcatA" (ByVal lpString1 As String, ByVal lpString2 As String) As Long
Private Declare Function SHBrowseForFolder Lib "shell32" (lpbi As BrowseInfo) As Long
Private Declare Function SHGetPathFromIDList Lib "shell32" (ByVal pidList As Long, ByVal lpBuffer As String) As Long
Private Sub Form_Load()
    'KPD-Team 1998
    'URL: http://www.allapi.net/
    'KPDTeam@Allapi.net
    Dim iNull As Integer, lpIDList As Long, lResult As Long
    Dim sPath As String, udtBI As BrowseInfo

    With udtBI
        'Set the owner window
        .hWndOwner = Me.hWnd
        'lstrcat appends the two strings and returns the memory address
        .lpszTitle = lstrcat("C:", "")
        'Return only if the user selected a directory
        .ulFlags = BIF_RETURNONLYFSDIRS
    End With

    'Show the 'Browse for folder' dialog
    lpIDList = SHBrowseForFolder(udtBI)
    If lpIDList Then
        sPath = String$(MAX_PATH, 0)
        'Get the path from the IDList
        SHGetPathFromIDList lpIDList, sPath
        'free the block of memory
        CoTaskMemFree lpIDList
        iNull = InStr(sPath, vbNullChar)
        If iNull Then
            sPath = Left$(sPath, iNull - 1)
        End If
    End If

    MsgBox sPath
End Sub


Christophe

cuq · Answer

Tr&#232;s bien mais peut on fixer le r&#233;pertoire de d&#233;part un peu comme avec le .InitDir = AppPath du controle ? common dialogue

Merci.

crenaud76 · Answer

Pour cela, il faut faire du subclassing ... Je dois avoir cela dans mes archives ... je recherche et je te poste cela.

Christophe

cuq · Answer

Ok Merci