ToolTip - Des fois ça marche, des fois...Résolu

Question

Salut à tous,

Voila, dans mon appli (dévellopée sous VB2010 avec le FW3.5), j'affiche un ToolTip sur des sections d'un diagramme de Gantt (Panel)pour informer l&#8217;utilisateur de sa nature.


     Public Sub Panel_Pnt_MouseEnter(ByVal sender As Object, ByVal e As System.EventArgs)
        Try
            Dim cible As Panel = DirectCast(sender, Panel)
            Dim ToolTip = New System.Windows.Forms.ToolTip
            Dim ID As String = cible.Tag

            ToolTip.IsBalloon = True
            ToolTip.ToolTipTitle = "Info:"
            ToolTip.UseAnimation = True
            ToolTip.InitialDelay = 0
            ToolTip.UseFading = True
            ToolTip.SetToolTip(cible, "ID: " & cible.Tag & ChrW(13) & "Titre: " & ReadTittle(cible.Tag))
        Catch ex As Exception
            WriteLog("Error Panel_Pnt_MouseEnter: Function - " & System.Reflection.MethodBase.GetCurrentMethod().Name & " - " & Date.Now & " - " & ex.Message)
        End Try
    End Sub


Le soucis, est que cela fonctionne très bien sur ma machine qui est en Seven, mais pas sur les machines clients encore pour quelques mois sous XP Pro!

Zauriez-vous une idée?

Merci! ;)

Jimy

Pensez: Réponse acceptée
'**********************************************

jimy neutron · Accepted Answer

J'ai trouvé, sous XP, la propriété
 
ToolTip.IsBalloon = True


ne fonctionne pas, je l'ai passé à false et ça marche!

Merci de ton aide Banana! ;)


Jimy

Pensez: Réponse acceptée
'**********************************************

jimy neutron · Answer

Je viens de regarder les plateformes admissibles:
Tapez le texte de l'url ici.

[quoteWindows Vista, Windows XP SP2, Windows XP Media Center Edition, Windows XP Professionnel Édition x64, Windows XP Starter Edition, Windows Server 2003, Windows Server 2000 SP4, Windows Millennium Edition, Windows 98
/quote

Je sius en XP Pro SP3, ca ne devrait pas poser de soucis?!

Jimy

Pensez: Réponse acceptée
'**********************************************

jimy neutron · Answer

Pour info, j'ai teste l'évènement MouseEnter, il fonctionne correctement.


Jimy

Pensez: Réponse acceptée
'**********************************************

Utilisateur anonyme · Answer

Bonjour,

Une petite question : La clause Handles n'est pas présente ? Je suppose que tu abonnes ton panel à cet événement ailleurs dans le code (AddHandler) ?

jimy neutron · Answer

Je n'ai pas la possibilité de te donner le code de création du contrôle dans l'heure, mais comme je l'ai dit plus haute, l'évènement "MouveEnnter" fonctionne bien, le code s&#8217;exécute correctement, seul le ToolTip ne s'affiche pas!

Jimy

Pensez: Réponse acceptée
'**********************************************

Utilisateur anonyme · Answer

C'est peut être parce que que ton tooltip est mal déclaré :
Dim ToolTip = New System.Windows.Forms.ToolTip
au lieu de :
Dim ToolTip as System.Windows.Forms.ToolTip = New System.Windows.Forms.ToolTip

jimy neutron · Answer

Salut Banana,
En effet, ça aurait pu être ça, et cela ne mange pas de pain de bien déclarer ses contrôles, mais cela ne change rien malheureusement!

C'est étrange, j'ai place des WriteLog partout dans le code pour m'assurer de son exécution, et tout va bien, mais il ne s'affiche pas! 


Jimy

Pensez: Réponse acceptée
'**********************************************

jimy neutron · Answer

Banana, pour répondre à ta première question:



Dim Panel_Pnt as Panel
...
...
...
Panel_Pnt = New Panel()
                    With Panel_Pnt
                        .Name = "Panel_Pnt" & ID.ToString
                        .Width = myrecordset.Item("Duree") + 1
                        .Height = 25
                        .Location = New Point(LocateX, -3)
                        .BackColor = Color.White
                        .BorderStyle = BorderStyle.FixedSingle
                        .Tag = ID
                        .Cursor = Cursors.Hand
                        .BackgroundImageLayout = ImageLayout.Stretch

                    End With


                    'ajout d'un gestionnaire d'événement click
                    AddHandler Panel_Pnt.Click, AddressOf Panel_Pnt_Click
                    'ajout d'un gestionnaire d'événement MouseEnter
                    AddHandler Panel_Pnt.MouseEnter, AddressOf Panel_Pnt_MouseEnter
                    'ajout d'un gestionnaire d'événement MouseLeave
                    AddHandler Panel_Pnt.MouseLeave, AddressOf Panel_Pnt_MouseLeave

                    'ajout du controle au formulaire
                    Outils.FLP_WO_WPnt.Controls.Add(Panel_Pnt)



Jimy

Pensez: Réponse acceptée
'**********************************************

foliv57 · Answer

Bonjour à tous les deux,

Juste un petit rappel. Il n'est pas judicieux de créer une nouvelle instance de l'objet ToolTip à chaque passage de la souris sur l'objet.

Il est préférable de déclarer l'objet de façon unique pour la Form et uniquement de faire un SetToolTip au survol.

Exemple :
Public Class Form1

    Private _toolTip As System.Windows.Forms.ToolTip

    Public Sub New()
        InitializeComponent()
        InitToolTip()
    End Sub

    Private Sub InitToolTip()
        _toolTip = New System.Windows.Forms.ToolTip()
        _toolTip.IsBalloon = True
        _toolTip.ToolTipTitle = "Info:"
        _toolTip.UseAnimation = True
        _toolTip.InitialDelay = 0
        _toolTip.UseFading = True
    End Sub

    Public Sub Panel_Pnt_MouseEnter(ByVal sender As Object, ByVal e As System.EventArgs) 
        Try
            Dim cible As Panel = DirectCast(sender, Panel)
            Dim ID As String = cible.Tag
            _toolTip.SetToolTip(cible, "ID: " & cible.Tag & ChrW(13) & "Titre: " & ReadTittle(cible.Tag))

        Catch ex As Exception
            WriteLog("Error Panel_Pnt_MouseEnter: Function - " & System.Reflection.MethodBase.GetCurrentMethod().Name & " - " & Date.Now & " - " & ex.Message)
        End Try
    End Sub

End Class

Nota : Exemple testé sous XP SP3 avec "IsBalloon = True" et cela fonctionne de mon coté. Donc le problème pourrait venir d'un paramètre du projet genre "Activer les styles visuels XP" décoché.

Bonne journée à vous.

Utilisateur anonyme · Answer

Bonjour foliv57,

Il doit pouvoir le faire aussi au moment de l'instanciation de son panel sans avoir besoin de le déclarer dans l'entête de la classe.

jimy neutron · Answer

Merci Foliv pour cet exemple très enrichissant. Cependant, cette expression ne passe pas!


    Public Sub New()
        InitializeComponent()
        InitToolTip()
    End Sub


 " Un 'Sub New' partagé ne peut pas être déclaré 'Public'"

Et j'ai bien peur pour le coup de ne pas être assez calé pour la comprendre.
Jimy

Pensez: Réponse acceptée
'**********************************************

foliv57 · Answer

Pouvoir, oui bien entendu.

Mais en terme de ressource, cella provoque une création d'objet ToolTip pour chaque élément panel survolé dans la Form alors que la classe ToolTip est justement prévue pour gérer les messages ToolTip de plusieurs éléments (Voir documentation). Normalement le cycle de vie de ce type d'objet est le même que celui de la Form.

Concrètement, si par exemple la Form est composée de 10 panels et qu'on survol ces 10 panels à la suite. Avec la l&#8217;instanciation de ToolTip sur chaque MouseEnter on va créer 10 objets ToolTip alors qu'une seule instance d'un objet ToolTip peut gérer les messages de tous les éléments d'une Form (donc des 10 panels).

En allant même plus loin dans mon exemple de tout à l'heure. La logique d'un objet ToolTip devrait être 1) d'être créé et initialisé lors de l'initialisation de la Form 2) d'être mis à jour lorsqu'un message doit être modifié (pas forcément à chaque survol) 3) de mourir avec la Form.

Exemple avec deux panels qui affiche leur propriété "Tag" comme message ToolTip :
Public Class Form1

    Private _toolTip As System.Windows.Forms.ToolTip

    Public Sub New()

        'Initialisation des composant de la form
        InitializeComponent()

        'Initialisation du gestionaire de ToolTip
        InitToolTip()

    End Sub

    'Initialisation du gestionaire de ToolTip
    Private Sub InitToolTip()
        _toolTip = New System.Windows.Forms.ToolTip()
        _toolTip.IsBalloon = True
        _toolTip.ToolTipTitle = "Info:"
        _toolTip.UseAnimation = True
        _toolTip.InitialDelay = 0
        _toolTip.UseFading = True
    End Sub

    'Mise à jour du tag d'un panel
    Private Sub UpdatePanelTag(ByVal panel As Panel, ByVal newTag As String)
        panel.Tag = newTag
        _toolTip.SetToolTip(panel, newTag)
    End Sub

    'Chargement du formulaire
    Private Sub Form1_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load

        'Initialisation des ToolTip
        UpdatePanelTag(Me.Panel1, "Mon tool tip panel 1 initial")
        UpdatePanelTag(Me.Panel2, "Mon tool tip panel 2 initial")

    End Sub

    'Evenement quelconque sencé mettre à jour un panel ou créer un panel ou autre...
    Public Sub FaitQuelqueChose()
        UpdatePanelTag(Me.Panel1, "Mon nouveau tool tip panel 1")
    End Sub

End Class

De cette façon on ne crée qu'un Objet ToolTip et on le met à jour uniquement quand c'est nécessaire. Celui-ci s'occupe du reste.

J'avoue que le fond de cette histoire est que je suis un malade de la mémoire vive :) Je me méfie toujours des classes qui implémentent la méthode "Dispose()". C'est souvent signe qu'il ne faut pas en créer à tour de bras.

Donc ma remarque était surtout un conseil. Les deux méthodes fonctionnent.

Normalement le problème de base (problème sous XP) ne devrait pas être lié à ma remarque, qui du coup est hors sujet sorry.

Pour approfondir il faudrait savoir comment le formulaire et les panels sont créés et si les propriétés de bases du projet ont été modifiés car pour ma part, les deux méthodes fonctionnent sous XP.

foliv57 · Answer

Merci Foliv pour cet exemple très enrichissant. Cependant, cette expression ne passe pas! 
Code Visual Basic :

    Public Sub New()
        InitializeComponent()
        InitToolTip()
    End Sub


" Un 'Sub New' partagé ne peut pas être déclaré 'Public'" 

Intéressant... Vous l'avez bien places au niveau de la classe "FLP_WO_WPnt" ?
Car d'après les post précédent vous devriez avoir ceci
Class FLP_WO_WPnt
End Class

jimy neutron · Answer

Je crois comprendre le soucis:

Ce que me propose Foliv doit être déclaré dans la class Form. 
Mais uniquement ceci (D'ailleurs, pourriez-vous m'en expliquer l'utilité?)

    Public Sub New()
        InitializeComponent()
        InitToolTip()
    End Sub    


Et le reste avec mes évenements 'MouseEnter', dans un module avec le code de création des controles. Et là ça marche sous seven et toujours pas sous XP, sauf avec "IsBalloon = False"...Et mon paramètre "Activer les styles visuels XP"  est bien coché!

Jimy

Pensez: Réponse acceptée
'**********************************************

jimy neutron · Answer

Nos messages se sont croisés, merci Foliv pour ces conseils avisés, mais le mystère reste en ce qui concerne XP...


Jimy

Pensez: Réponse acceptée
'**********************************************

foliv57 · Answer

Public Sub New()
Est la méthode lancée lors de la création de l'instance du formulaire.
Grossièrement cette méthode est appelée avant l'évènement "Load".
C'est dans cette méthode (appelée constructeur) que l'on va créer tous les éléments du formulaire.
La première instruction est obligatoirement InitializeComponent() (pour un formulaire).
On peut facilement aller jeter un coup d'oeil à cette méthode en faisant un "clic droit->Atteindre la définition" dessus. On y retrouvera la création, le positionnent et l'initialisation de chaque contrôles placés à l'aide de l'interface de visual studio. C'est parfois intéressant d'analyser la façon dont ils sont créés.

Après cette instruction vous pouvez y ajouter tout code qui vous permettrait de créer des éléments non ajoutés à l'aide de l'interface ou ne pouvant pas l'être.

foliv57 · Answer

mais le mystère reste en ce qui concerne XP... 

Oui malheureusement. Je n'arrive pas à le reproduire pour le moment

Utilisateur anonyme · Answer

la classe ToolTip est justement prévue pour gérer les messages ToolTip de plusieurs éléments (Voir documentation)
Merci foliv57 

@jimy neutron
Attention à ne pas abuser du ToolTip qui peut vite agacer un utilisateur. Prévoir une désactivation dans les options de ton appli.

jimy neutron · Answer

Merci pour cette remarque Banana. J'en prends bonne note! ;)

Jimy

Pensez: Réponse acceptée
'**********************************************

foliv57 · Answer

Jimy, pourriez vous me donner des informations sur l'action effectuée sur "MouseLeave" ?

Ca pourrait être une piste car on peut remarquer que lorsque le tooltip est affiché, si la sourie est au dessus, ça provoque un MouseLeave.

Et on peut remarquer qu'avec "IsBalloon = False" le curseur de la sourie n'est pas tout de suite au dessus du tooltip dès son affichage.

jimy neutron · Answer

En effet, avec "IsBalloon = True", ce phénoméne provoquait l'affichage d'autant de ToolTip que de pixels que parcourait la sousris sur le control. J'ai donc rusé comme ceci:


 Public Sub Panel_Pnt_MouseEnter(ByVal sender As Object, ByVal e As System.EventArgs)
        Try
            If Not ToolTipDisplay Then
                Dim cible As Panel = DirectCast(sender, Panel)
                Dim ID As String = cible.Tag

                _ToolTip.SetToolTip(cible, "ID: " & cible.Tag & ChrW(13) & "Titre: " & ReadTittle(cible.Tag))
                ToolTipDisplay = True
            End If
        Catch ex As Exception
            WriteLog("Error Panel_Pnt_MouseEnter: Function - " & System.Reflection.MethodBase.GetCurrentMethod().Name & " - " & Date.Now & " - " & ex.Message)
        End Try
    End Sub

    Public Sub Panel_Pnt_MouseLeave(ByVal sender As Object, ByVal e As System.EventArgs)
        ToolTipDisplay = False
    End Sub





Jimy

Pensez: Réponse acceptée
'**********************************************

jimy neutron · Answer

C'est aussi la raison pour laquelle je n'ai pas utilisé 'ToolTip.Show(...)', car l'affichage était catastrophique!

Jimy

Pensez: Réponse acceptée
'**********************************************

foliv57 · Answer

L'objet ToolTip gère automatiquement son affichage et sa disparition au survol du contrôle. Il est en aucun cas nécessaire de faire un "Show" ou un "Hide". Il sait tout seul quand il doit être affiché ou masqué.

Il est clair que si un Hide est fait sur MouseLeave, en mode "IsBalloon = True" le message disparaît juste après avoir était affiché.

Je vous conseil quand même de faire le "SetToolTip" uniquement lorsque le Tag du panel change.

S'il n'est pas amené à changer après sa création, en reprenant votre code précédent de création du panel, vous pourriez envisager de faire ceci :
Dim Panel_Pnt as Panel
Panel_Pnt = New Panel()
With Panel_Pnt
    .Name = "Panel_Pnt" & ID.ToString
    .Width = myrecordset.Item("Duree") + 1
    .Height = 25
    .Location = New Point(LocateX, -3)
    .BackColor = Color.White
    .BorderStyle = BorderStyle.FixedSingle
    .Tag = ID
    .Cursor = Cursors.Hand
    .BackgroundImageLayout = ImageLayout.Stretch

End With


  'ajout d'un gestionnaire d'événement click
  AddHandler Panel_Pnt.Click, AddressOf Panel_Pnt_Click
           
  'ajout du controle au formulaire
  Outils.FLP_WO_WPnt.Controls.Add(Panel_Pnt)
  
  'ajout du ToolTip
  _ToolTip.SetToolTip(Panel_Pnt, "ID: " & Panel_Pnt.Tag & ChrW(13) & "Titre: " & ReadTittle(Panel_Pnt.Tag) 
Du coup, plus besoin du "MouseEnter/Leave"

jimy neutron · Answer

Merci pour cet exemple, mais il s'agit d'un diagramme de gantt constitué de plusieurs dizaines de panels, d'où l&#8217;utilisation du 'MouseEnter' au choix de l'utilisateur.




Jimy

Pensez: Réponse acceptée
'**********************************************

jimy neutron · Answer

Hooo! autant pour moi, je n'avais pas compris votre dernier message.
En effet, c'est bien plus pratique. Je le teste dés que possible et reviens vers vous pour dire si cela à réglé le problème.

MERCI! :)

Jimy

Pensez: Réponse acceptée
'**********************************************

foliv57 · Answer

Je comprends bien.

Mais le titre des panels est-il amené à changer une fois que le panel est ajouté au formulaire ?

La logique voudrait que le SetToolTip des panels soit fait lorsque le panel est créé (valeur initiale) et si l'utilisateur modifie le titre ou l'ID.

Le titre et l'ID ne change pas à chaque fois que l'utilisateur survol le panel avec la souris.

L'utilisateur peut-il modifier le titre ou l'ID (donc le tag des panels) ? 

L'objet ToolTip n'a pas besoin de connaitre le message à afficher à chaque survol. Il suffit de lui paramétrer une seul fois ou de le modifier uniquement si celui ci change.

foliv57 · Answer

Hooo! autant pour moi, je n'avais pas compris votre dernier message. 

Désolé pour le chevauchement de mon dernier message. Ne pas en tenir compte du coup

jimy neutron · Answer

Bien, j'ai testé votre proposition, en effet les ToolTip se gère tout seuls, mais cela ne fonctionne toujours que sous Seven, pas d'affichage sous XP avec un 'IsBallon=True'  


Jimy

Pensez: Réponse acceptée
'**********************************************

foliv57 · Answer

mais cela ne fonctionne toujours que sous Seven, pas d'affichage sous XP avec un 'IsBallon=True'

Il résiste, mais pas pour longtemps...

Pourriez vous essayer ceci :
Public Sub Panel_Pnt_MouseEnter(ByVal sender As Object, ByVal e As System.EventArgs)
   _ToolTip.Active = False
   _ToolTip.Active = True
End Sub

Pensez à rattacher l&#8217;évènement "MouseEnter" à la création des panel.

foliv57 · Answer

Sinon ma dernière cartouche sera de faire un petit tour du coté du registre du pc sous XP.

Dans la clé :
[HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced]

il est possible d'ajouter (ou il existe) une valeur DWORD "EnableBalloonTips"
1 = BalloonTips autorisés
0 = BalloonTips bloqués

jimy neutron · Answer

Je comprends bien. 

Mais le titre des panels est-il amené à changer une fois que le panel est ajouté au formulaire ? 

La logique voudrait que le SetToolTip des panels soit fait lorsque le panel est créé (valeur initiale) et si l'utilisateur modifie le titre ou l'ID. 

Le titre et l'ID ne change pas à chaque fois que l'utilisateur survol le panel avec la souris. 

L'utilisateur peut-il modifier le titre ou l'ID (donc le tag des panels) ? 

L'objet ToolTip n'a pas besoin de connaitre le message à afficher à chaque survol. Il suffit de lui paramétrer une seul fois ou de le modifier uniquement si celui ci change.

Non, chaque panel créé correspond à un enregistrement d'une base SQL, su coup, l'ID est celui de l'enregistrement, et le titre le début du contenu d'un de ces items.

L'utilisateur qu'en a lui ne fait que les consulter.

Pour le registre, je ne pourrais voir cela que Lundi maintenant. 

Encore merci! ;)

Jimy

Pensez: Réponse acceptée
'**********************************************

Utilisateur anonyme · Answer

je ne pourrais voir cela que Lundi maintenantLundi étant largement dépassé, je reviens sur ce fil car j'ai eu une idée.
Il est peut-être possible de se servir de Environment.OSVersion pour paramétrer ton 'tooltip'. Voir une discussion msdn ici.

ToolTip - Des fois ça marche, des fois...

32 réponses

Votre réponse

Discussions similaires