Screen.TwipsPerPixelX équivalent en VBARésolu

Question

J'aimerais savoir si il y a un &#233;quivalent &#224; "Screen.TwipsPerPixelX" dans VBA (Access)


Merci


Antoine

Neo.balastik · Accepted Answer

Salut ;O)

Non !  Aucune &#233;quivalence.
Mais voici 2 fonctions (&#224; mettre dans un module) qui te feront certainement plaisir :
fTwipsToPixels
fPixelsToTwips

'API DECLARATION
Public Declare Function apiGetDC Lib "user32" Alias "GetDC" (ByVal hWnd As Long) As Long
Public Declare Function apiGetDeviceCaps Lib "gdi32" Alias "GetDeviceCaps" (ByVal hDC As Long, ByVal nIndex As Long) As Long

'CONSTANT DECLARATION
Public Const DIRECTION_VERTICAL = 1
Public Const DIRECTION_HORIZONTAL = 0
Private Const LOGPIXELSX = 88
Private Const LOGPIXELSY = 90

Function fTwipsToPixels(lngTwips As Long, lngDirection As Long) As Long
'   Function to convert Twips to pixels for the current screen resolution
'   Accepts:
'       lngTwips - the number of twips to be converted
'       lngDirection - direction (x or y - use either DIRECTION_VERTICAL or DIRECTION_HORIZONTAL)
'   Returns:
'       the number of pixels corresponding to the given twips
    On Error GoTo E_Handle
    Dim lngDeviceHandle As Long
    Dim lngPixelsPerInch As Long
    lngDeviceHandle = apiGetDC(0)
    If lngDirection = DIRECTION_HORIZONTAL Then
        lngPixelsPerInch = apiGetDeviceCaps(lngDeviceHandle, LOGPIXELSX)
    Else
        lngPixelsPerInch = apiGetDeviceCaps(lngDeviceHandle, LOGPIXELSY)
    End If
    lngDeviceHandle = apiReleaseDC(0, lngDeviceHandle)
    fTwipsToPixels = lngTwips / 1440 * lngPixelsPerInch
fExit:
    On Error Resume Next
    Exit Function
E_Handle:
    MsgBox Err.Description, vbOKOnly + vbCritical, "Error: " & Err.Number
    Resume fExit
End Function

Function fPixelsToTwips(lngPixels As Long, lngDirection As Long) As Long
    On Error GoTo E_Handle
    
    Dim lngDeviceHandle As Long
    Dim lngPixelsPerInch As Long
    lngDeviceHandle = apiGetDC(0)
    If lngDirection = DIRECTION_HORIZONTAL Then
        lngPixelsPerInch = apiGetDeviceCaps(lngDeviceHandle, LOGPIXELSX)
    Else
    lngPixelsPerInch = apiGetDeviceCaps(lngDeviceHandle, LOGPIXELSY)
    End If
    lngDeviceHandle = apiReleaseDC(0, lngDeviceHandle)
    fPixelsToTwips = lngPixels * 1440 / lngPixelsPerInch
fExit:
    On Error Resume Next
    Exit Function
E_Handle:
    MsgBox Err.Description, vbOKOnly + vbCritical, "Error: " & Err.Number
    Resume fExit
End Function

Guy

Neo.balastik · Answer

Oups !  Il manque une d&#233;claration API :

Public Declare Function apiReleaseDC Lib "user32" Alias "ReleaseDC" (ByVal hWnd As Long, ByVal hDC As Long) As Long

Guy

antoineraymond · Answer

Merci

Antoine

Neo.balastik · Answer

En fait, &#224; relire ta question, ces fonctions n'y r&#233;pondent pas directement.  Elles ne donnent pas une &#233;quivalence &#224; TwipsPerPixelX, mais j'ai suppos&#233; que tu cherchais &#224; convertir tes Twips en pixels et vice-versa...

Guy

Gobillot · Answer

aucune id&#233;e si &#231;a marche en VBa (?)



  MsgBox ScaleX(1, vbPixels, vbTwips)



 ou 



  MsgBox ScaleY(1, vbPixels, vbTwips)




Daniel

Neo.balastik · Answer

Daniel > voil&#224; ce qui fait la diff&#233;rence entre VB et VBA.  Bcp de fonctions de ce genre sont inexistantes et donc, passer par API est la seule alternative.
ScaleX et ScaleY sont inconnus au bataillon de VBA...

Guy

Screen.TwipsPerPixelX équivalent en VBA

6 réponses

Discussions similaires