liste déroulante dans la cellule d'une DBGrid

Question

voila je voudrais avoir une liste déroulante dans mon DBGrid 
j'ai mis la propriété "bouton" du DBGrid a true et donc j'ai une petite flèche comme pour choisir dans une liste déroulante, dans la cellule du DBGrid 
mais le pb c'est que j'arrive pas a ajouter des éléments dans la liste  
es-ce qui ya moyen d'en ajouter ou faut que je trouve une nouvelle solution. 

merci

gaa179 · Answer

Salut,

Tu fais apparaître un bouton et non une liste déroulante lorsque tu set la propriété button. 
Il y a un évènement button_click qui généré quand tu click sur ce bouton. Il te suffit de placer une liste déroulante sur ton form, proriété visible = False. Lorsque que tu click sur ton bouton (Event), tu fais apparaître ta liste dans la cellue du DBGrid. Il ne te reste plus qu'e récupérer la valeur sélectionné sur l'évèment OnClick de ta liste déroulante et de faire le traitement adéquat (Affichage dans la celluel, enregistrement dans un BD) esuite tu fais disparaitre ta liste déroulante quand tu pers le focus.

A+

Dom44103764 · Answer

Bonjour, je viens d'&#234;tre confront&#233; au m&#234;me probl&#232;me et comme j'ai trouv&#233; une solution je vous en fais part.
&#231;a vient de http://www.mvps.org/vexpert/articles/vb_dbgrid2.htm
et j'ai pu impl&#233;menter l'exemple avec succ&#232;s.
Dans ta form, en plus du dbgrid1, tu cr&#233;es une listbox List1.

Option Explicit
' le num&#233;ro de la colonne qui contient le bouton
Const ColIndex_List1 = 6

Private Sub Form_Load()
' Remplir list1 (exemple)
     With List1
       .AddItem "ATTENTE"
       .AddItem "RESILIE"
       .AddItem "CONTACTE"
    End With
'active le bouton de la colonne ColIndex_List1
  DBGrid1.Columns(ColIndex_List1).Button = True
End Sub
'-----------------------------------------
' a partir de l&#224; j'ai pas trop capt&#233; mais &#231;a marche garanti (voir manuel vb)
'-----------------------------------------
Private Sub DBGrid1_ButtonClick(ByVal ColIndex As Integer)
  Dim C As Column
  If ColIndex = ColIndex_List1 Then
  Set C = DBGrid1.Columns(ColIndex)
  With List1
    .Left = DBGrid1.Left + C.Left
    .Top = DBGrid1.Top + DBGrid1.RowTop(DBGrid1.Row) + DBGrid1.RowHeight
     .Width = C.Width + 15
     .ListIndex = 0
     .Visible = True
     .ZOrder 0
     .SetFocus
    End With
    End If
End Sub

Private Sub DBGrid1_BeforeColEdit(ByVal ColIndex As Integer, ByVal KeyAscii As Integer, Cancel As Integer)
    If ColIndex = ColIndex_List1 Then
       Cancel = True
       DBGrid1_ButtonClick (ColIndex)
    End If
End Sub

Private Sub DBGrid1_Scroll(Cancel As Integer)
    List1.Visible = False
End Sub

Private Sub List1_KeyPress(KeyAscii As Integer)
    Select Case KeyAscii
        Case vbKeyReturn
             DBGrid1.Columns(ColIndex_List1).Text = List1.Text
             List1.Visible = False
        Case vbKeyEscape
             List1.Visible = False
    End Select
End Sub

Private Sub List1_LostFocus()
    List1.Visible = False
End Sub

Private Sub List1_DblClick()
    List1_KeyPress vbKeyReturn
End Sub

Vol&#224;, c'&#233;tait simple et juste un site latinos que je b&#233;nis pour me donner la r&#233;ponse.

&#224; +

Liste déroulante dans la cellule d'une DBGrid

2 réponses

Discussions similaires