Comment insérer un bitmap dans un richtextbox

Question

ZTPdiffusion · Answer

Salut 

Pour répondre à ta question il te faut 2 form

Form1 avec un RichTextBox (RichTextBox1) et un bouton (Command1)

Code à mettre dans la Form1 :

Private Sub Command1_Click()
    Form2.Show 1, Me
End Sub

'******************************************

Form2 avec 2 boutons (command1 et command2), un controle Picture (Picture1), un TextBox (Text1)  et un Common Dialog (CommonDialog1)

Code à placer dans la Form2 :

Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hWnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
Const WM_PASTE = &H302
Private Sub Command1_Click()
  On Error GoTo Error
      
  With CommonDialog1
    .DialogTitle = "Insérer une image"
    .Filter = "Tous les fichiers(*.*)|*.*|Fichiers BMP(*.bmp)|*.bmp|Fichiers JPEG(*.jpg;*.jpeg)|*.jpg;*.jpeg|Fichiers GIF(*.gif)|*.gif|Fichiers TIF(*.tif)|*.tif"
    .FilterIndex = 3
    .ShowOpen
  End With
  If CommonDialog1.FileName <> "" Then
    Picture1.Picture = LoadPicture()
    Picture1.Picture = LoadPicture(CommonDialog1.FileName)
    Text1.Text = CommonDialog1.FileName
  Else
    Text1.SetFocus
  End If
Error:
End Sub

Private Sub Command2_Click()
  Clipboard.Clear
  Clipboard.SetData Picture1.Picture
  SendMessage Form1.RichTextBox1.hWnd, WM_PASTE, 0, 0
  Unload Me
End Sub

'*****************************************

J'espère que ça répond à ta question

a+

Comment insérer un bitmap dans un richtextbox

1 réponse

Discussions similaires