[Catégorie modifiée VB6 - VBA] Commentaire de cellule excel Résolu

Question

Bonjour à tous

Je suis sur Excel et j'essaie d'insérer des commentaires en gras sur une cellule.
Pour le moment, j'ai réussi un insérer un commentaire mais pas à le mettre en gras.
Voilà mon code :
Cells(10, 11).AddComment.Text "Affaire : " & TxtNumAff & vbCrLf & vbCrLf & " Commentaire :" & vbCrLf & TxtCommentaire

J'aimerai mettre en gras "Affaire" et "Commentaire". Quelqu'un aurait-il une solution ou un indice qui me permettrai d'avancer?

Merci par avance
     
Julien

cs_Jack · Accepted Answer

Salut

On le dit à longueur de temps : le VB de Excel n'est pas du VB6 mais du VBA.

Les Comment sous Excel ne sont pas simples et l'aide est très très sommaire, mais après quelques minutes de recherche sur le net, on trouve toujours des infos (ce que je te conseille de faire la prochaine fois)
Voici un exemple :
    Dim monRange    As Range
    Dim monComment  As Comment
    
    Set monRange = Range("B1")
    ' Tente de récupérer le commentaire actuel
    Set monComment = monRange.Comment
    ' S'il n'y en a pas
    If monComment Is Nothing Then
        ' Ajoute un commentaire    ----'----1----'----2----'----3----'----
        monRange.AddComment Text:="VBFrance est vraiment formidable"
        ' Associe mon objet à ce commentaire
        Set monComment = monRange.Comment
        ' Bidouillmage du contenu
        ' Le mot "vraiment" qu'on veut mettre en gras commence au
        '   14ème caractère et a une longueur de 8 caractères
        With monComment.Shape.TextFrame
            With .Characters(14, 8).Font
                .Bold = True
                .Name = "Arial Black"
                .Size = 20
                .ColorIndex = 3 ' Rouge
            End With
        End With
    End If
Vala
Jack, MVP VB
NB : Je ne répondrai pas aux messages privés

Le savoir est la seule matière qui s'accroit quand on la partage (Socrate)

cs_juloss · Answer

Bonjour jack

Merci pour ta réponse.

[Catégorie modifiée VB6 -> VBA] Commentaire de cellule excel

2 réponses

Votre réponse

Discussions similaires