comment afficher le resultat d un Vbscript sur une page Web !!!!Résolu

Question

Salut a tous en fait j ai mon script qui me permet d afficher l espace des mes disques ainsi que l espace libre et le pourcentage d espace libre!! donc d&#233;ja c est une bonne chose de faite ce que je sais pas faire c est afficher le tout sur page web!!! regardez le code ci dessous c est celui la que je veux afficher sur une page web mais je vois pas comment faire encore: alors est ce que quelqu un de caler en VBscript Wmi peu m aider si vous plait!!!!



Select Case WScript.Arguments.Count
    Case 0
        ' Default if none specified is local computer (".")
        Set objWMIService = GetObject( "winmgmts://./root/cimv2" )
        Set colItems = objWMIService.ExecQuery( "Select * from Win32_ComputerSystem", , 48 )
        For Each objItem in colItems
            strComputer = objItem.Name
        Next
    Case 1
        ' Command line parameter can either be a computer name
        ' or "/?" to request online help
        strComputer = Wscript.Arguments(0)
        if InStr( strComputer, "?" ) > 0 Then Syntax
    Case Else
        ' Maximum is 1 command line parameter
        Syntax
End Select


Display( strComputer )
WScript.Quit(0)



Function Display( strComputer )
    strMsg = vbCrLf & "Name:" & vbTab & "Drive:" & vbTab & "Size:" & _
             vbTab & "Free:" & vbTab & "% Free:" & vbCrLf & "=====" & _
             vbTab & "======" & vbTab & "=====" & vbTab & "=====" & _
             vbTab & "=======" & vbCrLf
    On Error Resume Next
    Set objWMIService = GetObject( "winmgmts://" & strComputer & "/root/cimv2" )
    If Err.Number Then
        WScript.Echo vbCrLf & "Error # " & CStr( Err.Number ) & _
                     " " & Err.Description
        Err.Clear
        Syntax
    End If
    On Error GoTo 0
    ' Set colItems = objWMIService.ExecQuery("Select * from Win32_LogicalDisk where MediaType=12",,48)
    Set colItems = objWMIService.ExecQuery("Select * from Win32_LogicalDisk where DriveType=3",,48)
    For Each objItem in colItems
        strMsg = strMsg & strComputer & vbTab & _
                 objItem.Name & vbTab & _
                 CStr( Int( 0.5 + ( objItem.Size / 1073741824 ) ) ) & _
                 vbTab & _
                 CStr( Int( 0.5 + ( objItem.FreeSpace / 1073741824 ) ) ) & _
                 vbTab & _
                 CStr( Int( 0.5 + ( 100 * objItem.FreeSpace / objItem.Size) ) ) & _
                 vbCrLf
    Next
    WScript.Echo strMsg
End Function

CTAC · Accepted Answer

Bonjour.

Il faudra ajuster la mise en page qui est diff&#233;rente dans une page web d'une msgbox.

Remplacer la ligne WScript.Echo strMsg par :

dim IE
set ie = createobject("Internetexplorer.application")
ie.navigate("about:blank")
do while ie.document.readystate<>"complete"
wscript.sleep 100
loop
ie.document.body.innertext = strmsg
ie.visible = true
set ie = nothing

ctac

mohax007 · Answer

merci CTAC d avoir pris le temps de repondre ca focntionne il me reste a poffiner tous ca

Comment afficher le resultat d un Vbscript sur une page Web !!!!

2 réponses

Discussions similaires