connecter un lecteur réseau

Question

Je réalise un programme qui récupère des données sur une bande DAT, et les place sur un des disques de mon snap server ( c'est un serveur de stockage ). En fait, je demande à l'utilisateur de me donner le disque où il veut stocker ( il y en a 4 ). Une fois qu'il m'a renseigné, je veux pouvoir connecter ce disque afin qu'il n'apparraisse plus que comme un lecteur normal de mon PC.
Alors, il y a l'assistant sous Windows qui le fait dans Poste de travail, le menu Outils-Connecter un lecteur réseau.
Seulement, je voudrais pouvoir le faire grâce à vb automatiquement.
Quelqu'un pourrait m'aider, svp?
Merci d'avance
Pensez-vous que c'est possible?

cs_Crazyht · Answer

Declare Function WNetConnectionDialog Lib "mpr.dll" (ByVal hwnd As Long, ByVal dwType As Long) As Long

Declare Function WNetDisconnectDialog Lib "mpr.dll" (ByVal hwnd As Long, ByVal dwType As Long) As Long

Regarde les deux fonctions API Suivantes.

A++
Hervé

cs_Crazyht · Answer

Voilà un exemple pris dans API Guide :


'Create a form with:
' • Two commands (Command1, Command2)
' • One Drive (Drive1)
' • One label (Label1)
Const RESOURCETYPE_DISK = &H1
Private Type NETRESOURCE
  dwScope As Long
  dwType As Long
  dwDisplayType As Long
  dwUsage As Long
  lpLocalName As String
  lpRemoteName As String
  lpComment As String
  lpProvider As String
End Type
Private Declare Function WNetAddConnection2 Lib "mpr.dll" Alias "WNetAddConnection2A" (lpNetResource As NETRESOURCE, ByVal lpPassword As String, ByVal lpUserName As String, ByVal dwFlags As Long) As Long
Private Declare Function WNetCancelConnection2 Lib "mpr.dll" Alias "WNetCancelConnection2A" (ByVal lpName As String, ByVal dwFlags As Long, ByVal fForce As Long) As Long
Dim theNetResource As NETRESOURCE
Dim UserName As String
Dim UserPassword As String
 Private Sub Form_Load()
  'example created by Tim Derdelinckx (tderdelinckx@allgeier.be)
  'visit his site at http://www.allgeier.be
  theNetResource.lpRemoteName = "\SERVER\ShareName"
  theNetResource.lpLocalName = "Z:"
  UserName = "Username"
  UserPassword = "Password"
  theNetResource.dwType = RESOURCETYPE_DISK
  Label1.Caption = ""
  Command1.Caption = "Add Connection"
  Command2.Caption = "Cancel Connection"
End Sub
Private Sub Command1_Click()
  Dim Result&
    Result = WNetAddConnection2(theNetResource, UserPassword, UserName, 0)
    If Result = 0 Then
      Label1.Caption = "Connection Established."
      Drive1.Drive = theNetResource.lpLocalName
      Drive1.Refresh
    Else
      Label1.Caption = "Connection not possible."
      MsgBox "Connection not possible." & vbCrLf & "(Maybe the drive is allready used or the share doesn't exist)"
    End If
End Sub
Private Sub Command2_Click()
  Dim Result&
    Result = WNetCancelConnection2(theNetResource.lpLocalName, 0, 0)
    If Result = 0 Then
      Label1.Caption = "Connection Closed."
    Else
      Label1.Caption = "Close connection not possible."
    End If
    Drive1.Refresh
End Sub

Cervomix · Answer

Merci beaucoup c'est ce dont je cherchais!

Connecter un lecteur réseau

3 réponses

Discussions similaires